Forsooth! My Missile Won't Work

Yup. I have another problem.
I have a code that I got from someone on this sight and I have implemented it into a project of mine.
Here is the code:

Graphics3D 1024,764
SetBuffer BackBuffer()

missile=CreateCone()
PositionEntity missile,EntityX(cam,1),EntityY(cam,1),EntityZ(cam,1)
ScaleEntity missile,.5,1,.5
RotateEntity missile,EntityPitch(cam,1),EntityYaw(cam,1),EntityRoll(cam,1)

;Creating the targets
Type target
     Field count
     Field shape
     Field health
End Type

For x=1 To 5
     For z=1 To 5
          foe.target=New target
          foe\count=25
          foe\health=3
          foe\shape=CreateCube()
          ScaleEntity foe\shape,2,2,2
          PositionEntity foe\shape,Rand(-450,790)+x*5,60,Rand(-600,750)+z*5
          EntityTexture foe\shape,l
          NameEntity foe\shape,Handle(foe)
     Next
Next

While Not KeyDown(1)

If KeyDown(57) Then 
MoveEntity missile,0,.3,0

	;get vector to target
	Dx# = EntityX( foe\shape ) - EntityX( missile )
	Dy# = EntityY( foe\shape ) - EntityY( missile )
	Dz# = EntityZ( foe\shape ) - EntityZ( missile )
	;align missle to target vector
	AlignToVector missile, Dx, Dy, Dz, 2, .09;.05 

EndIf

RenderWorld
Flip
Wend
End

When I press the space bar, it points to "Dx# = EntityX( foe\shape ) - EntityX( missile )" and says "Entity Does Not Exist".
I think it knows the missile is there so I'm guessing it's the foe\shape (I could be wrong).

So what am I to do?

Well, the code you've posted seems to run fine, if I add CreateCamera, remove EntityTexture, and use MoveEntity missile, 0, 0, 5. So I think the trouble must be in another part of the code.
Since the error is 'Entity does not exist', 'foe' should still exist, only the mesh that is placed in \shape seems to have dissapeared somewhere. I find it most likely that you somewhere assign another value to the 'shape' field.
Try a search in your code for 'shape' or perhaps 'FreeEntity'.

That is very possible. I only cut & pasted the parts of my code that I thought had something to do with it.
I'll look through my code, but were you hinting at a search engine inside Blitz3D? Because if you were, I would much like to learn of it.

Yup, it's definately not detecting foe\shape.
I did not find anything unusual in my code so it's probably some Type thing I have not learned yet.

Wouldn't PointEntity accomplish what you need to do?

Possibly, but it would not look very good.
When a missile is launched it takes a time to aim itself in the right direction. If I were to use PointEntity, I could work, but it would instantly go in the direction of the target.

Also, I tried changing "foe\shape" to a normal identifier that was not a Type and it worked fine. I still need it to seek the "foe\shape, however.

Still can't find anything to explain my problem.

If you need help you need to post more code. As some have suggested you are probably doing something elsewhere in your program which is affecting this. Are you freeing the foe\shape somewhere?

As it stands, when you press space, "foe" is the last instance of target that was created so it should work fine.

If you add this line of code after you press space

for t.target = each target
debuglog str$( t )
next

What information is displayed in the debuglog?

Well, the debuglog turned up this:

[25,28297848,3]
[25,28298528,3]
[25,34764816,3]
[25,34765496,3]
[25,34750472,3]
[25,34751152,3]
[25,28295176,3]
[25,28295856,3]
[25,34607112,3]
[25,34607792,3]

I couldn't make heads or tails of it.

Also, here is more of my code that I dug up that might, just might, have something to do with it:

Graphics3D 1024,764
SetBuffer BackBuffer()

;Types
Const type_player=1
Const type_terrain=2
Const type_missile=3
Const type_target=4

;The camera
Global cam=CreateCamera()
ScaleEntity cam,1,1,1
PositionEntity cam,0,0,0
EntityType cam,type_player
EntityRadius cam,5

;The enviroment
.enviroment
Global ground=LoadTerrain("Canyon1.bmp")
ScaleEntity ground,5,300,5
PositionEntity ground,-500,-200,-500
tex=LoadTexture("Desert Sand.jpg")
ScaleTexture tex,50,50
EntityTexture ground,tex
EntityType ground,type_terrain
TerrainShading ground,1
TerrainDetail ground,10000

.gunz
Global gun=LoadMesh("Pistol.3ds")
PositionEntity gun,.25,gunbob#,recoil#
ScaleEntity gun,.05,.05,.05
RotateEntity gun,0,-90,0
tex3=LoadTexture("Metal 3.jpg")
EntityTexture gun,tex3
EntityParent gun,cam
EntityType gun,type_player
EntityRadius gun,.005

;The missile
missile=CreateCone()
PositionEntity missile,EntityX(cam,1),EntityY(cam,1),EntityZ(cam,1)
RotateEntity missile,90,0,0
ScaleEntity missile,.5,1,.5
EntityParent missile,cam

;The targets
.targets
Type target
     Field count
     Field shape
     Field health
End Type

Global l=LoadTexture("target.jpg")
For x=1 To 5
     For z=1 To 5
          foe.target=New target
          foe\count=25
          foe\health=3
          foe\shape=CreateCube()
          ScaleEntity foe\shape,2,2,2
          PositionEntity foe\shape,Rand(-450,790)+x*5,60,Rand(-600,750)+z*5
          EntityTexture foe\shape,l
          EntityType foe\shape,type_target
          EntityRadius foe\shape,5,5
          NameEntity foe\shape,Handle(foe)
     Next
Next

;Camera look
Function CurveValue#(current#,destination#,curve)

	current#=current#+((destination#-current#)/curve)
	
	Return current#

End Function

;How far the camera can see
cam_range=10000

;Collision method & respons
Collisions type_player,type_terrain,2,2
Collisions type_missile,type_terrain,2,1
Collisions type_target,type_terrain,2,1
Collisions type_missile,type_target,2,1

.game_loop
While Not KeyDown(1)

;How near the camera can see
CameraRange cam,.1,cam_range

;Controls
If KeyDown(200)=True Then MoveEntity cam,0,0,.3
If KeyDown(205)=True Then MoveEntity cam,.3,0,0
If KeyDown(203)=True Then MoveEntity cam,-.3,0,0
If KeyDown(208)=True Then MoveEntity cam,0,0,-0.3

;More camera look
mxs#=MouseXSpeed()*.3                          
mys#=MouseYSpeed()*.3                          
                                               
dest_xangle#=dest_xangle#+mys#                 
dest_yangle#=dest_yangle#-mxs#                 
                                              
xangle#=CurveValue#(xangle#,dest_xangle#,3)   
yangle#=CurveValue#(yangle#,dest_yangle#,3)   
                                               
RotateEntity cam,xangle#,yangle#,0            
                                                   
MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

;Firing bullets
If MouseHit(1) And reload=0
     EntityParent ammo\shape,gun
     PositionEntity ammo\shape,1,-7,10
     RotateEntity ammo\shape,0,90,0
     ShowEntity ammo\shape
     EntityParent ammo\shape,0
     bamchn=PlaySound(SOUNDbam)
     ChannelVolume bamchn,.5
     ammo\count=ammo\count-1
EndIf

If KeyDown(57) Then 
MoveEntity missile,0,1,0
EntityParent missile,0

	;get vector to target
	Dx# = EntityX( foe\shape ) - EntityX( missile )
	Dy# = EntityY( foe\shape ) - EntityY( missile )
	Dz# = EntityZ( foe\shape ) - EntityZ( missile )
    ;align missle to target vector
	AlignToVector missile, Dx#, Dy#, Dz#, 2, .09;.05 

EndIf

For t.target=Each target
DebugLog Str$(t)
Next

bulletpath(ammo.bullet,foe.target)

;Gravity
TranslateEntity cam,0,-.35,0
For foe.target=Each target
TranslateEntity foe\shape,0,-2,0
Next

;Acceleration/Jump
If KeyHit(54)=True And CountCollisions(cam)=True Then 
     acceleration#=1
     jumpchn=PlaySound(jump)
     ChannelVolume jumpchn,.2
EndIf
If Not KeyHit(54)=True Then acceleration#=acceleration#-.008
If acceleration#<-.1 Then acceleration#=-.1
TranslateEntity cam,0,acceleration#,0

;Checking for collisions
UpdateWorld

RenderWorld

;I preformed Flip elsewhere in my code

Wend

;Some of this is other stuff
;Freeing Fonts and Stuff
FreeFont hudfont
FreeSound SOUNDbam
FreeSound jump
FreeSound die
FreeSound thrust
FreeImage ch
FreeTexture l
FreeTexture tex
FreeTexture tex2
FreeTexture tex3
FreeTexture tex4

End

Function bulletpath(ammo.bullet,foe.target)
     MoveEntity ammo\shape,.26,-.15,15
     If CountCollisions(ammo\shape)=True Then HideEntity ammo\shape
End Function

If you can find anything to blame in there feel free to point it out.
And thanks in advance.

Your code is a bit of a mess but I see the problem.

As you are using the 'foe' variable to iterate through the type list to apply gravity, 'foe' will be set to null at the end of the loop.

See example :

For foe.target=Each target
  TranslateEntity foe\shape,0,-2,0
  debuglog str$(foe)
Next
debuglog str$(foe)  ; <---- foe will be [NULL]

Don't use the same variable for the missiles target, use a global variable:

global MissileTarget.Target

and set it to one of the existing targets, once they are created :

MissileTarget = GetNearestTarget( Cam )

function GetNearestTarget.Target( Source )

  local Found.target = null

  MinDistance# = 100000

  for t.target = each target
     
    Distance = entitydistance( Source , t\Shape )

    if Distance < MinDistance
       MinDistance = Distance
       Found = t
    endif

  next

  return found

end function

Then, instead of using foe\shape for the missile targetting, use MissileTarget\Shape.

Stevie

Darn, and I thought I was being smart with the gravity code. Aw well.
Thanks for the advice, I'll see what I can do with it.
I'm still curious as to how you can figure anything out from that DeBugLog code.

Having a little trouble figuring out where to put certain pieces of code.

I tried putting "global MissileTarget.Target" in a few different places in the target creating part of my code and it either said "Illegal Type Conversion" or "Global Can Only Appear-" anyway I can't figure that part out.

I also put "MissileTarget = GetNearestTarget( Cam )" right under the missile firing part of my code and got an "Illegal Type Conversion".

I'm obviously not very good at this.
When you said "Variable" did you mean Identifier, I got a little confused at that part.

I got nothing from the debuglog other than the fact that the \shape exists for them all.

No offence Ace but I think you should start with something simpler, or at least learn a bit more about how to use types properly.

I did mean variable, but you can only declare a global variable once in your code. I see nowhere in your code which handles missiles once space is pressed? At the moment you have to continually hold space to align and move the missile. Surely this isn't how you intend for this to work?

Anyway, this is what I meant from my previous post :

Graphics3D 1024,764
SetBuffer BackBuffer()

;Types
Const type_player=1
Const type_terrain=2
Const type_missile=3
Const type_target=4

;The camera
Global cam=CreateCamera()
ScaleEntity cam,1,1,1
PositionEntity cam,0,0,0
EntityType cam,type_player
EntityRadius cam,5

;The enviroment
.enviroment
Global ground=LoadTerrain("Canyon1.bmp")
ScaleEntity ground,5,300,5
PositionEntity ground,-500,-200,-500
tex=LoadTexture("Desert Sand.jpg")
ScaleTexture tex,50,50
EntityTexture ground,tex
EntityType ground,type_terrain
TerrainShading ground,1
TerrainDetail ground,10000

.gunz
Global gun=LoadMesh("Pistol.3ds")
PositionEntity gun,.25,gunbob#,recoil#
ScaleEntity gun,.05,.05,.05
RotateEntity gun,0,-90,0
tex3=LoadTexture("Metal 3.jpg")
EntityTexture gun,tex3
EntityParent gun,cam
EntityType gun,type_player
EntityRadius gun,.005

;The missile
missile=CreateCone()
PositionEntity missile,EntityX(cam,1),EntityY(cam,1),EntityZ(cam,1)
RotateEntity missile,90,0,0
ScaleEntity missile,.5,1,.5
EntityParent missile,cam

;The targets
.targets
Type target
     Field count
     Field shape
     Field health
End Type

;SG
Global MissileTarget.target

Global l=LoadTexture("target.jpg")
For x=1 To 5
     For z=1 To 5
          foe.target=New target
          foe\count=25
          foe\health=3
          foe\shape=CreateCube()
          ScaleEntity foe\shape,2,2,2
          PositionEntity foe\shape,Rand(-450,790)+x*5,60,Rand(-600,750)+z*5
          EntityTexture foe\shape,l
          EntityType foe\shape,type_target
          EntityRadius foe\shape,5,5
          NameEntity foe\shape,Handle(foe)
     Next
Next

;Camera look
Function CurveValue#(current#,destination#,curve)

	current#=current#+((destination#-current#)/curve)
	
	Return current#

End Function

;How far the camera can see
cam_range=10000

;Collision method & respons
Collisions type_player,type_terrain,2,2
Collisions type_missile,type_terrain,2,1
Collisions type_target,type_terrain,2,1
Collisions type_missile,type_target,2,1

.game_loop
While Not KeyDown(1)

;How near the camera can see
CameraRange cam,.1,cam_range

;Controls
If KeyDown(200)=True Then MoveEntity cam,0,0,.3
If KeyDown(205)=True Then MoveEntity cam,.3,0,0
If KeyDown(203)=True Then MoveEntity cam,-.3,0,0
If KeyDown(208)=True Then MoveEntity cam,0,0,-0.3

;More camera look
mxs#=MouseXSpeed()*.3                          
mys#=MouseYSpeed()*.3                          
                                               
dest_xangle#=dest_xangle#+mys#                 
dest_yangle#=dest_yangle#-mxs#                 
                                              
xangle#=CurveValue#(xangle#,dest_xangle#,3)   
yangle#=CurveValue#(yangle#,dest_yangle#,3)   
                                               
RotateEntity cam,xangle#,yangle#,0            
                                                   
MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

;Firing bullets
If MouseHit(1) And reload=0
     EntityParent ammo\shape,gun
     PositionEntity ammo\shape,1,-7,10
     RotateEntity ammo\shape,0,90,0
     ShowEntity ammo\shape
     EntityParent ammo\shape,0
     bamchn=PlaySound(SOUNDbam)
     ChannelVolume bamchn,.5
     ammo\count=ammo\count-1
EndIf

If KeyDown(57) Then 

	MissileTarget = GetNearestTarget( cam )

	MoveEntity missile,0,1,0
	EntityParent missile,0

	;get vector to target
	Dx# = EntityX( MissileTarget\shape ) - EntityX( missile )
	Dy# = EntityY( MissileTarget\shape ) - EntityY( missile )
	Dz# = EntityZ( MissileTarget\shape ) - EntityZ( missile )
    ;align missle to target vector
	AlignToVector missile, Dx#, Dy#, Dz#, 2, .09;.05 

EndIf

;For t.target=Each target
;DebugLog Str$(t)
;Next

bulletpath(ammo.bullet)

;Gravity
TranslateEntity cam,0,-.35,0
For foe.target=Each target
TranslateEntity foe\shape,0,-2,0
Next

;Acceleration/Jump
If KeyHit(54)=True And CountCollisions(cam)=True Then 
     acceleration#=1
     jumpchn=PlaySound(jump)
     ChannelVolume jumpchn,.2
EndIf
If Not KeyHit(54)=True Then acceleration#=acceleration#-.008
If acceleration#<-.1 Then acceleration#=-.1
TranslateEntity cam,0,acceleration#,0

;Checking for collisions
UpdateWorld

RenderWorld

;I preformed Flip elsewhere in my code

Wend

;Some of this is other stuff
;Freeing Fonts and Stuff
FreeFont hudfont
FreeSound SOUNDbam
FreeSound jump
FreeSound die
FreeSound thrust
FreeImage ch
FreeTexture l
FreeTexture tex
FreeTexture tex2
FreeTexture tex3
FreeTexture tex4

End

Function bulletpath(ammo.bullet)
     MoveEntity ammo\shape,.26,-.15,15
     If CountCollisions(ammo\shape)=True Then HideEntity ammo\shape
End Function

Function GetNearestTarget.Target( Source )

  Local Found.target

  MinDistance# = 100000

  For t.target = Each target
     
    Distance# = EntityDistance( Source , t\Shape )

    If Distance < MinDistance
       MinDistance = Distance
       Found = t
    EndIf

  Next

  Return found

End Function

If you need any further help can I suggest you make a version of your code which does not require external media. You are more likely to get help that way.

Stevie

In response to the previous comment of my code being a mess: Tell me about it.

I started out with the KeyDown command for the missile because it was simpler and I was planning to make an update code for it later once I got it working.

Also, yeah I probably shouldn't shoot for the sky quite yet. If I see something I really like I just get the irresistible urge to dive right into it.
And yes, I'll work on a non-external media version of my code.

Thanks again for all the help. I'll try this out and see how it works, and try to find time to check out some of the sweet tutorials I've been hearing about.

Well, I still get an "Illegal Type Conversion" in reference to the "MissileTarget = GetNearestTarget( Cam )" line, but that's ok.

I think I'm going to come back to this later on when I am more better skilled at this.

Thanks again for all your help.

Try using:

MissileTarget.Target = GetNearestTarget( Cam )

after you set the variable as a global pointer like Stevie showed you.

That function is returning a pointer to a Type and may be why you're getting the "Illegal Type Conversion" error message.

Don't give up!

Clearly your not using the code I posted above as it includes "global MissileTarget.Target" just below the type definition. If you do this then then line "MissileTarget = GetNearestTarget( cam )" will not give an illegal Type conversion error.

If it's still an issue post the code.

@ Mikel:
Don't worry, I'm not giving up. I'm mearly taking a break to look into the details, as all this talk of variables and types is confusing me.

Also, the problem presists.
Here is where I put the code:

Graphics3D 1024,764
SetBuffer BackBuffer()

;Creating the targets
.targets
Type target
     Field count
     Field shape
     Field health
End Type

Global missiletarget.target

For x=1 To 5
     For z=1 To 5
          foe.target=New target
          foe\count=25
          foe\health=3
          foe\shape=CreateCube()
          ScaleEntity foe\shape,2,2,2
          PositionEntity foe\shape,Rand(-450,790)+x*5,60,Rand(-600,750)+z*5
          EntityTexture foe\shape,l
          EntityType foe\shape,type_target
          EntityRadius foe\shape,5,5
          NameEntity foe\shape,Handle(foe)
     Next
Next

While Not KeyDown(1)

If KeyDown(57) Then 
MoveEntity missile,0,1,0
EntityParent missile,0
missiletarget=getnearesttarget(cam)

	;get vector to target
	Dx# = EntityX( missiletarget\shape ) - EntityX( missile )
	Dy# = EntityY( missiletarget\shape ) - EntityY( missile )
	Dz# = EntityZ( missiletarget\shape ) - EntityZ( missile )
    ;align missle to target vector
	AlignToVector missile, Dx#, Dy#, Dz#, 2, .09;.05 

EndIf


UpdateWorld

RenderWorld
Wend
End

Function getnearesttarget(cam)
Local found.target;=Null
mindistance#=100000
For t.target=Each target
     distance#=EntityDistance(source,t\shape)
     If distance=<mindistance
          mindistance=distance
          found=t
     EndIf
Next
Return found
End Function

Likely and oversimplified example. If I needed to put anything else in there just let me know.

I'm sure you are being very patient with my noobishness Stevie G and I am greatful for it.

You need to add a .target at the end of the function name as it indicates what type of variable you are returning from the function. By default this is an integer which is why you get the error.

Function getnearesttarget( cam ) ; default  / returns integer

Function getnearesttarget%( cam ) ;returns integer

Function getnearesttarget#( cam ) ;returns a float

Function getnearesttarget.target( cam ) ; returns a .target

Stevie

Yep, just do what Stevie suggested with your Function name and also, I think when you call that function you should use the pointer missiletarget.target

Try it with those changes and let us know how it goes.

If you declare the missiletarget.target to be global then blitz already knows what type of variable missiletarget is so this works fine:

missiletarget = getnearesttarget( cam )

Wow, I did not know that.
It solved my "Illegal Type Conversion" problem.

But now it points to this line:

distance#=EntityDistance(source,t\shape)

and says "Entity Does Not Exist" for as long as I hold down the space bar (I assume that's because of the KeyDown command).
Come to think of it, I didn't see "Source" anywhere else in the code. Was that supposed to mean something else?

Ace, if you'd copied the code I posted then you wouldn't have had any of these issues!!

See the original function below as I posted it, note the 'Source' instead of 'cam' as a function parameter. When you call the function use 'cam'.

Function GetNearestTarget.Target( Source )

  Local Found.target

  MinDistance# = 100000

  For t.target = Each target
     
    Distance# = EntityDistance( Source , t\Shape )

    If Distance < MinDistance
       MinDistance = Distance
       Found = t
    EndIf

  Next

  Return found

End Function

I can see that you are frustrated with me, quite understandable as I am noobish when it comes to Types and not much better when it comes to Functions and tend to occasionally over look an instruction. For that, I apologize.

I did get it to work. Thank you for your help and patience.

I also found a neat little tutorial that should help me with this type thing.

Thanks again.