Planet atmosphere glow

I am experimenting with a simple planet atmosphere FX without textures. I have a sphere and a ring of triangles surrounding the sphere, the ring always points to the cam. It looks nice when you're far away from the planet but doesn't work when you get closer. I am looking for some kind of formula which resizes/repositions the ring according to the viewer's perspective along the sphere. I tried some experiments with SQR,EXP and so on but wasn't successful. And even if I got close to an acceptable result it didn't worked anymore when I resized the sphere from 1.0 to 2.0 or other values.

Here is a demo code to visualize the problem:

Graphics3D 1024,768,32,2

; Variables
mousespeed#=0.1
cameraspeed#=0.05
camerasmoothness#=10
scale#=1.0

; Camera
cam=CreateCamera()
PositionEntity cam,0,0,-5
CameraRange cam,0.1,100

; Planet
planet=CreateSphere(32)
ScaleEntity planet,scale,scale,scale
EntityColor planet,0,255,0
EntityFX planet,1

; Glow
ring=CreateRing(1*scale,1.5*scale,30,1,255,255,255,32,32,32,0)
EntityFX ring,1+2+32

; Timer
timer=CreateTimer(60)

MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

While Not KeyHit(1)
	
	; SPACE = Wireframe
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousecam
	mx#=CurveValue(MouseXSpeed()*mousespeed,mx,camerasmoothness)
	my#=CurveValue(MouseYSpeed()*mousespeed,my,camerasmoothness)
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	pitch#=EntityPitch(cam)
	yaw#=EntityYaw(cam)
	pitch=pitch+my
	yaw=yaw-mx
	If pitch>89 Then pitch=89
	If pitch<-89 Then pitch=-89
	RotateEntity cam,0,yaw,0
	TurnEntity cam,pitch,0,0
	
	; Movement
	cx#=(KeyDown(205)-KeyDown(203))*cameraspeed
	cz#=(KeyDown(200)-KeyDown(208))*cameraspeed
	MoveEntity cam,cx,0,cz
	
	; Ring points always to camera
	PointEntity ring,cam
	TurnEntity ring,-90,0,0
	
	RenderWorld
	
	WaitTimer timer
	
	Flip
	
Wend

End

; Smoothcam
Function CurveValue#(newvalue#,oldvalue#,increments )
	If increments>1 oldvalue#=oldvalue#-(oldvalue#-newvalue#)/increments
		If increments<=1 oldvalue=newvalue
			Return oldvalue#
End Function

; Create Single Surface Ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,r1%=255,g1%=255,b1%=255,r2%=0,g2%=0,b2%=0,a#=1.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),0,radius1*Sin(a1),0,0)
		v1=AddVertex(surf,radius1*Cos(a2),0,radius1*Sin(a2),0,0)
		v2=AddVertex(surf,radius2*Cos(a3),0,radius2*Sin(a3),1,1)
		v3=AddVertex(surf,radius2*Cos(a4),0,radius2*Sin(a4),1,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,1
		VertexColor surf,v1,r1,g1,b1,1
		VertexColor surf,v2,r2,g2,b2,a
		VertexColor surf,v3,r2,g2,b2,a
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	If fx>0 Then EntityFX mesh,fx
	
	Return mesh
	
End Function

Any suggestions?

I think what you have is pretty good to start with.

The thing that is screwing you up is the perspective of the sphere when you get close. If you change your camerazoom to a higher value (I used 4) things work a lot better.

That's not bad - simple and practical.

I think this is doable. You basically want to position the ring on the horizon of the sphere/planet. Google 'calculating distance to horizon' to get started.

Wouldn't that get complicated and involve a re-scaling of the ring then?
As the horizon shrinks at higher 'latitudes' ('latitude' here is assuming an invariance where any point on the sphere's surface can be considered a pole)

Once you get close enough for the 'distortioon' to set in, might be niece to just switch to a sprite overlay instead. ?

I think it's acvtually a lot more complicated than it first appears...

Yes, it will require re-scaling the ring, but I dont see that as a problem.

Hehe well I had problems trying to work it..

I am in agreement wit the cameraoom comment though, because the fisheye distortion plays havoc with objects up close which I don't think is easily reslveable.

You could always re-size the ring slightly smaller than the calculations say, to get over the perspective problem, I think.

It's not only the perspective that is causing the problem.

The glow is using a look at constraint to the camera. When the camera gets really close and is not looking at the center of the glow, then the glow will actually tip away from the camera view. (I don't know if I explained this very good)

Anyways, the larger camerazoom also helps this because the camera stays farther away from the glow, so you do not get this effect as bad.

I started a quick'n'dirty test to check out if it is really possible, and it IS - but with my solution not in realtime. Here is my testbed (with a improved Createring function, there was an error in the UV coordinates and we don't need to turn it 90° all the time anymore):

1. the dummy pivot always points to cam
2. do a linepick from cam to spherecenter
3. check if it hits the planet or the dummy
4. if it hits the planet move the dummy a little bit to the cam
5. if it hits the dummy move the dummy a little bit from the cam away
6. the ring scale is (the distance between dummy and sphere) / 2
7. scale the ring and point it to the cam

The process is due accuracy very slow so be patient if you get too far away from the planet (this is a testbed for a close orbit). You can speed this up by changing the 0.001 value to 0.01 or 0.1, which will result in precision lost.

big10p: I don't get the "calculate distance to horizon" function to work. To be precise: I can calc the distance between the cam and the horizon, but how shall I calculate the actual scale of the ring out of it? Can you post a small BB-Example?

Graphics3D 1024,768,32,2

; Variables
mousespeed#=0.1
cameraspeed#=0.1
camerasmoothness#=10
scale#=2.0

timer=CreateTimer(60)

; Camera
cam=CreateCamera()
PositionEntity cam,0,0,-scale*1.1
CameraRange cam,0.1,1000

; Planet
ppiv=CreatePivot()
PointEntity ppiv,cam
planet=CreateSphere(60)
ScaleEntity planet,scale,scale,scale
EntityPickMode planet,1
EntityRadius planet,scale
NameEntity planet,"Planet"
EntityColor planet,0,255,0

; Dummy
dummy=CreateSphere(8,ppiv)
PositionEntity dummy,scale*2.5,0,0
EntityPickMode dummy,1
EntityRadius dummy,0.1
ScaleEntity dummy,0.1*scale,0.1*scale,0.1*scale
NameEntity dummy,"Dummy"

ring=CreateRing(1*scale,1.1*scale,120,1+2+32,3,192,224,255,64,128,255,0,scale)

MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

PointEntity cam,dummy


While Not KeyHit(1)
	
	cx#=EntityX(cam)
	cy#=EntityY(cam)
	cz#=EntityZ(cam)
	
	dx#=EntityX(dummy,1)
	dy#=EntityY(dummy,1)
	dz#=EntityZ(dummy,1)
	
	entity=LinePick(cx,cy,cz,dx-cx,dy-cy,dz-cz,0.001)
	If entity=planet Then MoveEntity dummy,0.001,0,0
	If entity=dummy Then MoveEntity dummy,-0.001,0,0
	
	diff#=EntityDistance(ppiv,dummy)/scale
	
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousecam
	mx#=CurveValue(MouseXSpeed()*mousespeed,mx,camerasmoothness)
	my#=CurveValue(MouseYSpeed()*mousespeed,my,camerasmoothness)
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	pitch#=EntityPitch(cam)
	yaw#=EntityYaw(cam)
	pitch=pitch+my
	yaw=yaw-mx
	If pitch>89 Then pitch=89
	If pitch<-89 Then pitch=-89
	RotateEntity cam,0,yaw,0
	TurnEntity cam,pitch,0,0
	
	; Movement
	cx#=(KeyDown(205)-KeyDown(203))*cameraspeed
	cz#=(KeyDown(200)-KeyDown(208))*cameraspeed
	MoveEntity cam,cx,0,cz
	
	PointEntity ppiv,cam
	PointEntity ring,cam
	
	ScaleEntity ring,diff,diff,diff
	
	RenderWorld
	
	WaitTimer timer
	
	Flip 0
	
Wend

End

; Smoothcam
Function CurveValue#(newvalue#,oldvalue#,increments )
	If increments>1 oldvalue#=oldvalue#-(oldvalue#-newvalue#)/increments
		If increments<=1 oldvalue=newvalue
			Return oldvalue#
End Function

; Ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,blend%=0,r1%=255,g1%=255,b1%=255,r2%=0,g2%=0,b2%=0,a#=1.0,scale#=1.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),radius1*Sin(a1),0,0,0)
		v1=AddVertex(surf,radius1*Cos(a2),radius1*Sin(a2),0,0,0)
		v2=AddVertex(surf,radius2*Cos(a3),radius2*Sin(a3),0.01*scale,1,1)
		v3=AddVertex(surf,radius2*Cos(a4),radius2*Sin(a4),0.01*scale,0,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,1
		VertexColor surf,v1,r1,g1,b1,1
		VertexColor surf,v2,r2,g2,b2,a
		VertexColor surf,v3,r2,g2,b2,a
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	If fx>0 Then EntityFX mesh,fx
	If blend>0 Then EntityBlend mesh,blend

	
	Return mesh
	
End Function

Edit: it could look like this image if it is working:

Erm, I'd have to have a think about that, TBH. I just figured the 'distance to horizon' calc was along the right lines.

Actually, looking at that screenie, I'm thinking using a separate sphere for the atmosphere may be a better way to go. That pic doesn't look quite right - kinda looks like theres a light behind the planet.

> That pic doesn't look quite right - kinda looks like theres a light behind the planet.

I know. But that is priority 5 at the moment. Its only the testbed with textures and stars.

I think that you should loop through each vertex of the planet, and project it. Then, determine min/max x/y/z values. If the ring was a 2D object, that would be enough. However, because the ring is 3D, you'll need to find a way to project the 2D coords back into the 3D world. CameraPick on a plane should usually work, but I had trouble getting it to work with this.
Anyway, here is code that projects the 2D size of the planet onto the screen:

Graphics3D 1024,768,32,2

; Variables
mousespeed#=0.1
cameraspeed#=0.05
camerasmoothness#=10
scale#=1.0

; Camera
cam=CreateCamera()
PositionEntity cam,0,0,-5
CameraRange cam,0.1,100

; Planet
planet=CreateSphere(32)
ScaleEntity planet,scale,scale,scale
EntityColor planet,0,255,0
EntityFX planet,1

; Glow
ring=CreateRing(1*scale,1.5*scale,30,1,255,255,255,32,32,32,0)
EntityFX ring,1+2+32

; Timer
timer=CreateTimer(60)

MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

While Not KeyHit(1)
	
	; SPACE = Wireframe
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousecam
	mx#=CurveValue(MouseXSpeed()*mousespeed,mx,camerasmoothness)
	my#=CurveValue(MouseYSpeed()*mousespeed,my,camerasmoothness)
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	pitch#=EntityPitch(cam)
	yaw#=EntityYaw(cam)
	pitch=pitch+my
	yaw=yaw-mx
	If pitch>89 Then pitch=89
	If pitch<-89 Then pitch=-89
	RotateEntity cam,0,yaw,0
	TurnEntity cam,pitch,0,0
	
	; Movement
	cx#=(KeyDown(205)-KeyDown(203))*cameraspeed
	cz#=(KeyDown(200)-KeyDown(208))*cameraspeed
	MoveEntity cam,cx,0,cz

	RenderWorld
	
	; Ring points always to camera
	ScaleRing(cam, planet)
	PointEntity ring,cam
	TurnEntity ring,-90,0,0
			
	WaitTimer timer
		
	Flip
	
Wend

End

; Smoothcam
Function CurveValue#(newvalue#,oldvalue#,increments )
	If increments>1 oldvalue#=oldvalue#-(oldvalue#-newvalue#)/increments
		If increments<=1 oldvalue=newvalue
			Return oldvalue#
End Function

; Create Single Surface Ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,r1%=255,g1%=255,b1%=255,r2%=0,g2%=0,b2%=0,a#=1.0)

	Local a1#,a2#,a3#,a4#,angle%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),0,radius1*Sin(a1),0,0)
		v1=AddVertex(surf,radius1*Cos(a2),0,radius1*Sin(a2),0,0)
		v2=AddVertex(surf,radius2*Cos(a3),0,radius2*Sin(a3),1,1)
		v3=AddVertex(surf,radius2*Cos(a4),0,radius2*Sin(a4),1,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,1
		VertexColor surf,v1,r1,g1,b1,1
		VertexColor surf,v2,r2,g2,b2,a
		VertexColor surf,v3,r2,g2,b2,a
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	;If fx>0 Then EntityFX mesh,fx
	
	Return mesh
	
End Function


Function ScaleRing(cam, planet)
	
	;get size of rendered planet
	surf = GetSurface(planet, 1)
	minx# =  10000
	maxx# =  -10000
	miny# =  10000
	maxy# =  -10000
	For i = 1 To CountVertices(surf) - 1
		TFormPoint VertexX(surf, i), VertexY(surf, i), VertexZ(surf, i), planet, 0
		CameraProject cam, TFormedX(), TFormedY(), TFormedZ()
		If ProjectedX() < minx# Then minx# = ProjectedX()
		If ProjectedX() > maxx# Then maxx# = ProjectedX()
		If ProjectedY() < miny# Then miny# = ProjectedY()
		If ProjectedY() > maxy# Then maxy# = ProjectedY()
	Next

	Rect minx, miny, maxx-minx, maxy-miny, 0
	
End Function

Woo-hoo! Finally I found the exact mathematical solution (with some help from this homepage - it is in german but you don't need to understand german to understand the solution :-)

We only need two right-angled triangles and some trigonometry knowledge to solve it. The ring scale is identical with the c2 hypotenuse we need to calc. I named the variables like they would appear in the two triangles. And we only need to know the scale (Radius of the planet) and the distance between the camera and the planet, it is very simple if you understand how ;-)

Here is a simple sketch of the two triangles, the red dot at the top is the cam, the red line at the left the distance, the black line the radius and the violet line at the bottom is the c2 hypotenuse we are looking for:


radius#=scale
distance#=EntityDistance(cam,planet)

; First triangle
c1#=distance
a1#=radius
q1#=a1^2/c1
p1#=c1-q1
h1#=Sqr(p1*q1)
gamma1#=90
alpha1#=ATan(h1/p1)
beta1#=gamma1-alpha1

; Second Triangle
alpha2# = 90-(90-beta1)
b2# = a1/Tan(alpha2)
c2# = (Sqr(a1^2 + b2^2))/radius

ScaleEntity ring,c2,c2,c2

Graphics3D 1024,768,32,2

; Variables
mousespeed#=0.1
cameraspeed#=0.01
camerasmoothness#=10
scale#=1.0

timer=CreateTimer(60)

; Camera
cam=CreateCamera()
PositionEntity cam,0,0,-scale*2
CameraRange cam,0.01,1000

; Planet
planet=CreateSphere(60)
ScaleEntity planet,scale,scale,scale
EntityColor planet,0,255,0

ring=CreateRing(1*scale,1.5*scale,120,1+2+32,3,192,224,255,64,128,255,0,scale)

MoveMouse GraphicsWidth()/2,GraphicsHeight()/2


While Not KeyHit(1)
	
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousecam
	mx#=CurveValue(MouseXSpeed()*mousespeed,mx,camerasmoothness)
	my#=CurveValue(MouseYSpeed()*mousespeed,my,camerasmoothness)
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	pitch#=EntityPitch(cam)
	yaw#=EntityYaw(cam)
	pitch=pitch+my
	yaw=yaw-mx
	If pitch>89 Then pitch=89
	If pitch<-89 Then pitch=-89
	RotateEntity cam,0,yaw,0
	TurnEntity cam,pitch,0,0
	
	; Movement
	cx#=(KeyDown(205)-KeyDown(203))*cameraspeed
	cz#=(KeyDown(200)-KeyDown(208))*cameraspeed
	MoveEntity cam,cx,0,cz
	
	PointEntity ring,cam
	
	radius#=scale
	distance#=EntityDistance(cam,planet)
	
	; First triangle
	c1#=distance
	a1#=radius
	q1#=a1^2/c1
	p1#=c1-q1
	h1#=Sqr(p1*q1)
	gamma1#=90
	alpha1#=ATan(h1/p1)
	beta1#=gamma1-alpha1
	
	; Second Triangle
	alpha2# = 90-(90-beta1)
	b2# = a1/Tan(alpha2)
	c2# = (Sqr(a1^2 + b2^2))/radius
	
	ScaleEntity ring,c2,c2,c2
	
	RenderWorld
	
	WaitTimer timer
	
	Flip 0
	
Wend

End

; Smoothcam
Function CurveValue#(newvalue#,oldvalue#,increments )
	If increments>1 oldvalue#=oldvalue#-(oldvalue#-newvalue#)/increments
		If increments<=1 oldvalue=newvalue
			Return oldvalue#
End Function

; Ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,blend%=0,r1%=255,g1%=255,b1%=255,r2%=0,g2%=0,b2%=0,a#=1.0,scale#=1.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),radius1*Sin(a1),0,0,0)
		v1=AddVertex(surf,radius1*Cos(a2),radius1*Sin(a2),0,0,0)
		v2=AddVertex(surf,radius2*Cos(a3),radius2*Sin(a3),0,1,1)
		v3=AddVertex(surf,radius2*Cos(a4),radius2*Sin(a4),0,0,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,1
		VertexColor surf,v1,r1,g1,b1,1
		VertexColor surf,v2,r2,g2,b2,a
		VertexColor surf,v3,r2,g2,b2,a
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	If fx>0 Then EntityFX mesh,fx
	If blend>0 Then EntityBlend mesh,blend
	
	
	Return mesh
	
End Function

Perfect! Nice work.

Yeah I did erealise this tioo, just didn't mention it. The same problem occurs when you get within CameraNear Range etc. and objects seem to 'flip' over or around.

Still nice to see a solution works there. I gave up way too early because trig gives me a headache (why do I punish myself tryiong to work in 3D >? :D :D :D)



I'm sure just alpha-ing it down a little (if that makes sense) will be fine.
Using a whole sphere is gonna be a lot more intensive than a smaller bunch of tri's at least.

I am not sure If I understood this correct, but after my post I had the problem that when I got closer to the planet the glow "shrinked" instead of expanding like an atmosphere would do. I solved the problem by using some kind of "flipped" ring and bending the outer vertices towards and away from the cam that a "glow cone" exists. Now I can even "land" on the planet and see the stars shining through my atmosphere without changing anything, just rescaling the ring!

Sorry, I have no time for a small demo (perhaps later) but here is the function call and the main function parts (scale is here 1.0, 10.0... must match the planet size):

; Function call
glow1=CreateRing(1*scale,0.5*scale,60,1+2+32,1,224,240,255,0.5, 64,128,255,0.0,scale*1)
glow2=CreateRing(0.8*scale,0.1*scale,60,1+2+32,1,255,255,255,1.0,  0,128,255,0.0,scale*1)
EntityOrder glow1,10
EntityOrder glow2,10

; put this in the main loop
radius#=scale
distance#=EntityDistance(cam,planet)
c1#=distance
a1#=scale
q1#=a1^2/c1
p1#=c1-q1
h1#=Sqr(p1*q1)
gamma1#=90
alpha1#=ATan(h1/p1)
beta1#=gamma1-alpha1
alpha2# = 90-(90-beta1)
b2# = a1/Tan(alpha2)
c2# = (Sqr(a1^2 + b2^2))/radius
PointEntity glow1,cam
PointEntity glow2,cam
ScaleEntity glow1,c2,c2,c2
ScaleEntity glow2,c2,c2,c2

; The functions that creates the ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,blend%=0,r1%=255,g1%=255,b1%=255,alpha1#=1.0,r2%=0,g2%=0,b2%=0,alpha2#=1.0,scale#=0.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	Local v0%,v1%,v2%,v3%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),radius1*Sin(a1),0,0,0)
		v1=AddVertex(surf,radius1*Cos(a2),radius1*Sin(a2),0,0,0)
		v2=AddVertex(surf,radius2*Cos(a3),radius2*Sin(a3),scale,1,1)
		v3=AddVertex(surf,radius2*Cos(a4),radius2*Sin(a4),scale,1,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,alpha1
		VertexColor surf,v1,r1,g1,b1,alpha1
		VertexColor surf,v2,r2,g2,b2,alpha2
		VertexColor surf,v3,r2,g2,b2,alpha2
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	If fx>0 Then EntityFX mesh,fx
	If blend>0 Then EntityBlend mesh,blend
	
	Return mesh
	
End Function

As you can see, the ring starts now at the size of the planet and moves inwards, I don't know how to explain. Just stop the glow rings pointing to the cam, set FX 16 and move around the planet and you will see what happens. And here three eye-candy shots using this technique (still room for improvement, e.g. fading the stars and matching the Cameraclscolor while inside the atmosphere):

Nice view from a geostationary orbit - lets land at the far left side


Entering the atmosphere


We reached the cruising altitude


Oh and yes I know - planets don't glow at the dark side. If anybody has a nice solution how to setup the ring normals according to the light angle - POST IT!

Nice work Krischan and cheers for the math lesson (with diagram even!). I have enjoyed this thread :).

When can we see a demo of this?

Well here is a little tech demo, I added some basic light functionality, not finished yet - but this is a good point to start from. Just copy'n'paste - it doesn't need any media but uses the same technique which I used to make the screenshots above. Additional, I tried to measure the angles between the cam, the planet and the sun. The variable alpha# holds a value from 0.0 to 1.0 where 1.0 is in a direct line between sun and the planet and 0.0 is behind the planet to check if the ring glow has full or some alpha.

To enjoy the effect just try to land at the far right side of the planet (the sunny side) and when you're close to the surface press the right arrow key to start in a 90° angle from the surface into space.

Graphics3D 1024,768,32,2

; Variables
mousespeed#=0.1
camerasmoothness#=10
scale#=10.0
cameraspeed#=scale/10.0

timer=CreateTimer(60)

; Camera
cam=CreateCamera()
PositionEntity cam,-scale*3,0,scale*2
CameraRange cam,0.01,1000

; Planet
planet=CreateSphere(60)
ScaleEntity planet,scale,scale,scale
EntityColor planet,64,128,255

; Directional Sunlight
light=CreateLight(1)
PositionEntity light,0,0,-scale*10
LightRange light,10*scale
AmbientLight 32,32,32

; Sunsprite
sun=CreateSprite()
ScaleSprite sun,scale,scale
EntityFX sun,1+16
EntityColor sun,255,255,0
EntityParent sun,light
PositionEntity sun,0,0,0
EntityBlend sun,3

; Glow
glow1=CreateRing(1.0*scale,0.5*scale,120,2+16+32,1,224,240,255,0.5, 64,128,255,0.0,scale*1)
glow2=CreateRing(0.8*scale,0.1*scale,120,2+16+32,1,255,255,255,1.0,  0,128,255,0.0,scale*1)

; Hide glow behind the planet
EntityOrder glow1,10
EntityOrder glow2,10

; Cam points to planet first
PointEntity cam,planet

; Center mouse
MoveMouse GraphicsWidth()/2,GraphicsHeight()/2

While Not KeyHit(1)
	
	; SPACE = Wireframe
	If KeyHit(57) Then wf=1-wf : WireFrame wf
	
	; Mousecam
	mx#=CurveValue(MouseXSpeed()*mousespeed,mx,camerasmoothness)
	my#=CurveValue(MouseYSpeed()*mousespeed,my,camerasmoothness)
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	pitch#=EntityPitch(cam)
	yaw#=EntityYaw(cam)
	pitch=pitch+my
	yaw=yaw-mx
	If pitch>89 Then pitch=89
	If pitch<-89 Then pitch=-89
	RotateEntity cam,0,yaw,0
	TurnEntity cam,pitch,0,0
	
	; Calculate ring scale
	radius#=scale
	distance#=EntityDistance(cam,planet)
	c1#=distance
	a1#=scale
	q1#=a1^2/c1
	p1#=c1-q1
	h1#=Sqr(p1*q1)
	gamma1#=90
	alpha1#=ATan(h1/p1)
	beta1#=gamma1-alpha1
	alpha2# = 90-(90-beta1)
	b2# = a1/Tan(alpha2)
	c2# = (Sqr(a1^2 + b2^2))/radius
	
	; Calculcate the sun light angle (1 = between sun and planet, 0 = behind the planet)
	aa#=EntityDistance(cam,planet)
	bb#=EntityDistance(planet,light)
	cc#=EntityDistance(cam,light)
	alpha#=ACos((aa^2+cc^2-bb^2)/(2*aa*cc))/180.0
	If alpha<0 Or alpha>1 Then alpha=1
	If alpha<0.25 Then alpha=0.25
	
	; Glow always points to cam
	PointEntity glow1,cam
	PointEntity glow2,cam
	
	; Scale the rings
	ScaleEntity glow1,c2,c2,c2
	ScaleEntity glow2,c2,c2,c2
	
	; Update the rings
	UpdateRing(glow1,1*scale,0.5*scale,120,224,240,255,0.5*alpha,64,128,255,0.0,scale*1) : UpdateNormals glow1 : FlipMesh glow1
	UpdateRing(glow2,0.8*scale,0.1*scale,120,255,255,255,1.0*alpha,0,128,255,0.0,scale*1) : UpdateNormals glow2 : FlipMesh glow2
	
	; Movement with speed limit closer to the planet surface
	cx#=(KeyDown(205)-KeyDown(203))*cameraspeed
	cz#=(KeyDown(200)-KeyDown(208))*cameraspeed
	moz#=cz*1.0/(c2)^3
	mox#=cx*1.0/(c2)^3
	MoveEntity cam,mox,0,moz
	
	; simple background color change in atmosphere
	bg#=1-(1.0/c2)
	If bg<0 Then bg=0
	If bg>1 Then bg=1
	CameraClsColor cam,160*bg,192*bg,255*bg
	
	RenderWorld
	
	WaitTimer timer
	
	Flip 0
	
Wend

End

; Smoothcam
Function CurveValue#(newvalue#,oldvalue#,increments )
	If increments>1 oldvalue#=oldvalue#-(oldvalue#-newvalue#)/increments
		If increments<=1 oldvalue=newvalue
			Return oldvalue#
End Function

; The functions that creates the ring
Function CreateRing(radius1#=1.0,radius2#=2.0,segments%=360,fx%=0,blend%=0,r1%=255,g1%=255,b1%=255,alpha1#=1.0,r2%=0,g2%=0,b2%=0,alpha2#=1.0,scale#=0.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	Local v0%,v1%,v2%,v3%
	
	Local mesh=CreateMesh()
	Local surf=CreateSurface(mesh)
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),radius1*Sin(a1),0,0,0)
		v1=AddVertex(surf,radius1*Cos(a2),radius1*Sin(a2),0,0,0)
		v2=AddVertex(surf,radius2*Cos(a3),radius2*Sin(a3),scale,1,1)
		v3=AddVertex(surf,radius2*Cos(a4),radius2*Sin(a4),scale,1,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,alpha1
		VertexColor surf,v1,r1,g1,b1,alpha1
		VertexColor surf,v2,r2,g2,b2,alpha2
		VertexColor surf,v3,r2,g2,b2,alpha2
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	If fx>0 Then EntityFX mesh,fx
	If blend>0 Then EntityBlend mesh,blend
	
	Return mesh
	
End Function

; Re-creates the ring vertices and triangles with different values
Function UpdateRing(mesh%,radius1#=1.0,radius2#=2.0,segments%=360,r1%=255,g1%=255,b1%=255,alpha1#=1.0,r2%=0,g2%=0,b2%=0,alpha2#=1.0,scale#=0.0)
	
	Local a1#,a2#,a3#,a4#,angle%
	Local v0%,v1%,v2%,v3%
	
	Local surf=GetSurface(mesh,1)
	ClearSurface surf,1,1
	
	; Limit segments
	If segments>360 Then segments=360
	
	; Create ring
	For angle=1 To segments
		
		a1=angle*360.0/segments
		a2=angle*360.0/segments +360.0/segments
		a3=angle*360.0/segments +180.0/segments
		a4=angle*360.0/segments -180.0/segments
		
		; Calc vertex points
		v0=AddVertex(surf,radius1*Cos(a1),radius1*Sin(a1),0,0,0)
		v1=AddVertex(surf,radius1*Cos(a2),radius1*Sin(a2),0,0,0)
		v2=AddVertex(surf,radius2*Cos(a3),radius2*Sin(a3),scale,1,1)
		v3=AddVertex(surf,radius2*Cos(a4),radius2*Sin(a4),scale,1,1)
		
		; Color
		VertexColor surf,v0,r1,g1,b1,alpha1
		VertexColor surf,v1,r1,g1,b1,alpha1
		VertexColor surf,v2,r2,g2,b2,alpha2
		VertexColor surf,v3,r2,g2,b2,alpha2
		
		; Create Triangles
		AddTriangle surf,v2,v1,v0
		AddTriangle surf,v0,v3,v2
		
	Next
	
	Return mesh
	
End Function

Beautiful. Great work, Krischan! Very impressive.

Of course what you have shown is purely a demo, and maybe you have considered this already, but I was wondering if it's worth using HideEntity when the 'atmosphere' is not visible? I guess this really depends on how many planets and what other stuff is going on at the time, either way, I really like what you have done here!

It is only a tech demo. Do whatever you want with it, improve it and let us share if you think it is usable for others. I was only disappointed that I didn't found a nice and elegant solution for my atmosphere problem - so i coded my own. My solution is not the best or even physically correct, but my planet looks much nicer now and if I ever consider to implement some kind of "landing on the planet" feature this is the way I can go now.

I really enjoyed the game Starflight years ago where you could land on a planet and drive around to collect things from the surface. The GFX is a big laugher today but the gameplay and the imagination balanced everything. Later - Frontier was THE procedural game (until today?) but it was boring and too exact. Infinity looks very promising and i hope that it won't be a blown up Frontier without a challenging gameplay (if we'll ever see it).

It has to make fun, fun and fun again. Who cares about lit nightsides? We had a lot of fun with 64K/16 color games only a few years ago, and often even more fun than in some games today.

And if you never played Starflight go and get an Amiga Emulator, the ADF and play it. You really missed something -> Screenshots

I'm old enough (and ugly enough) to fondly remember Elite. Yeah, Frontier was a nice change moving from the speccy to the Amiga and getting all those colours, but just... too much overkill on the physics ;)

I don't recall Starflight, though, but I'm sure it was grand!

I was working on something similar to Elite with beng able to land on planets and including various land-based 'factories' etc. but as my coding improved I have scrapped a lot of previous attempts, and am now concentrating more on planning other aspects before I hit it again. However, I'm sure stuff like this will be a great addition. It's an open-source plan, so hopefully I'll have some useful routines in return especially seeing as the two projects appear to have some similarities.