Setting Resolution

What commands allow the program to set the resolution of the computer?

Jason

For a full-screen game, or for the desktop itself when running a GUI app?

If you're talking about full screen graphics: simply specify the resolution you want in the GRAPHICS command, and it will switch to that resolution:

graphics 640,480,32,60 -> 640x480x32-bit color at 60 Hz. (The Hz is optional)

If you're talking about the resolution for the desktop, then you probably need to interface with the windows API directly to get it to do that.

I am talking about setting the game to a specific resolution with the graphics command and then changing the viewers monitor to match the resolution so it is full screen.

I am currently using the graphics command to set the screen size less then the resolution I am using on the monitor but it is not changing the monitors resolution so the game screen is full screen.

Jason

You need to make sure you set a compatible bit depth, the third parameter of the Graphics command. If you don't set it, or if you set it to a value the graphics card does not support, then you might end up with a windowed screen instead of fullscreen.
Example:
Graphics 640,480 <- creates a 640x480 window on the desktop
Graphics 640,480,32 <- sets the monitor to 640x480x32 and makes a window fullscreen

Oh -- something else that just occured to me: When you say that it's not full screen: do you mean that is actually running inside of a window on the desktop, or that the image is taking up just part of the screen with black borders around it?

If the latter, then it's a restriction of the video drivers on the computer in question. I've seen some laptops where the drivers force the native pixel resolution rather than stretching the image to the edge of the screen. Could be either a setting in the video drivers, or an option in the computer BIOS.

(On a few laptops, it's not possible to change that behaviour)

If you *do* see the windows desktop behind your game then you're missing the 3rd parameter of the graphics command:

graphics 640,480,32,60

the '32' specifies that you want 32 bit. Other options are '16', '24' (depending on your video card) and '0'. If you choose 0 then it will run the program in a window.

I was seeing the windows in the background arround the edges of the window. Changing the third option to 16 or higher fixed it so it is now full screen.

I want the program to run at full screen with windows, linux and the mackintosh. Which bit setting should I use to get a full screen on the most computers on all operating systems?

Also, is there a way to have the program check which bit settings are available on their video card and then have it sellect the bit setting appropriate for their card?

Jason

Yes, you can check ... and it's all in the built-in documentation under Modules > Graphics! Anyway, the following is a little program I wrote a while ago, which simply lists all available modes, unique resolutions, bitdepths, and so on. It's a little over-complicated for your needs, but it should answer your questions.

Strict

Local modeCount=CountGraphicsModes()

Local gfxRes:Int[32,2],gfxResCnt:Int=0	' holds all possible resolutions
Local gfxDep:Int[4],gfxDepCnt:Int=0		' holds all possible bit depths above 8bpp
Local gfxHtz:Int[16],gfxHtzCnt:Int=0	' holds all possible refresh settings

Print
Print "No. of graphics modes: "+modeCount
Print

Local scrWidth,scrHeight,scrDepth,scrHertz

For Local i=0 Until modeCount
	GetGraphicsMode(i,scrWidth,scrHeight,scrDepth,scrHertz)
	Print RSet(scrWidth,4)+" x "+RSet(scrHeight,4)+" x "+RSet(scrDepth,2)+" bpp @ "+RSet(scrHertz,3)+" hz"
	' see if resolution has already been counted
	Local found:Int=False
	If gfxResCnt Then
		For Local j=0 Until gfxResCnt
			If scrWidth=gfxRes[j,0] And scrHeight=gfxRes[j,1] Then
				found=True
				Exit
			EndIf
		Next
	EndIf
	If Not found Then
		gfxRes[gfxResCnt,0]=scrWidth
		gfxRes[gfxResCnt,1]=scrHeight
		gfxResCnt:+1
	EndIf
	' check if depth already found
	found=False
	If gfxDepCnt Then
		For Local j=0 Until gfxDepCnt
			If scrDepth=gfxDep[j] Then
				found=True
				Exit
			EndIf
		Next
	EndIf
	If Not found Then
		gfxDep[gfxDepCnt]=scrDepth
		gfxDepCnt:+1
	EndIf
	' check if hertz already found
	found=False
	If gfxHtzCnt Then
		For Local j=0 Until gfxHtzCnt
			If scrHertz=gfxHtz[j] Then
				found=True
				Exit
			EndIf
		Next
	EndIf
	If Not found Then	
		Local pos=0
		If gfxHtzCnt Then
			While scrHertz>gfxHtz[pos] And pos<gfxHtzCnt
				pos:+1
			Wend
			If pos<>gfxHtzCnt Then
				For Local j=gfxHtzCnt-1 To pos Step -1
					gfxHtz[j+1]=gfxHtz[j]
				Next
			EndIf
		EndIf		
		gfxHtz[pos]=scrHertz
		gfxHtzCnt:+1
	EndIf
Next

Print
Print "No. of resolutions supported: "+gfxResCnt
Print
For Local i=0 Until gfxResCnt
	Local ratio:Float=Float(gfxRes[i,0])/gfxRes[i,1]
	Print RSet(gfxRes[i,0],4)+" x "+RSet(gfxRes[i,1],4)+"  Ratio "+Left(ratio,4)+":1"
Next

Print
Print "No. of bit depths supported: "+gfxDepCnt
Print
For Local i=0 Until gfxDepCnt
	Print RSet(gfxDep[i],2)+" bpp"
Next

Print
Print "No. of refresh rates available: "+gfxHtzCnt
Print
For Local i=0 Until gfxHtzCnt
	Print RSet(gfxHtz[i],3)+" hz"
Next

Basically, the commands you're looking for are CountGraphicsModes() and GetGraphicsModes(). Be aware though that some graphics drivers return a Hz setting as 0! In which case, you'll have to assume these are 60, which is safe.

Hope it helps.