Heat Distortion

Hi All,

I am considering adding a "Heat Distortion" effect to my FPS and was wondering what the best approach may be.

I have a couple of Armoured tanks that leave their detroyed remains on the terrain for some time. I would like the remnants to show a refractive effect in the atmospehe just above the wreck (3 to 5 feet?)

My immediate thought is a Quad that always faces the cam. Beyond this, I need some suggestions. I am looking for a subtle distortion ....less is more etc.

This is a water distortion, maybe it helps somewhat:
http://www.blitzmax.com/codearcs/codearcs.php?code=1693

Look up the fast extend library. This can do that effect alot quicker.

Woo somewhere to add this..

I found on Grand Theft Auto San Andreas that if you're at CJ's house (not sure if it's anywhere else) and are high up and look down at the street, you can see transparent squares (look like sprites) rising up to simulate a hot road effect.

Warner; Thats a full screen distort and while nice, isnt practical for me as I need to isolate only a small part of the screen for the heat distort. (just above my tanks)

Ross; I sort of follow (fast extend library) but cant really see how to attack this. Do you know of any examples of partial screen distortion? Would it cause a real slowdown even if it works?

Anyhow Ross, if you have time, could you explain the principals (dumb it down a little) so I can get my head around the theory of what needs to be done to acheive this effect.


Perhaps some heat haze coming off a desert plane would be a better start. I am not sure. Surely someone has acheived this effect.

Hmm, there was once a thread of a guy that developed a quite simple Heat post-screen effect...

Ah! here it is, was searching on my HD. Just copy and paste this s*** and see if that's what you're looking for:

;----- Heat Distortion Effect by Roland Ludlam ------
;----- web: <a href="http://www.sover.net/~ardeo" target="_blank">http://www.sover.net/~ardeo</a>        ------
;----- e-mail ardeo@...                  ------

;----- I'm new to blitz and coding in general  ------
;----- So forgive my messy code!  any comments ------
;----- or suggestions for optimization or      ------
;----- other solutions are welcome!            ------
;-----                                         ------
;-----                thanks!  roland          ------
;----------------------------------------------------


Graphics3D 640,480,0

SeedRnd MilliSecs()

;----- create main scene camera ------
Global cam = CreateCamera()
CameraProjMode cam,1
CameraRange cam,.01,1000
PositionEntity cam,0,10,-20

;----- create effect camera ------
Global cam2 = CreateCamera()
PositionEntity cam2,0,10,-20
CameraViewport cam2,0,0,256,256
CameraProjMode cam2,0
CameraRange cam2,.01,1000

l=CreateLight()

;----- texture globals ------
Global texmove#=0
Global angle# = 0
Global angle2# = 0
Global texscale#=.978999
Global texscaley# =1.041
Global texx#=.0109977
Global texy#=-.023003

;----- globals to control the distortion effect ------
Global distamount# = 1
Global distalpha# = 1

;----- sin or random distortion? set to 1 for sin and 0 for random ------
Global sinewave = 1



;----- create blank texture to use later ------
Global imagetex = CreateTexture(256,256,256)


;----- load up or lava textures ------
Global lavatex = LoadTexture("lava.bmp")
ScaleTexture lavatex,300,300
Global explosion = LoadTexture("lava3.tga",1)
ScaleTexture explosion,500,500


;----- initialize types: vert is for displacement / distortion ------
Type vert
	Field x#
	Field y#
	Field z#
	Field num
	Field a#
	Field distance#

End Type

Type box
	Field entity
End Type


;----- load textures onto planes (just for fun) ------
Global plane = CreatePlane()
PositionEntity plane,0,-5,0
EntityTexture plane,lavatex
EntityFX plane,1

Global plane2 = CreatePlane()
EntityBlend plane2,3
EntityTexture plane2,explosion
EntityFX plane2,1


;----- load mesh to use as distortion sprite ------
Global dist = LoadMesh("plane.x",cam2)
PositionEntity dist,0,0,.1
ScaleEntity dist,.0256,.0256,.0256
RotateEntity dist,90,0,0
EntityFX dist,1
EntityTexture dist,imagetex
Global distsurf = GetSurface(dist,1)
Global vnum = CountVertices(distsurf)

;----- scale texture to match sprite... ------
ScaleTexture imagetex,texscale,texscaley
PositionTexture imagetex,texx,texy

;----- convert vertices to types for easy access ------
For a=0 To vnum-1
	v.vert = New vert
		v\num = Int(a)
		v\x = VertexX#(distsurf,a)
		v\y = VertexY#(distsurf,a)
		v\z = VertexZ#(distsurf,a)
		v\a = Rnd(0,360)	
Next


;----- place some boxes to show off effect better ------
For i=0 To 10
	b.box = New box
	b\entity = CreateCube()
	PositionEntity b\entity,Rnd(-20,20),Rnd(0,20),Rnd(-20,20)
Next


;----- main loop ------
While Not KeyHit(1)


;----- make the boxes move ------
For b.box = Each box
	TurnEntity b\entity,1,1,1
Next 


;----- call heatdist function ------
heatdist()

;----- make the textures on the planes move ------
texturemove()


;----- keys to change the effect if you want to. ------
If KeyHit(2) Then sinewave = 1
If KeyHit(3) Then sinewave = 0
If KeyHit(4) Then sinewave = 2

If KeyDown(200) Then distamount = distamount+.025
If KeyDown(208) Then distamount = distamount-.025

If KeyDown(203) Then distalpha = distalpha-.01
If KeyDown(205) Then distalpha = distalpha+.01

If distalpha <=0 Then distalpha = 0

UpdateWorld
RenderWorld

Text 0,0,"1 / 2 toggle sine / random"
Text 0,12,"up and dn +/- distortion"
Text 0,24,"lft and rt +/- effect alpha"

Flip True
Wend


;----- heat distortion function ------
Function heatdist()

;----- first we render the screen to texture. change the alpha of dist for more / less blur ------
	EntityAlpha dist,.8*distalpha
	CameraProjMode cam,0
	CameraProjMode cam2,1
	RenderWorld
	CopyRect 0,0,256,256,0,0,BackBuffer,TextureBuffer(imagetex)


;----- then switch back to regular camera and modify vertices for distortion effect. ------
	CameraProjMode cam2,0
	CameraProjMode cam,1
	ShowEntity dist
	EntityAlpha dist,.6*distalpha
	For v.vert = Each vert
		v\a=v\a+5
		If v\a>=360 Then v\a = 0

;----- displace vertices.  use sine or straight up random distortion? ------
		If sinewave = 0 Then VertexCoords(distsurf,v\num,v\x,v\y,v\z+(Rnd(-.08*distamount,.08*distamount)))	
		If sinewave = 1 Then VertexCoords(distsurf,v\num,v\x,v\y,v\z+((Sin(v\a)/(30/distamount))))
		If sinewave = 2 Then VertexCoords(distsurf,v\num,v\x+((Sin(v\a)/(30/distamount))),v\y,v\z)
	Next

End Function

;----- moves the textures on the ground planes.  just for show. ------
Function texturemove()
	angle = angle+.5
	If angle >=360 Then angle = 0
	angle2 = angle2+.1
	If angle2 >=360 Then angle2 = 0
	PositionTexture lavatex,(Sin(angle)/5),0
	RotateTexture lavatex,angle2
	texmove = texmove+.001
	PositionTexture explosion,texmove,0
End Function

End

@Ross C: Boy you are sure advertising the hell out of fastlibs throughout the forums! are you getting something for it?...

Cheers Rafael.

As I dont have those textures or *.X model, will take this home and have a squiz.

Thanks for the effort man!

HOW GOOD ARE FRIDAYS?

Holy damn, sorry man. Forgot about that :P

Here's the full Zipped source with the media it uses...

http://www.geocities.com/rafael_nvg/rl_heatdistortion.zip

Good luck...

PS: You could make only a certain spot of the screen to have this effect, by making the overlay plane (the one which you go and CopyRect to) have multiple segments, and then using Vertex Alpha to hide the vertices that are not "covering" the parts you don't want the effect to happen.

I'm not getting anything for it :o) I just think it should be an essential add on for blitz3d. It has so many useful commands. Spped enhancements and seems to be very stable. I think alot of people would benefit from the lib. But not many people seem to be using it, so i'm trying to get word of it out.

People keep saying blitz3d is old tech, which is true, but the lib breathes some more life, graphically, into it.

Yeah I thought of that later on...it's just that I just wanted to pay for Blitz3D and do whatever I can with it, the rest, I can find in the Code Archives and\or generous Devils Child's engines.


Precisely, it gives more freedom to develop the game you really want.

try my shader engine at
http://stuff.dev-ch.de/

Thanks to all who contributed to this post. However, I think providing me with links and suggetions to use this - use that, are valid, but are not going to teach me anything.

A good example is Devils Child's stuff. Amazing stuff to say the least. Your stuff in maxes out B3D..So much more advanced that anything I could produce at the moment... But way too complex! I wouldnt know where to start!

I am requesting the principal (or Theory) only. I am not asking for code or Zips etc. (perhaps a line or 2 of code would help)

So, I will start things rolling....(can we start again?)

Simple Heat Distortion: (Air Buckling effect)- Theory Of Operation;

1) Place a Quad in the area you want to distort. (Partial Screen Distort)

2) Grab that area of the screen (copy rect?)

3) Process (manipulate the pixels) the PARTIAL screen grab and send it to a texture? Buffer?

4) Display the final result over the heat source.

Thats all I have...any thoughts on this approach? I am sure there are DLL's and all sorts of solutions to this issue....but would rather tackle it myself from the perspective of understanding - and not speedy short-cuts....that can come later when I have my head around the basic principals themselves.

Phew!

What happens is that if you really really wanted to learn instead of us just giving you the answer, you would've looked inside the source in the Zip code I gave you, studied it, and then learned the answer to the question you made just now.

"Any thoughts on this approach" - Look the damn zip! it HAS a FUNCTIONAL version of what you want, using the steps you described. It would never be a shortcut, unless you simply Copy-"pasta" the thing into your game\engine. Rather, look at the code and go find out for yourself the answers - look what the code does, learn from it, improve it if you can, and then apply to whatever end. That's how we all learned ( as well as the guy who created the example in the first place! ).

A DLL is probably the only way you will be able to do this effect at any speed.