; LoadAnimSeq Example
; -------------------

Graphics3D 640,480,0,2
SetBuffer BackBuffer()

camera=CreateCamera()
PositionEntity camera,0,2,-6
RotateEntity camera,12,0,0

light=CreateLight()
RotateEntity light,45,45,0

; A grassy paddock for the fox to roam
ground=CreatePlane()
EntityTexture ground,LoadTexture("media/MossyGround.BMP")

; Load the rigged fox; its own file provides sequences 0, 1 and 2
fox=LoadAnimMesh("../../../samples/glTF/assets/Fox/Fox.glb")
If fox=0 Then RuntimeError "Could not load Fox.glb: "+ModelLoadError()

; Shrink the fox to game scale (the file is modelled about 100 units tall)
FitMesh fox,-0.8,0,-0.8,1.6,1.6,1.6,True

; LoadAnimSeq appends animation from another file to an existing entity and
; returns the new sequence number. Here we append from the same file, so the
; fox ends up with a second copy of its clips as sequences 3, 4 and 5.
extra=LoadAnimSeq(fox,"../../../samples/glTF/assets/Fox/Fox.glb")

; Play the appended sequence
Animate fox,1,1,extra

While Not KeyDown(1)

    UpdateWorld

    ; Arrow keys move the camera
    If KeyDown(200) Then MoveEntity camera,0,0,0.1
    If KeyDown(208) Then MoveEntity camera,0,0,-0.1
    If KeyDown(203) Then TurnEntity camera,0,1,0
    If KeyDown(205) Then TurnEntity camera,0,-1,0

    RenderWorld

    Text 0,0,"Arrows: camera   Esc: exit"
    Text 0,20,"LoadAnimSeq returned sequence "+extra+", now playing sequence "+AnimSeq(fox)

    Flip

Wend

End