Concerning Configuration Files.

Hey everyone,

I have a question concerning configuration files!


Sometimes with programs, I've noticed that they include a text
file usually called something or other, .config
By opening the text file and modifying some of the numbers,
you can change how the program works.

How can I do this in Blitz?

I've tried making a program where the code goes like this,

;Start of Code
Include "Main Code File.bb"
;End Of Code

And then I put "Main Code File" in the same folder and create a
.exe


What this SHOULD do, is make it so you can modify "Main Code File"
and still be able to run the .exe with the newly modified code.
But it doesn't work :(

Whenever I run the .exe it just runs my program how it WAS, not
how it IS after modifying "Main Code File"



Why is this, and how can I fix it?

Do I need to use some kind of .dat file?


Thanks if anyone can answer this,

WERDNA

I have no idea what you think these configuration files are doing, but they're not doing it. It almost seems as if you think a compiled exe is dynamically recompiling itself according to some arbitrary file you have laying around.

Config files are just text files. You read them with ReadLine and ReadFile and you write them with WriteLine and WriteFile. What effect they have on the program is entirely up to you, which is to say you have to write the code to read them and do something based on what it reads in your game before you compile the exe. Once you've made an exe, you're not changing it, and Blitz3D is a compiled language, not interpreted, so nothing in any .BB source file is going to be understood automatically at that stage.

Ohhhhhhhhhhhhhh.

Guess I'm still a noob with Blitz, lol

Thanks for the help Gariel ^_^


I appreciate it greatly.

Werdna, what those config files do is what you program it to do. You can read any information from any text file using the read commands. It doesn't actually manipulate the code, what they are doing is getting variables FROM the config file.

Here is an example, it reads a file called "config.txt", if it exists.
You should first create a file "config.txt" and save it in the same folder as this program.
"config.txt" should be this:

width=1024
height=768
depth=0
mode=2

And this is the example:

;just in case no "config.txt" was found
width = 800
height = 600
depth = 0
mode = 2

;if the file does exist, then
If FileType("config.txt") = 1 Then 

	;open the file
	ff = ReadFile("config.txt") 
	
	;read until file ends
	While Not(Eof(ff)) 
	
		;read line from file
		l$ = ReadLine(ff) 
		;make lowercase
		l$ = Lower$(l$)   
		
		;find "=" sign in the line
		cc = Instr(l$, "=") 
		
		;if "=" sign was found, then
		If (cc > 0) Then 
		
			;get everything before "="
			name$ = Left$(l$, cc - 1) 
			
			;get everything after "="
			value$ = Mid$(l$, cc + 1) 
			
			;print what was found
			Print "NAME='" + name$ + "' VALUE='" + value$ + "'"
		
			;deal with the value that was found
			If name$ = "width"  Then width = value 
			If name$ = "height" Then height = value
			If name$ = "depth"  Then depth = value
			If name$ = "mode"   Then mode = value
			
		End If
		
	Wend	
	;close file
	CloseFile ff
	
Else

	Print "missing config.txt"
	
End If

;;example usage:
;Graphics width, height, depth, mode

Print
Print "press any key"
FlushKeys 
WaitKey
End

OH!

I get it now.


Thanks for the example Warner, and thanks everyone else for your
help as well!

WERDNA