Default ShouldCollide Method in Box2d Problem

Sorry - I seem to be needing a lot of help lately. What should the default ShouldCollide method be?. I want to implement my own Contact Filter. I wanted to use the standard(default) 'ShouldCollide' method, but add an extra condition to it - of my own. To start with I am just trying to replicate the existing method. I want to get this working before I add anything. I am using this (from the documentation)

Local filter1:b2FilterData = shape1.GetFilterData()
Local filter2:b2FilterData = shape2.GetFilterData()
	
If filter1.GetGroupIndex() = filter2.GetGroupIndex() And filter1.GetGroupIndex() <> 0
      Return filter1.GetGroupIndex() > 0
End If
	
Local collide:Int = (filter1.GetMaskBits() & filter2.GetCategoryBits()) <> 0 And (filter1.GetCategoryBits() & filter2.GetMaskBits()) <> 0
Return collide

However I get an ''unhandled' memory exception error' I tried it with commenting bits out and the first thing that makes this happen is the filter2.GetGroupIndex(). The equivalent with filter1 works fine. Can someone help me with this? Thank you.

I still have this problem. It is definitely a problem with Shape2 - I can't get this to work the TestBed examples either, so I don't think it is me doing something wrong.


It doesn't crash doing this. (this is just an example to show the problem)

Method ShouldCollide:Int(shape1:b2Shape, shape2:b2Shape)
                Local bd:b2Body=shape1.GetBody()
                Return False
EndMethod

but if i try to do anthing with Shape2 it doesn't like it

Method ShouldCollide:Int(shape1:b2Shape, shape2:b2Shape)
                Local bd:b2Body=shape1.GetBody()
                Local bd2:b2Body=shape2.GetBody()
                Return False
EndMethod

I now get an unhandled memory exception.

Does anyone else get this?

I added this to the collisionfiltering example :

Type myfilter Extends b2ContactFilter
	Method ShouldCollide:Int(shape1:b2Shape, shape2:b2Shape)
	DebugLog "shape1 : " + (shape1 <> Null) + " : shape2 " + (shape2 <> Null)
	
	Local filter1:b2FilterData = shape1.GetFilterData()
Local filter2:b2FilterData = shape2.GetFilterData()
	
If filter1.GetGroupIndex() = filter2.GetGroupIndex() And filter1.GetGroupIndex() <> 0
      Return filter1.GetGroupIndex() > 0
End If
	
Local collide:Int = (filter1.GetMaskBits() & filter2.GetCategoryBits()) <> 0 And (filter1.GetCategoryBits() & filter2.GetMaskBits()) <> 0
Return collide

'		Return True
	End Method
End Type

with this line after the Init(20, 20)

m_world.SetFilter(New myfilter)

and it gave me this output :

Executing:collisionfiltering.debug
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1
DebugLog:shape1 : 1 : shape2 1

and no crashing... on MacOS with the latest from SVN.

From what I can see looking through the source, shape2 should never be null. If it was, then you'd get an exception in the internal code.

One thing you might try is removing the .bmx folders from the module and doing a Build Modules. (or doing something like bmk makemods -a bah.box2d from the console), or Rebuild Modules (except that will do them all).

I'll try the same code on Win32 tomorrow morning.

I have done exactly the same thing that you did Brucey with the CollisionFiltering example, and I got exactly the same results as you.
I then copied exactly the same code into my program, and i got the same error as before. At least I know it must be something I'm doing now. I've no idea what (yet). The thing is - is that shape2 isn't coming up as NULL. I can do shape2.GetFilterData() without an error, but I can't do shape2.GetFilterData().GetGroupIndex() without an error for example. In fact I can't seem to do anything else on Shape2.

Thank you for your help Brucey. I will let you know what was wrong when I find out.

Rico

Is the filter from Shape2 Null or not?

If not, then there's perhaps some corruption somewhere - although you'd expect to see that problem in my posted code above also, if there was.

If you can put a very small example together, it might help track it down.

Hi Brucey!

I have found out what causes the problem. It is when shapes overlap - at least when they are first created. I got an 'unhandled memory exception' in the collisionFiltering example by setting the large box's position so that it overlapped the smaller box.

This error never occurs if you don't override the ShouldCollide Method, so somethings going wrong.

Also in the CollisionFiltering example I edited it so that if you press a key then a square box shape appears at the mouse cursor position. If you make this shape appear over an existing shape then the 'unhandled memory exception' error occurs. This is a problem because it seems like the shapes themselves don't have to be overlapping for this error to occur, they just need to be very close - so maybe its the bounding boxes overlapping that causes the problem?

Do you know if there is a way to use the ShouldCollide method so that things behave normally? The filterdata is coming up as not Null.

Thanks Brucey for the help - Rico.

Brucey - Yes there is definitely a problem. Can you check to see if you also have the same problem. I wonder if is a problem with Box2D or the Blitz wrapper?

Here is what I am having trouble with

1. If you create a new body and its shape is overlapping another body's shape then I get an unhandled memory exception' error. This only happens if you implement your own Contact Filter. If you use the defauly system shapes can happily overlap on creation

2. if you create a shape+body and it overlaps another objects AABB then the same error occurs. This means you can't create a shape next to a slope of a triangle for instance - even if the actual shapes aren't actually overlapping. Again this only happens when implementing a ContactFilter.

Please note these problem only seem to happen when the object is first created, not at any other time. I could see a solution would be to create an object offscreen and then manually place it at a seperate position. But this is not really satisfactory. Would you mind checking to see if you also have the above problems?

Thank you very much - Rico

Hi Rico, this is a modified collisionfiltering example :

SuperStrict

Framework BaH.Box2d
Import BRL.GLMax2D

Import "test.bmx"


Graphics 800,600, 0
SetBlend alphablend


Run(New CollisionFiltering.Create(), New TSettings)


Type CollisionFiltering Extends Test

	' This is a test of collision filtering.
	' There is a triangle, a box, and a circle.
	' There are 6 shapes. 3 large and 3 small.
	' The 3 small ones always collide.
	' The 3 large ones never collide.
	' The boxes don't collide with triangles (except if both are small).
	Const k_smallGroup:Short = 1
	Const k_largeGroup:Short = -1
	
	Const k_defaultCategory:Short = $0001:Short
	Const k_triangleCategory:Short = $0002:Short
	Const k_boxCategory:Short = $0004:Short
	Const k_circleCategory:Short = $0008:Short

	Const k_triangleMask:Short = $FFFF:Short
	Const k_boxMask:Short = $FFFF:Short ~ k_triangleCategory
	Const k_circleMask:Short = $FFFF:Short

	Method Create:CollisionFiltering()

		Init(20, 20)
m_world.SetFilter(New myfilter)
	
		Local ground:b2Body
		
		Local sd:b2PolygonDef = New b2PolygonDef
		sd.SetAsBox(50.0, 10.0)

		Local bd:b2BodyDef = New b2BodyDef
		bd.SetPosition(New b2Vec2.Create(0.0, -10.0))
		ground = m_world.CreateBody(bd)
		ground.CreateShape(sd)
		
		
		' Small triangle
		Local triangleShapeDef:b2PolygonDef = New b2PolygonDef

		Local vertices:b2Vec2[] = New b2Vec2[3]
		vertices[0] = Vec2(-1.0, 0.0)
		vertices[1] = Vec2(1.0, 0.0)
		vertices[2] = Vec2(0.0, 2.0)

		triangleShapeDef.SetVertices(vertices)
		triangleShapeDef.SetDensity(1.0)

		' modify the def's filter
		triangleShapeDef.GetFilter().SetGroupIndex(k_smallGroup)
		triangleShapeDef.GetFilter().SetCategoryBits(k_triangleCategory)
		triangleShapeDef.GetFilter().SetMaskBits(k_triangleMask)

		Local triangleBodyDef:b2BodyDef = New b2BodyDef
		triangleBodyDef.SetPositionXY(-5.0, 2.0)

		Local body1: b2Body = m_world.CreateBody(triangleBodyDef)
		body1.CreateShape(triangleShapeDef)
		body1.SetMassFromShapes()


		' Large triangle (recycle definitions)
		vertices[0].Multiply(2.0)
		vertices[1].Multiply(2.0)
		vertices[2].Multiply(2.0)
		triangleShapeDef.SetVertices(vertices)
		
		triangleShapeDef.GetFilter().SetGroupIndex(k_largeGroup)
		triangleBodyDef.SetPositionXY(-5, 6.0)
		triangleBodyDef.SetFixedRotation(True) ' look at me!

		Local body2:b2Body = m_world.CreateBody(triangleBodyDef)
		body2.CreateShape(triangleShapeDef)
		body2.SetMassFromShapes()

		
		' Small box
		Local boxShapeDef:b2PolygonDef = New b2PolygonDef
		boxShapeDef.SetAsBox(1.0, 0.5)
		boxShapeDef.SetDensity(1.0)

		' create our own filter object
		Local filter:b2FilterData = New b2FilterData
		filter.SetGroupIndex(k_smallGroup)
		filter.SetCategoryBits(k_boxCategory)
		filter.SetMaskBits(k_boxMask)

		boxShapeDef.SetFilter(filter)
		
		Local boxBodyDef:b2BodyDef = New b2BodyDef
		boxBodyDef.SetPositionXY(0.0, 2.0)

		Local body3:b2Body = m_world.CreateBody(boxBodyDef)
		body3.CreateShape(boxShapeDef)
		body3.SetMassFromShapes()
		
		
		' Large box (recycle definitions)
		boxShapeDef.SetAsBox(2.0, 1.0)
		boxShapeDef.GetFilter().SetGroupIndex(k_largeGroup)
		boxBodyDef.SetPositionXY(0.0, 6.0)

		Local body4:b2Body = m_world.CreateBody(boxBodyDef)
		body4.CreateShape(boxShapeDef)
		body4.SetMassFromShapes()

		
		' Small circle
		Local circleShapeDef:b2CircleDef = New b2CircleDef
		circleShapeDef.SetRadius(1.0)
		circleShapeDef.SetDensity(1.0)

		filter = New b2FilterData
		filter.SetGroupIndex(k_smallGroup)
		filter.SetCategoryBits(k_circleCategory)
		filter.SetMaskBits(k_circleMask)
		
		circleShapeDef.SetFilter(filter)

		Local circleBodyDef:b2BodyDef = New b2BodyDef
		circleBodyDef.SetPositionXY(5.0, 2.0)
		
		Local body5:b2Body = m_world.CreateBody(circleBodyDef)
		body5.CreateShape(circleShapeDef)
		body5.SetMassFromShapes()

		
		' Large circle
		circleShapeDef.SetRadius(circleShapeDef.GetRadius() * 2.0)
		circleShapeDef.GetFilter().SetGroupIndex(k_largeGroup)
		circleBodyDef.SetPositionXY(5.0, 6.0)

		Local body6:b2Body = m_world.CreateBody(circleBodyDef)
		body6.CreateShape(circleShapeDef)
		body6.SetMassFromShapes()
		
		Return Self
	End Method

	Method Keyboard()
		Super.Keyboard()
	
		If KeyHit(KEY_SPACE) Then
			' Small box
			Local boxShapeDef:b2PolygonDef = New b2PolygonDef
			boxShapeDef.SetAsBox(1.0, 0.5)
			boxShapeDef.SetDensity(1.0)
	
			Local boxBodyDef:b2BodyDef = New b2BodyDef
			boxBodyDef.SetPosition(ConvertScreenToWorld(MouseX(), MouseY()))
	
			Local body3:b2Body = m_world.CreateBody(boxBodyDef)
			body3.CreateShape(boxShapeDef)
			body3.SetMassFromShapes()

		End If
		
	End Method

End Type

Type myfilter Extends b2ContactFilter
	Method ShouldCollide:Int(shape1:b2Shape, shape2:b2Shape)
	
		Local filter1:b2FilterData = shape1.GetFilterData()
		Local filter2:b2FilterData = shape2.GetFilterData()
	
		If filter1.GetGroupIndex() = filter2.GetGroupIndex() And filter1.GetGroupIndex() <> 0
 			Return filter1.GetGroupIndex() > 0
		End If
	
		Local collide:Int = (filter1.GetMaskBits() & filter2.GetCategoryBits()) <> 0 And (filter1.GetCategoryBits() & filter2.GetMaskBits()) <> 0
		Return collide

	End Method
End Type

Press SPACE to create a small box under the mouse location.

I can seemingly create them anywhere I like without any problems.
Does this work for you too, or do you get a crash somewhere?

Or, modify it appropriately and put the crashing version here :-)

If I try to create a box on top of another box it crashes every time.

I've also tried my above example on Win32 also (originally tested on Mac), and it seems to work for me still.

Yes I'm afraid it crashes for me - in the same way I described before. Hmm, do you think its my version? I am using the most recent release version, not the most recent SVN one.
I might try installing it again - I didn't before - because I got your previous example working, so I assumed that everything was ok.

Strange. It might well be something in the latest version that is fixed in box2d.
But I'll do a rebuild of the module and try it again, just in case it was a fluke for me ;-)

I also am using the most recent release (non-SVN) version on a Mac. It could be this release build, as I assume you are using the latest SVN version Brucey. ;)

Okay. So we'll assume that the latest code is fine. I'm just adding some new types/methods to it, and then I'll hopefully have a new release out shortly.

Box2D 1.03 release is now available from the Downloads area.

Summary :
* Updated to box2d svn (rev 172)
* Added b2CircleShape and b2PolygonShape types.
* Added b2OBB type.
* Added b2Segment type.
* Added b2World Raycast(), RaycastOne() and InRange() methods.
* Added b2Body.GetWorld() method.
* Added raycast example.

Please let me know if that resolves your problem.

Note that you should perform a non-Quick compile of your application after building the new module to ensure your binary is up-to-date.

:o)

Thanks Brucey - that looks good. I downloaded the new module, but I am having trouble building it. It no longer has .bmx code in it like before. I always used to go to the command prompt, set the 'bin' directory and type 'bmk makemods bah.box2d' and it would compile the files. What do I need to do now?
I have never been able to use the Build Modules option on the IDE - because its always ghosted out.

Thanks

I just downloaded it and it looks fine from here. there is a box2d.bmx in the box2d.mod folder.

That folder goes in place of the one in the BlitzMax/mod/bah.mod folder.


I expect that option is ghosted out because you don't have the MINGW environment variable set (to the folder where you have mingw).

Thanks Brucey! I'm having fun messing around with Box2D; currently deciding whether to use it, Chipmunk, or Farseer for my actual project. :)

Yes. Its fine for me now. I have no idea how that happened! I downloaded it again and it was fine!

I did set the MINGW environment variable in the control panel area somewhere (you can tell I am not very technical), when I first installed it. It is probable I set it wrong though - so I will check it out.

Thank you very much Brucey - for all the help - and the new version. I reallt needed Raycasts, for line-of-sight tests, so I am very happy! Thank you!