; WorldEntityID Example
; ---------------------
; Requires Extended mode.

Graphics3D 640,480,0,2
SetBuffer BackBuffer()

; Load a world whose author placed an invisible spawn marker
world=LoadWorldAsync("../../../samples/worlds/help-marker.world")
While Not WorldReady(world)
    If WorldLoadState(world)=WORLD_LOAD_FAILED Then RuntimeError WorldLoadError(world)
    Cls
    Text 0,0,"Loading the marker world..."
    Flip
Wend

; Select the loaded world and give it a camera and a light
SetWorld world
camera=CreateCamera()
PositionEntity camera,0,1,-5
light=CreateLight()
RotateEntity light,45,45,0

; The authored marker entity, found by its stable ID
spawn=FindWorldEntity(world,"player-spawn")

; A locally created cone marks the spawn point visibly
player=CreateCone()
PositionEntity player,EntityX(spawn),EntityY(spawn),EntityZ(spawn)
EntityColor player,80,220,120
PointEntity camera,player

; WorldEntityID$ recovers the stable .world document ID of an entity;
; entities the document did not create report an empty string
spawn_id$=WorldEntityID(spawn)
player_id$=WorldEntityID(player)

While Not KeyDown(1)

    TurnEntity player,0,2,0

    ; Arrow keys move the camera
    If KeyDown(200) Then MoveEntity camera,0,0,0.1
    If KeyDown(208) Then MoveEntity camera,0,0,-0.1
    If KeyDown(203) Then TurnEntity camera,0,1,0
    If KeyDown(205) Then TurnEntity camera,0,-1,0

    RenderWorld

    Text 0,0,"Arrow keys: move camera   Esc: exit"
    Text 0,20,"WorldEntityID$(spawn) = '"+spawn_id+"'"
    Text 0,40,"WorldEntityID$(player) = '"+player_id+"' (the cone is not from the document)"

    Flip

Wend

FreeWorld world
End