Full WinBlitz3D FREE

Hi Guys

Ive now made available for free the full unrestricted version of winblitz3d.

If you find winblitz3d useful then all donations welcome :)

click the winblitz3d link below to download.

*EDIT: new version now available, same download link.

WHATS NEW?
some bug fixes.

kev

Nice one cheers. That tank game looks familiar :)

Yes, it's had quite an adventure lately :)
Hmm... I should have kept the News page out of that screenshot. I guess a more Internet-ish thing there would look odd, though, since that web browser window is not actually done by WB3d. (Which is, in my opinion, a very cool thing; using a native GUI API, a DLL can create any gadget it wants and just throw it onto your program).


Nice work, Kev!

I like the web site. It's simple but effective.
Maybe the border at the top could be widened a bit, though, because the images at the bottom are wider than it.

I'll be watching to see where this goes.
WB3d is a very well made system, so I'm sure it will go far.

Very generous, thanks Kev!

Thank you very much...earlier today I downloaded the lite version LOL

i didn't know where i could get winblitz3d until now.

does anyone know what blitz3d programs are using winblitz3d?

how does it work?

The ones at the bottom on that page, the best simulator ever made, and a few others :)

hmm, thanks.

i know of the "grasshopper web plugin system" (because it's in your sig)
but what is "life-studio 2006"?
and "3d photo gallery"? i think that's what it says.

why no links to these programs? it's a little odd isn't it?

They are both projects being worked on by folks who beta tested the system.

There is also a GUI editor written using Wb3d, I believe...

oh i forgot. thanks Kev! very generous! :)

Well done Kev!

I will try and finish the WB3D GUI Editor ( SCHNOK! ) over the weekend. There's a small bug I got to kill and write some basic docs.
(The Life Editor was made using this editor)

Here's a screenshot showing some of it's functions like gadget properties, style editing, font manager, etc.
It exports the gui straight to BB code in different ways and formats depending your need/style:

www.xs4all.nl/~dendanny/SCHNOK/schnok.v0.90.jpg

Danny

Great! Just in time for my project! I sent you a small donation, keep it alive, it's great library!

thanks guys, for people that made a donation its much appreciated.

thank you

kev

Gives me a 404 when I click "download". Any chance to get it? If I'll win in Lottery, I'l make a donation, promised! (Until then I can only offer you a beer or two).

I have made Texture Wobbler (sig) with an older version of Winblitz3D. Great work, thanks.

ok, this seems to be the problem: your page links to:
http://www.winblitz3d.co.uk/www.winblitz3d.co.uk/wb3d_1.zip

where it should be
http://www.winblitz3d.co.uk/wb3d_1.zip

Or maybe my browser has bugs :/

EDIT: Wah! now both give me a 404! What's going on here?

odd, try this
http://www.winblitz3d.co.uk/winblitz3d.zip

This is a tremendous add on for Blitz3d - Very well done Kevin and all the Beta testers - superb job and very generous. Donation on its way - I hope all that use it will contribute as well so you can keep working on this excellent lib.

Thanks muk!

Thanks alot kev, very generous of you. Im gonna switch to this now in my editor :P

EDIT: sorry, was thanking muk instead kev for some reason :)

I just noticed that when I try and set style for a gadget other than default the gadget gets created in its own little window instead of on the parent - if you try to set the style after creation using
WB3D_SetGadgetStyle%(gadget%,style%)
The gadget dissapears altogether ?!?
What am I doing wrong ?

:o

Hmm... us this a totally custom style?

If so, try adding WS_CHILD to that.
That style tells the window to put itself within its parent window, because otherwise it won't for some reason.

@Smiff what Mr. Picklesworth said is correct for gadgets to be children there style must include WS_CHILD.

For the gadgets to be drawn correct i would recommend using WS_CLIPCHILDREN and WS_CLIPSIBLINGS styles also.

kev

Danny, what you've done really hammers home what WinBlitz3D is all about - the only possible solution for an editor-type app.

Kev - brilliant work, mate.

That worked fine - thanks !
I must say this is very easy to integrate.

Any examples of how to create a Tabber and TabberPanels ?
Which is which ? Is the Tabber the parent and the TabberPanels the "pages" or vice-versa ?

Hi Smiff

Yes your correct in fact TabberPanels are like pages use wb3d_hidegadget and wb3d_showgadget to display the selected page.

below is a test example used while beta testing, this contains lots of gadget creation, including tabber gadgets

;
;
;

; WB3D styles
Include "WB3DStyles.bb"

Graphics3D 640,480,16,2
SetBuffer BackBuffer()

Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_SetQuitMessage "WB3D 3D/GUI quit","Sure To Quit Test.bb" 
WB3D_SetGadgetText RuntimeWindow_hWnd,"WB3D Test.bb Demo" 

WB3D_DragAcceptFiles RuntimeWindow_hWnd,True

image = CreateImage(100,100)
SetBuffer ImageBuffer(image)
Rect 0,0,100,100
Color Rnd(255),Rnd(255),Rnd(255) : Text 0,0,"Example"
Color Rnd(255),Rnd(255),Rnd(255) : Text 0,10,"Blitz"
Color Rnd(255),Rnd(255),Rnd(255) : Text 0,20,"Image"

icond =  WB3D_BBImageToIcon(image)

Color 255,255,255

SetBuffer BackBuffer()

WB3D_CreateGadgetsHidden True

; bitdepth 
; 0 = ILC_COLOR32
; 1 = ILC_COLOR24
; 2 = ILC_COLOR16
; 3 = ILC_COLOR8
; 4 = ILC_COLOR4 
icons2 = WB3D_LoadIconStrip("mar.bmp",70,0)

; RuntimeWindow_hWnd
toolbar = WB3D_CreateToolBar(0,0,100,25,RuntimeWindow_hWnd,0)
WB3D_SetGadgetIconStrip toolbar,icons2
WB3D_AddToolBarButton toolbar,0,1001,"","Tool1",0
WB3D_AddToolBarButton toolbar,1,1002,"","Tool2",0
WB3D_AddToolBarButton toolbar,2,1003,"","Tool3",0
WB3D_AddToolBarSeparator toolbar
WB3D_AddToolBarButton toolbar,3,1004,"","Tool4",0

WB3D_UpdateToolbar toolbar

icons = WB3D_LoadIconStrip("mar2.bmp",16,0)


WB3D_SetWindowIcon RuntimeWindow_hWnd,icons,2


button = WB3D_CreateButton("test",50,240,100,20,RuntimeWindow_hWnd,0)

checkbox1 = WB3D_CreateCheckButton("test",50,85,100,20,RuntimeWindow_hWnd,0)
WB3D_CreateToolTip checkbox1,"Im a checkbox tooltip",0
checkbox2 = WB3D_CreateCheckButton("test",50,105,100,20,RuntimeWindow_hWnd,0)

radiobox1 = WB3D_CreateRadioButton("test",50,125,100,20,RuntimeWindow_hWnd,0,True)    ; true starts a New radio group 
radiobox2 = WB3D_CreateRadioButton("test",50,145,100,20,RuntimeWindow_hWnd,0,False) 

radiobox3 = WB3D_CreateRadioButton("test1",50,165,100,20,RuntimeWindow_hWnd,0,True)    ; true starts a New radio group 
radiobox4 = WB3D_CreateRadioButton("test2",50,185,100,20,RuntimeWindow_hWnd,0,False) ;--> PAINTED AS PUSHBUTTON!! 
radiobox5 = WB3D_CreateRadioButton("test3",50,205,100,20,RuntimeWindow_hWnd,0,False) 

toggle1 = WB3D_CreateToggleButton("toggle1",170,240,80,20,RuntimeWindow_hWnd,0)
toggle2 = WB3D_CreateToggleButton("toggle2",170,260,80,20,RuntimeWindow_hWnd,0)
WB3D_SetButtonState toggle2,True

button3 = WB3D_CreateButton("test2",50,260,100,20,RuntimeWindow_hWnd,0)
WB3D_CreateToolTip button3,"Button3",1
WB3D_DefaultGadgetFont button3

;
;
;
;
;

edit = WB3D_CreateTextArea(50,300,200,100,RuntimeWindow_hWnd,0)
;WB3D_SetTextAreaColor edit,255,0,255 
;WB3D_SetTextAreaBKGNColor edit,10,200,255
WB3D_SetTextAreaTabs edit,12
WB3D_SetTextAreaText edit,"12345"+Chr(13)+"12345"+Chr(13)+"12345"+Chr(13)+"12345"+Chr(13)
;WB3D_SetTextAreaColor edit,255,255,255
WB3D_SetTextAreaText edit,Chr(13)
 
Strings$ = WB3D_TextAreaText(edit) 
WB3D_SetTextAreaText edit,Strings$+"qwerty"+Chr(13)+"qwerty"+Chr(13)+"qwerty"+Chr(13)+"qwerty"

WB3D_CreateToolTip edit,"Im a textarea tooltip",0

;
;
;
;
;

; menus
menus = WB3D_WindowMenu(RuntimeWindow_hWnd)
file = WB3D_CreateMenu("File",0,menus,0)
	NewItem = WB3D_CreateMenu("New",1,file,0) : WB3D_AddMenuIcon(file,1,"menuBMPS/MENUNEW.BMP")
	OpenItem = WB3D_CreateMenu("Open",2,file,1) : WB3D_AddMenuIcon(file,2,"menuBMPS/MENULOAD.BMP")
	
		OpenItem_1 = WB3D_CreateMenu("Open Sub Item 1",43,OpenItem,0) 
		OpenItem_2 = WB3D_CreateMenu("Open Sub Item 2",20,OpenItem,0) 
		
			SUBOpenItem_1 = WB3D_CreateMenu("Sub Item 1",44,OpenItem_2,0) : WB3D_AddMenuIcon(file,44,"menuBMPS/MENULOAD.BMP") 
			SUBOpenItem_2 = WB3D_CreateMenu("Sub Item 2",45,OpenItem_2,1) 
				SUBOpenItem_5 = WB3D_CreateMenu("Sub Item 2",46,SUBOpenItem_2,0)
			
	WB3D_CreateMenu("",0,file,0)
	SaveItem = WB3D_CreateMenu("Save",3,file,0)  : WB3D_AddMenuIcon(file,3,"menuBMPS/MENUSAVE.BMP")
	WB3D_CreateMenu("",0,file,0)
	QuitItem = WB3D_CreateMenu("Quit",4,file,0) : WB3D_AddMenuIcon(file,4,"menuBMPS/MENUQUIT.BMP")

editmenu_window_1 = WB3D_CreateMenu("Edit",0,menus,0)
	CutItem = WB3D_CreateMenu("Cut",5,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,5,"menuBMPS/MENUCUT.BMP")
	CopyItem = WB3D_CreateMenu("Copy",6,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,6,"menuBMPS/MENUCOPY.BMP")
	PasteItem = WB3D_CreateMenu("Paste",7,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,7,"menuBMPS/menupaste.BMP")
	
	;WB3D_DisableMenuItem file,2
	;WB3D_EnableMenuItem editmenu_window_1,7
	;WB3D_CheckMenuItem editmenu_window_1,7
	;WB3D_UnCheckMenuItem editmenu_window_1,7
	
	;WB3D_RemoveMenuItem menus,46 
	
 
	WB3D_RadiocheckMenu editmenu_window_1,5,7,6
		
WB3D_UpdateWindowMenu(RuntimeWindow_hWnd)

WB3D_HideWindowMenu RuntimeWindow_hWnd

WB3D_UpdateWindowMenu(RuntimeWindow_hWnd)
	
;create hotkey - F1 generates a menu_action event with EventData() of 1 
WB3D_HotKeyEvent 59,0,$1001,1,0,0,0

window_floating = WB3D_CreateWindow("New Floating Window",100,100,200,100,RuntimeWindow_hWnd,0)
WB3D_ExcludeGadgetShown window_floating

floatbutton = WB3D_CreateButton("Test WB3D_Notify",10,10,170,25,window_floating,0)
WB3D_SetWindowIcon window_floating,icons,5


window = WB3D_CreateWindow("New Window",450,100,520,550,0,0)
WB3D_SetWindowIcon window,icons,3

camera = CreateCamera()

light = CreateLight()

cube = CreateCube()
PositionEntity cube,0,0,10


id = 0
button2 = WB3D_CreateButton("Show Floating Window",20,60,170,20,window,0)
WB3D_CreateToolTip button2,"Use me to test",1


listbox = WB3D_CreateListBox(180,300,200,100,window,0)
WB3D_SetGadgetIconStrip listbox,icons
WB3D_CreateToolTip listbox,"Im a listbox tooltip",1
For loop = 0 To 10
	icon_index = Rand(0,5)
	WB3D_AddGadgetItem listbox,"item: "+loop,0,icon_index
Next
;WB3D_SetListBoxBKGNColor listbox,10,200,255
;WB3D_SetListBoxTextColor listbox,255,255,100
WB3D_SelectGadgetItem listbox,10

; group all gadgets in one box for this example
;WB3D_CreateGroupBox("Treeview Gadget",5,5,430,235,window,0)


tabber = WB3D_CreateTabber(230,45,220,150,window,0)
WB3D_SetGadgetIconStrip tabber,icons
WB3D_CreateToolTip tabber,"Im a tabber tooltip",0

For loop = 0 To 10
	icon_index = Rnd(0,5)
	WB3D_AddGadgetItem tabber,"item: "+loop,0,icon_index
Next

combo1 = WB3D_CreateComboBox(10,245,200,90,window,WS_CLIPSIBLINGS Or WS_CHILD Or WS_VISIBLE Or CBS_DROPDOWN) 
WB3D_SetGadgetIconStrip combo1,icons
For loop = 0 To 10
	icon_index = Rand(0,5)
	WB3D_AddGadgetItem combo1,"item: "+loop,0,icon_index
Next
WB3D_SelectGadgetItem combo1,4
WB3D_CreateToolTip combo1,"Im a combobox 1 tooltip",0

combo2 = WB3D_CreateComboBox(10,270,200,90,window,WS_CLIPSIBLINGS Or WS_CHILD Or WS_VISIBLE Or CBS_DROPDOWN)
WB3D_SetGadgetIconStrip combo2,icons 
For loop = 0 To 10
	icon_index = Rand(0,5)
	WB3D_AddGadgetItem combo2,"item: "+loop,0,icon_index
Next
WB3D_SelectGadgetItem combo2,4
WB3D_CreateToolTip combo2,"Im a combobox 2 tooltip",1


listview = WB3D_CreateListView(10,100,200,100,window,0)
WB3D_SetGadgetExtendedStyle listview,LVS_EX_FULLROWSELECT Or LVS_EX_GRIDLINES Or LVS_EX_SUBITEMIMAGES
WB3D_SetGadgetIconStrip listview,icons
For loop = 0 To 4
	WB3D_AddListViewColumn listview,loop,"item: "+loop,100
	For loop2 = 0 To 10
		icon_index = Rand(0,5)
		WB3D_AddListViewItem listview,loop,loop2,"Column "+loop+" Item "+loop2,icon_index
	Next
Next
WB3D_CreateToolTip listview,"Im a listview tooltip",0
;WB3D_SetListviewBKGNColor listview,200,10,255
;WB3D_SetListViewTextColor listview,255,255,100

progbar = WB3D_CreateProgBar(10,220,200,20,window,0)
WB3D_ProgBarStepSize progbar,5

treeview = WB3D_CreateTreeView(10,300,130,150,window,0)
WB3D_SetGadgetIconStrip treeview,icons
node1 = WB3D_AddTreeViewNode(treeview,"node1",0,1,1)
	subnode1 = WB3D_AddTreeViewNode(treeview,"node1",node1,1,1)
	subnode2 = WB3D_AddTreeViewNode(treeview,"node1",node1,2,2)
		subnode1_subnode = WB3D_AddTreeViewNode(treeview,"node1",subnode1,1,1)
				
node2 = WB3D_AddTreeViewNode(treeview,"node2",0,3,3)
	a_subnode1 = WB3D_AddTreeViewNode(treeview,"node1",node2,2,2)
	a_subnode2 = WB3D_AddTreeViewNode(treeview,"node1",node2,3,3)
	

node3 = WB3D_AddTreeViewNode(treeview,"node3",0,4,4)
	
	
WB3D_ExpandTreeViewNode treeview,node1
WB3D_ExpandTreeViewNode treeview,node2
WB3D_ExpandTreeViewNode treeview,subnode1

WB3D_ModifyTreeViewNode(treeview,node3,"modifyed")
WB3D_CreateToolTip treeview,"Im a treeview tooltip",1
WB3D_ModifyTreeViewNode(treeview,node3,"modifyed"+"*")

WB3D_SetGadgetItemIcon treeview,node3,22,0

tvfont = WB3D_OpenFont("arial",8,8,0,0,0) ; set bold ,italic ,underline to true
WB3D_Usefont treeview,tvfont

;WB3D_AutoSetGadgetRedraw treeview1,False
For loop = 0 To 400
    WB3D_AddTreeViewNode (treeview,"Sub node value"+loop,node3,0,0) 
Next
;WB3D_AutoSetGadgetRedraw treeview1,True


; menus
menus = WB3D_WindowMenu(window)
file = WB3D_CreateMenu("File",0,menus,0)
	NewItem = WB3D_CreateMenu("New",8,file,0)
	OpenItem = WB3D_CreateMenu("Open",9,file,0)
	WB3D_CreateMenu("",0,file,0)
	SaveItem = WB3D_CreateMenu("Save",10,file,0)
	WB3D_CreateMenu("",0,file,0)
	QuitItem = WB3D_CreateMenu("Quit",11,file,0)

editmenu_window_2 = WB3D_CreateMenu("Edit",0,menus,0) 
	CutItem = WB3D_CreateMenu("Cut",12,editmenu_window_2,0)
	CopyItem = WB3D_CreateMenu("Copy",13,editmenu_window_2,0)
	PasteItem = WB3D_CreateMenu("Paste",14,editmenu_window_2,0)

mixed_items = WB3D_CreateMenu("mixed",0,menus,0)
	coloritem = WB3D_CreateMenu("color dialog",15,mixed_items,0)
	pathitem = WB3D_CreateMenu("path dialog",16,mixed_items,0)
	fontitem = WB3D_CreateMenu("font dialog",17,mixed_items,0)
			
WB3D_UpdateWindowMenu(window)

;
panel0 = WB3D_CreateTabberPanel(5,30,200,100,tabber)
button_tab0 = WB3D_CreateButton("Show Panel Splash",5,10,190,40,panel0,0)
WB3D_CreateToolTip button_tab0,"show me the splash",1

font = WB3D_OpenFont("blitz",8,8,True,True,True) ; set bold ,italic ,underline to true
WB3D_Usefont button_tab0,font


panel1 = WB3D_CreateTabberPanel(5,30,150,100,tabber)
button_tab1 = WB3D_CreateButton("Tab1",10,10,100,20,panel1,0)
WB3D_HideGadget panel1

panel2 = WB3D_CreateTabberPanel(5,30,150,100,tabber)
button_tab2 = WB3D_CreateButton("Tab2",10,10,100,20,panel2,0)
WB3D_HideGadget panel2

panel3 = WB3D_CreateTabberPanel(5,30,150,100,tabber)
button_tab3 = WB3D_CreateButton("Tab3",10,10,100,20,panel3,0)
WB3D_HideGadget panel3

toolbar2 = WB3D_CreateToolBar(0,0,100,20,window,0)
WB3D_ToolBarDefaultBmp toolbar2
WB3D_AddToolBarButton toolbar2,STD_CUT,2000,"Cut","cut",0
WB3D_AddToolBarButton toolbar2,STD_COPY,2001,"Copy","copy",0
WB3D_AddToolBarButton toolbar2,STD_PASTE,2003,"Paste","paste",0

WB3D_UpdateToolbar toolbar2

WB3D_DisableToolBarButton toolbar2,2003

label = WB3D_CreateLabel("here",10,40,100,20,window,0)

name_field = WB3D_CreateEditField("Default text",180,420,200,20,window,0,0)
name_field_tooltip = WB3D_CreateToolTip(name_field,"Im a editfield tooltip",1)

tray = WB3D_AddTrayIcon(icons,2,"trayicon tooltip")
contextmenu = WB3D_CreateContextMenu()
context_show = WB3D_CreateMenu("Show Window",6000,contextmenu,0): WB3D_AddMenuIcon(context_show,1000,"menuBMPS/MENUNEW.BMP")
context_hide = WB3D_CreateMenu("Hide Window",6001,contextmenu,0): WB3D_AddMenuIcon(context_hide,1001,"menuBMPS/MENUCOPY.BMP")
WB3D_CreateMenu("",0,contextmenu,0)
context_hide = WB3D_CreateMenu("About",6002,contextmenu,0)

contextmenu_RuntimeWindow_hWnd = WB3D_CreateContextMenu()
context_show = WB3D_CreateMenu("Show Entity",3000,contextmenu_RuntimeWindow_hWnd,0)
context_hide = WB3D_CreateMenu("Hide Entity",3001,contextmenu_RuntimeWindow_hWnd,0)
WB3D_CreateMenu("",0,contextmenu_RuntimeWindow_hWnd,0)
context_hide = WB3D_CreateMenu("About",3002,contextmenu_RuntimeWindow_hWnd,0)

contextmenu_button_hWnd = WB3D_CreateContextMenu()
context_show = WB3D_CreateMenu("Button Context Menu 1",4000,contextmenu_button_hWnd,0)
context_hide = WB3D_CreateMenu("Button Context Menu 2",4001,contextmenu_button_hWnd,0)
WB3D_CreateMenu("",0,contextmenu_button_hWnd,0)
context_hide = WB3D_CreateMenu("About Button Menus",4002,contextmenu_button_hWnd,0)

contextmenu_list_hWnd = WB3D_CreateContextMenu()
context_show = WB3D_CreateMenu("ListView/ListBox Context Menu 1",5000,contextmenu_list_hWnd,0)
context_hide = WB3D_CreateMenu("ListView/ListBox Context Menu 2",5001,contextmenu_list_hWnd,0)
WB3D_CreateMenu("",0,contextmenu_list_hWnd,0)
context_hide = WB3D_CreateMenu("About ListView/ListBox Menus",5002,contextmenu_list_hWnd,0)

contextmenu_edit_hWnd = WB3D_CreateContextMenu()
context_show = WB3D_CreateMenu("Edit Context Menu 1",7000,contextmenu_edit_hWnd,0)
context_hide = WB3D_CreateMenu("Edit Context Menu 2",7001,contextmenu_edit_hWnd,0)
WB3D_CreateMenu("",0,contextmenu_edit_hWnd,0)
context_hide = WB3D_CreateMenu("About Edit",7002,contextmenu_edit_hWnd,0)


WB3D_SelectGadgetItem listbox,10

trackbar_red = WB3D_CreateTrackBar(280,220,100,20,window,0,0)
WB3D_SetTrackBarRange trackbar_red,0,255
red_label = WB3D_CreateLabel("RED:",220,220,60,20,window,0)
WB3D_CreateToolTip trackbar_red,"change cube's red color",1

trackbar_green = WB3D_CreateTrackBar(280,245,100,20,window,0,0)
WB3D_SetTrackBarRange trackbar_green,0,255
green_label = WB3D_CreateLabel("GREEN:",220,245,60,20,window,0)
WB3D_CreateToolTip trackbar_green,"change cube's green color",1

trackbar_blue = WB3D_CreateTrackBar(280,270,100,20,window,0,0)
WB3D_SetTrackBarRange trackbar_blue,0,255
blue_label = WB3D_CreateLabel("BLUE:",220,270,60,20,window,0)
WB3D_CreateToolTip trackbar_blue,"change cube's blue color",1

track_red_pos = 255
track_green_pos = 255
track_blue_pos = 255

WB3D_SetTrackBarPos trackbar_red,track_red_pos
WB3D_SetTrackBarPos trackbar_green,track_green_pos
WB3D_SetTrackBarPos trackbar_blue,track_blue_pos

;spinner_label = WB3D_CreateLabel("",400,270,60,22,window,0)
spinner_label = WB3D_CreateEditField("",400,270,60,22,window,0,0)
spinner = WB3D_CreateSpinner(460,270,50,22,window,0,0) 
WB3D_SetSpinnerRange spinner,0,2000
WB3D_SetSpinnerPos spinner,100

WB3D_CreateToolTip spinner,"spin values",0

rstatus = WB3D_CreateStatusBar(RuntimeWindow_hWnd,"")
WB3D_SetStatusParts rstatus,4
WB3D_SetStatusText rstatus,0,"part 0"
WB3D_SetStatusText rstatus,1,"part 1"
WB3D_SetStatusText rstatus,2,"part 2"
WB3D_SetStatusText rstatus,3,"part 3"



For loop = 0 To 4
	WB3D_SetStatusPartIcon rstatus,loop,icons,Rnd(1,5)
Next
WB3D_UpdateStatusbar rstatus

status = WB3D_CreateStatusBar(window,"")
WB3D_SetStatusParts status,6
For loop = 0 To 6
	WB3D_SetStatusText status,loop,"part "+loop
Next

WB3D_StatusPartWidth status,0,0
WB3D_StatusPartWidth status,1,200

For loop = 0 To 6
	WB3D_SetStatusPartIcon status,loop,icons,Rnd(1,5)
Next

WB3D_UpdateStatusbar status

; needed in order to flush events when gadgets was created
WB3D_FlushEvents()

; default back to showing gadgets when there created.
WB3D_CreateGadgetsHidden False

WB3D_ShowGadget window
WB3D_ShowGadget RuntimeWindow_hWnd

; resize window_floating while hidden, does not become visable
WB3D_SetGadgetShape window_floating,50,50,200,300

WB3D_ActivateGadget window

WB3D_GUIMouseEvents False

; add checkbox's to listbox, then set random listbox checkbox states
WB3D_SetGadgetExtendedStyle listbox,LVS_EX_CHECKBOXES
For loop = 0 To WB3D_CountGadgetItems(listbox)
	WB3D_ListSetCheckState listbox,loop,Rand(1,2) 
Next

WB3D_SetGadgetText combo1, "ARGH1!" 
WB3D_SetGadgetText combo2, "ARGH2!" 

progcount = 0

bank_buffer = CreateBank(ImageWidth(image)*ImageHeight(image))

;
;
While Not KeyDown(1)
	
	;Cls
	
	
	;WB3D_StopEvents()
	
	
	;WB3D_StartEvents()
	
		
	If wheeldata > 0 Then
		TranslateEntity cube,0,0,1
	ElseIf wheeldata < 0 
		TranslateEntity cube,0,0,-1
	EndIf
	
	TurnEntity cube,1,1,1
	
	UpdateWorld
	RenderWorld
	
	Text 10,40,"button  "+Hex(button) 
	Text 200,40,"event "+Hex(event)
	Text 400,40,"id "+Hex(id)
	
	Text 100,100,"mouse position x/y "+MouseX()+" : "+MouseY()
	Text 100,130,"mouse position x/y "+mx+" : "+my
	
	If KeyDown(28) Then
		key = True
	Else
		key = False
	EndIf
		
	Text 100,110,"key press "+key
	Text 100,150,"Use MouseWheel to move cube, wheel data "+wheeldata 
	Text 100,170,"menu item selected "+menuID
	
	
	Text 100,190,"gadget: "+Hex(gadget_mouse_over);Hex(WB3D_EventY())
	Text 100,210,"mouseX: "+gadget_mouse_overX
	Text 100,230,"mouseY: "+gadget_mouse_overY
	
	Text 100,220,"track_pos: "+track_pos
	;Text 100,220,"GadgetX: "+GadgetX(button)+" : "+Hex(button)
	;Text 100,240,"GadgetX: "+GadgetX(button2)+" : "+Hex(button2)
	;Text 100,260,"GadgetX: "+GadgetX(tabber)+" : "+Hex(tabber)
	;Text 100,280,"GadgetX: "+GadgetX(edit)+" : "+Hex(edit)
	
	
	EntityColor cube,track_red_pos,track_green_pos,track_blue_pos

	If progcount < 100 Then
		progcount = WB3D_UpdateProgBar(progbar)
	Else
		progcount = 0
	EndIf
	
	If MouseDown(2) Then
		WB3D_TrackContextMenu RuntimeWindow_hWnd,contextmenu_RuntimeWindow_hWnd,MouseX(),MouseY()
	EndIf
	
	;DrawImage image,410,350	
	WB3D_DrawIcon window,400,350,icond
	;WB3D_SetIconBuffer window,icond,bank_buffer
	
	;For loop = 0 To 100
	;	Text 200,180,"BANK DATA: "+PeekByte(bank_buffer,loop)
	;Next

	
	Flip

	
	;WB3D_ForceSetForegroundWindow window_floating
	;WB3D_ForceSetForegroundWindow RuntimeWindow_hWnd
	
	event = WB3D_WaitEvent()
	Select event
		
		Case $1001 ; menu selection
			
			menuID = WB3D_EventData()
			Select menuID
				
				Case 44
					WB3D_Notify "","here",0
					
				Case 2 ; open
					; file extensions
					; first the description then the .extension
					file_ext$ = "BlitzBasic Source Code"+Chr(0)+"*.bb"+Chr(0)+"Text"+Chr(0)+"*.txt"+Chr(0)
					open$ = WB3D_OpenFileRequest("select file open","D:\Blitz3D_GUI_DLL",file_ext$,"Test")
					If open$ <> "" Then WB3D_Notify("Selected File To Open",open$,0)
				
				Case 3 ; save
					save_file_ext$ = "BlitzBasic Source Code"+Chr(0)+"*.bb"+Chr(0)+"Text"+Chr(0)+"*.txt"+Chr(0)
					save$ = WB3D_SaveFileRequest("select file save","D:\Blitz3D_GUI_DLL",save_file_ext$,"Test")
					If save$ <> "" Then WB3D_Notify("Selected File To Save",save$,0)
					
				Case 4 ; quit
					
					WB3D_EndGUI()
					EndGraphics 
					
					Print "finished press mouse button"
					MouseWait
					End
				
				Case 5,6,7 ; test radio check menu items 5,6,7
					WB3D_RadiocheckMenu editmenu_window_1,5,7,menuID

				Case 15 
					
					
					selectedColor = WB3D_RequestColor(100,100,105)
					If selectedColor <> 0 Then
						red = WB3D_RequestedRED()
						green = WB3D_RequestedGREEN()
						blue = WB3D_RequestedBLUE()
					EndIf
					WB3D_Notify "colors","red "+red+" green "+green+" blue "+blue,0

				Case 16
					newdir$ = WB3D_RequestDir("Select NEW Folder",newdir$)
					WB3D_Notify "folder selected","You Selected: "+newdir$,0
				
				Case 17
					font = WB3D_OpenFontRequest()
					WB3D_Notify "font selected","Selected font pointer: "+font,0
					WB3D_Usefont button,font
					
				Case 6000
					;Notify "context menu","6000",0
					WB3D_ShowGadget RuntimeWindow_hWnd
					WB3D_ShowGadget window
					
				Case 6001
					;Notify "context menu","6001",0
					WB3D_HideGadget RuntimeWindow_hWnd
					WB3D_HideGadget window
				Case 6002
					WB3D_Notify "WB3D Demo","WB3D Copyright Kevin Poole"+Chr(13)+"2005,2006.",0
					
				Case 5000
					WB3D_Notify "context menu","5000",0
					
				Case 5001
					WB3D_Notify "context menu","5001",0
							
			End Select
			
		Case $208	; mouse wheel
				flagkey = WB3D_EventFlagKey()
				wheeldata = WB3D_EventData()
				cursx = WB3D_EventX()
				cursy = WB3D_EventY()
						
		Case WB3D_EVENT_GADGET	; gadget event
			id = WB3D_EventSource()
			
			Select id
				
				Case floatbutton
					ret_notify_code = WB3D_Notify("Testing......","WB3D_Notify Test",MB_CANCELTRYCONTINUE Or MB_ICONEXCLAMATION)
					Select ret_notify_code
						Case IDCANCEL
							WB3D_Notify "You Selected","Cancel button was selected",0
								
						Case IDRETRY
						 	WB3D_Notify "You Selected","Retry button was selected",0
						
						Case IDCONTINUE
						 	WB3D_Notify "You selected","Continue button selected",0
						
					End Select
					
				Case trackbar_red
					track_red_pos = WB3D_GetTrackBarPos(trackbar_red)

				Case trackbar_green
					track_green_pos = WB3D_GetTrackBarPos(trackbar_green)

				Case trackbar_blue
					track_blue_pos = WB3D_GetTrackBarPos(trackbar_blue)
					
					
				Case toggle1 
					WB3D_Notify "","Toggle Button State "+WB3D_ButtonState(toggle1),0

				Case toggle2 
					WB3D_Notify "","Toggle Button State "+WB3D_ButtonState(toggle2),0
					
				Case button_tab0
					splash_window = WB3D_CreateWindow("spash window",400,140,320,250,0,0)
					panel_splash = WB3D_CreatePanel(20,20,400,200,splash_window,0)
					WB3D_AddPanelImage panel_splash,"SPLASH.bmp"

				Case button_tab1
					WB3D_Notify "button_tab1","button_tab1",0

				Case button_tab2
					WB3D_Notify "button_tab2","button_tab2",0

				Case button_tab3
					WB3D_Notify "button_tab3","button_tab3",0
					
				Case toolbar
					WB3D_Notify "toolbar","toolbar: "+WB3D_EventData(),0

				Case toolbar2
					WB3D_Notify "toolbar2","toolbar2: "+WB3D_EventData(),0
					
				Case listview
					
					If WB3D_EventEdited() = 0 Then

						selectedcolumn = WB3D_EventData()
						If(selectedcolumn = -1) Then
							oldicon = WB3D_SetGadgetItemIcon(WB3D_EventSource(),WB3D_SelectedListViewItem(listview),22,0)
							WB3D_Notify "listview","listview item selected "+WB3D_SelectedListViewItem(listview),0
						Else
							WB3D_Notify "listview","listview column clicked "+selectedcolumn,0
						EndIf
					
					EndIf
																
				Case button
					
					
				Case edit
					 
				Case combo1
					selected = WB3D_SelectedGadgetItem(combo1)
					
					If selected <> -1 Then
						WB3D_Notify "combo Selected","combo Selected "+selected,0
					
					Else
						If WB3D_GetEditedLabel() <> "" Then
							WB3D_ModifyGadgetItem WB3D_EventSource(),WB3D_GetEditedLabelIndex(),WB3D_GetEditedLabel(),-1	; -1 use same icon
							WB3D_SelectGadgetItem WB3D_EventSource(),WB3D_GetEditedLabelIndex()
						EndIf
					EndIf

				Case combo2
					selected = WB3D_SelectedGadgetItem(combo2)
					
					If selected <> -1 Then
						WB3D_Notify "combo Selected","combo Selected "+selected,0
					
					Else
						If WB3D_GetEditedLabel() <> "" Then
							WB3D_ModifyGadgetItem WB3D_EventSource(),WB3D_GetEditedLabelIndex(),WB3D_GetEditedLabel(),-1	; -1 use same icon
							WB3D_SelectGadgetItem WB3D_EventSource(),WB3D_GetEditedLabelIndex()
						EndIf
					EndIf
					
				Case listbox
								
										
					If WB3D_EventEdited() = 0 Then
												
						; wb3d_eventdata returns -1 if the items label was clicked, or the index of
						; the items whos checkbox has been selected
						checkbox_selected = WB3D_EventData()
					
						; has the listbox checkbox generated the event?
						If checkbox_selected = -1 Then
							selected = WB3D_SelectedGadgetItem(listbox)
							oldicon = WB3D_SetGadgetItemIcon(WB3D_EventSource(),selected,22,0)
							WB3D_Notify "listbox Selected","listbox Selected "+selected,0
						Else
							selected = checkbox_selected
							WB3D_Notify "listbox Selected","listbox Selected "+selected+Chr(13)+"Checkbox Selected "+WB3D_ListCheckState(listbox,selected),0
						EndIf
								
					Else
						If WB3D_GetEditedLabel() <> "" Then
							WB3D_ModifyGadgetItem WB3D_EventSource(),WB3D_GetEditedLabelIndex(),WB3D_GetEditedLabel(),0
						EndIf
					EndIf
					

				Case button2
					
					WB3D_ShowGadget window_floating
										
										
				Case tabber
					selectedtab = WB3D_EventData()
					
					Select selectedtab
					
						Case 0
							WB3D_ShowGadget panel0
							WB3D_HideGadget panel1
							WB3D_HideGadget panel2
							WB3D_HideGadget panel3
						
						Case 1
							WB3D_ShowGadget panel1
							WB3D_HideGadget panel0
							WB3D_HideGadget panel2
							WB3D_HideGadget panel3
						
						Case 2
							WB3D_ShowGadget panel2
							WB3D_HideGadget panel0
							WB3D_HideGadget panel1
							WB3D_HideGadget panel3
						
						Case 3
							WB3D_ShowGadget panel3
							WB3D_HideGadget panel0
							WB3D_HideGadget panel1
							WB3D_HideGadget panel2
					
					Default
						WB3D_Notify "Tab Selected","Tab Selected "+selectedtab,0
	
						WB3D_HideGadget panel0
						WB3D_HideGadget panel1
						WB3D_HideGadget panel2
						WB3D_HideGadget panel3		
					End Select
					
					oldicon = WB3D_SetGadgetItemIcon(WB3D_EventSource(),selectedtab,22,0)
					
				Case treeview
					
					selectednode = WB3D_EventData()
					
					If selectednode = subnode1 
						WB3D_Notify "subnode1 ","subnode1 selected",0
					Else
						WB3D_Notify "selected node","Selected Node "+selectednode ,0
					EndIf
					
					If WB3D_GetEditedLabelIndex() Then
						If WB3D_GetEditedLabel() <> "" Then
							WB3D_ModifyTreeViewNode WB3D_EventSource(),WB3D_GetEditedLabelIndex(),WB3D_GetEditedLabel()
						EndIf
					EndIf
					
					WB3D_SetGadgetItemIcon(WB3D_EventSource(),selectednode,22,1)

 
				Case name_field
					;
					WB3D_SetGadgetText window,WB3D_GetGadgetText(name_field)
					;WB3D_Notify "",Len(WB3D_GetGadgetText(name_field)),0
									
				
			End Select
			
		Case WB3D_EVENT_WINDOW_CLOSE   ; close window
			
			closewin = WB3D_EventSource()
			If closewin = window_floating Then
				WB3D_HideGadget window_floating
			EndIf
						
		Case $802	; window size
			; for move,moving,size,sizing see 
			; WB3D_EventData() - edge being moved Or sized
			; WB3D_EventX()	- new size, position
			; WB3D_EventY()	- new size position
			
			; update window toolbars
			;WB3D_UpdateToolbar toolbar
			;WB3D_UpdateToolbar toolbar2
			
			
			; update the status bars
			;WB3D_UpdateStatusbar status
			;WB3D_UpdateStatusbar rstatus
			

		Case $805	; window sizing	
			
		Case $806	; window moving

		
		Case $807	; window move
		
		Case $200	; mousemove
			gadget_mouse_over = WB3D_EventSource()
			gadget_mouse_overX = WB3D_EventX()
			gadget_mouse_overY = WB3D_EventY()
							
		Case $101	; key down
			
			gadget_keydown = WB3D_EventSource()
			key_code = WB3D_EventData()	
			
			Select gadget_keydown
				
				Case name_field
					If key_code = WB3D_KEY_ENTER Then
						WB3D_Notify "Gadget Contents",WB3D_GetGadgetText(name_field),0
					EndIf
				
				Case edit
					If key_code = WB3D_KEY_ENTER Then
						WB3D_Notify "Gadget Contents",WB3D_TextAreaText(edit),0
					EndIf

				Case listbox
					If key_code = WB3D_KEY_ENTER Then
						WB3D_Notify "Selected Gadget Item","You Selected Item: "+WB3D_SelectedGadgetItem(listbox)+Chr(13)+"Item Text: "+WB3D_GadgetItemText(listbox,WB3D_SelectedGadgetItem(listbox)),0
					EndIf
				
				Case spinner_label
					
					If key_code = WB3D_KEY_ENTER Then
						WB3D_Notify "Spinner ","Spinner Value "+WB3D_GetSpinnerPos(spinner),0
						;WB3D_SetSpinnerPos(spinner,WB3D_GetGadgetText(spinner_label))
					EndIf
					
			End Select
		
		Case $502	; gadgets context menus
				gadget = WB3D_EventSource()
				
				;;Notify Hex(window),Hex(gadget),0
								
				contextmenu_popup = 0
				Select gadget
						
					Case RuntimeWindow_hWnd	
						contextmenu_popup = contextmenu_RuntimeWindow_hWnd
					
					Case button,button3
						contextmenu_popup = contextmenu_button_hWnd
					
					Case listview,listbox
						contextmenu_popup = contextmenu_list_hWnd
					
					Case edit 
						contextmenu_popup = contextmenu_edit_hWnd
								
				End Select
				WB3D_TrackContextMenu(gadget,contextmenu_popup,WB3D_EventX(),WB3D_EventY())
			
		Case $503	; system tray
			
			eventtype = WB3D_EventData()
			
			Select eventtype
				
				Case 1
					WB3D_Notify "system tray","system tray left mouse double click",0

				Case 2,3
					WB3D_TrackContextMenu(WB3D_EventSource(),contextmenu,WB3D_EventX(),WB3D_EventY())
			End Select
		
		
		Case $504	; drag and drop files
			gadget = WB3D_EventSource()
			
			
			For do_files = 0 To WB3D_CountDroppedFiles()
				WB3D_Notify "",""+WB3D_DroppedFileName(do_files),0
			Next
		
		Case $200
												
	Default
		
		; reset wheel move flag 	
		wheeldata = 0
		
	End Select
	;RuntimeWindow_hWnd
	;WB3D_PlayAnimate delayanim,0,-1,-1
	

Wend

WB3D_EndGUI()
EndGraphics 
Print "finished press mouse button"
MouseWait
End

kev

Thanks Kev That's very useful !

this rocks!

it is using the windows API, isn't it?

it don't work for me , It can't find the user lib , to be sure
I put the file WB3DStyles.bb in the same dir and change the path of the include in the sample ... same thing
I put the file Blitz3D_GUI_DLL.decls in userllibs dir

I use blitz v1.98
,

either put the blitz3d_gui_dll.dll file in the same directory as your .bb file, or copy it to your windows/system32 directory.

Hi Smokey

Please ensure blitz3d_gui_dll.dll is in the same folder as the example your testing.

can you let me know if that helps.

kev

Hi Kev :) nice job your GUI !

It is possible to define a no resizable window ?

hi filax

window = WB3D_CreateWindow("New Window",450,100,520,550,0,WS_VISIBLE Or WS_SYSMENU Or WS_MINIMIZEBOX Or WS_CAPTION)

kev

Many thanks ! Great lib !

Here is a manifest file to give winblitz3D xp look :)

Example : WB3D_Notify.exe.manifest


<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
<assemblyIdentity
version="1.0.0.0"
processorArchitecture="X86"
name="MyCompany.MyLabel.MyAppName"
type="win32"
/>
<description>Filax powaa</description>
<dependency>
<dependentAssembly>
<assemblyIdentity
type="win32"
name="Microsoft.Windows.Common-Controls"
version="6.0.0.0"
processorArchitecture="X86"
publicKeyToken="6595b64144ccf1df"
language="*"
/>
</dependentAssembly>
</dependency>
</assembly>

Here is a little software to hack blitz exe's to remove
black window at start :)

;
; WB3D_CreateWindow example
;	By Kevin Poole.

; were using external winapi styles
Include "../../../WB3DStyles.bb"

; setup gfx mode.
Graphics3D 640,480,16,2

; install winblitz3d.
Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_SetQuitMessage "WinBlitz3D 3D/GUI","Sure To Quit" 
WB3D_HideGadget RuntimeWindow_hWnd

; create winapi window, setting its title, and position on screen. use default style creation.
MyWindow = WB3D_CreateWindow("WB3D_CreateWindow Example",200,100,275,275,0,WS_VISIBLE Or WS_SYSMENU Or WS_CAPTION)

; cleanup any old creation events, its better to do this before we enter the main
; event loop, when some gadgets are created they generate events.
WB3D_FlushEvents 

LoadExe = WB3D_CreateButton("Open blitz exe to hack",10,10,250,25,MyWindow,0)
WB3D_DefaultGadgetFont LoadExe


Listbox = WB3D_CreateListBox(10,40,250,190,MyWindow,0)

; setup out quit flag, and loop until the flag is set.
QUIT = 0

While Not QUIT = 1
	; generate an internal blitz event
	Flip

	; get an event of the event queue.
	event = WB3D_WaitEvent()
	Select event
		Case WB3D_EVENT_GADGET
			selected = WB3D_EventSource()
			Select selected

			Case LoadExe
				Filename$ = WB3D_OpenFileRequest("Open file","",example_file_ext$,WB3D_GetGadgetText(example_init_filename))
				WB3D_ClearGadgetItems Listbox
				
				If Filename$<> "" Then
					fil=OpenFile(Filename$)

					WB3D_AddGadgetItem Listbox,"Opening executable file",0,0

					If fil
						siz=FileSize(Filename$)

						For i=0 To siz
							byt=ReadByte(fil)
							If Frst
								If scnd
									If byt=$8B
										pos=i-1
										Exit	
									Else
										scnd=False
										If byt<>$CA frst=False
									EndIf
								ElseIf byt=$10
									scnd=True
								Else
									If byt<>$CA Frst=False
							EndIf
						ElseIf byt=$CA
							Frst=True

						EndIf	
					Next

					WB3D_AddGadgetItem Listbox,"Patching executable file",0,0
					
					SeekFile fil,pos
					WriteByte fil,$00

					WB3D_AddGadgetItem Listbox,"Process completed",0,0
					
					CloseFile fil

					WB3D_AddGadgetItem Listbox,"Close file",0,0
					EndIf
				EndIf
			End Select
			
		
		Case WB3D_EVENT_KEYPRESS
		
			; wb_eventdata holds the key code that was pressed.
			keypressed = WB3D_EventData()
			Select keypressed
				
				Case WB3D_KEY_ESCAPE	
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
				
		Case WB3D_EVENT_WINDOW_CLOSE
		
			; wb3d_eventsource hold the handle to the window that close button was selected
			window = WB3D_EventSource()
			Select window
			
				Case MyWindow
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
	End Select
	
Wend

; use notify using external winapi constants. 
WB3D_EndGUI()
EndGraphics
End

Excellent. I've been waiting for this. Thanks Kev!

@filax, the manifest should be wrapped into startup scr patcher and included with winblitz3d.

kev

interesting program above...killed my blitz3d.exe file. Now it pops up a black box (dos box) and closes after about 1 second. Need to reinstall, I think.
***EDIT***
After reinstall I checked a hex dump of blitz3d.exe and stepped through the above program. Very nice...it writes a 0 into position 0 in the file. An easy way to fix that problem is to open your "dead" blitz32.exe file in a hex editor such as hiew and replace the 0 with a 4D.

Filax, great post man... Froze my pc and gave me pure hell, thank you!

@kevin8084:
Filax's explanation above is a little confusing. That program is not meant to be run on the bltz3d.exe! The idea is to compile your Blitz project as an exe, and then use his program on that exe. The result is that your program will run without creating a window---that way you can use WinBlitz3D to create whatever interface you want for your program, without the default Blitz window appearing.

@Kev
Many thanks for this excellent library. If I ever get round to writing a commercial app with it, I'll be sure to send a donation.

Incidentally, I find that all of the included examples run much more smoothly with the addition of "delay 10" just after the "flip" statement--just to allow other Windows processes a chance to do their thing as well. Otherwise the Blitz application sits there doing nothing, but using 100% of the processor's power.

Ahhh...I understand. I misread the "blitz exe" as "blitz.exe" and thought that he meant "blitz32.exe"
Thanks for clarifying.

Tssss .... i have specify blitz exe files not your blitz3D.exe !!

Tssss....already admitted that I misread and misunderstood. My apologies.

No problemo :)

Kev : "should be wrapped into startup scr patcher and included with winblitz3d."

What ?? Don't understand

@filax, one example that does both manifest and startup scr patcher using winblitz3d.

this will patch the .exe and write out the manifest

;
; WB3D_CreateWindow example
;	By Kevin Poole.

; were using external winapi styles
Include "../../WB3DStyles.bb"

; setup gfx mode.
Graphics3D 640,480,16,2

; install winblitz3d.
Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_SetQuitMessage "WinBlitz3D 3D/GUI","Sure To Quit" 
WB3D_HideGadget RuntimeWindow_hWnd

; create winapi window, setting its title, and position on screen. use default style creation.
MyWindow = WB3D_CreateWindow("WB3D_CreateWindow Example",200,100,275,275,0,WS_VISIBLE Or WS_SYSMENU Or WS_CAPTION)

; cleanup any old creation events, its better to do this before we enter the main
; event loop, when some gadgets are created they generate events.
WB3D_FlushEvents 

LoadExe = WB3D_CreateButton("Open blitz exe to hack",10,10,250,25,MyWindow,0)
WB3D_DefaultGadgetFont LoadExe


Listbox = WB3D_CreateListBox(10,40,250,190,MyWindow,0)

; setup out quit flag, and loop until the flag is set.
QUIT = 0

While Not QUIT = 1
	; generate an internal blitz event
	Flip

	; get an event of the event queue.
	event = WB3D_WaitEvent()
	Select event
		Case WB3D_EVENT_GADGET
			selected = WB3D_EventSource()
			Select selected

			Case LoadExe
				Filename$ = WB3D_OpenFileRequest("Open file","",example_file_ext$,WB3D_GetGadgetText(example_init_filename))
				WB3D_ClearGadgetItems Listbox
				
				If Filename$<> "" Then
					fil=OpenFile(Filename$)

					WB3D_AddGadgetItem Listbox,"Opening executable file",0,0

					If fil
						siz=FileSize(Filename$)

						For i=0 To siz
							byt=ReadByte(fil)
							If Frst
								If scnd
									If byt=$8B
										pos=i-1
										Exit	
									Else
										scnd=False
										If byt<>$CA frst=False
									EndIf
								ElseIf byt=$10
									scnd=True
								Else
									If byt<>$CA Frst=False
							EndIf
						ElseIf byt=$CA
							Frst=True

						EndIf	
					Next

					WB3D_AddGadgetItem Listbox,"Patching executable file",0,0
					
					SeekFile fil,pos
					WriteByte fil,$00

					WB3D_AddGadgetItem Listbox,"Process completed",0,0
					
					CloseFile fil

					WB3D_AddGadgetItem Listbox,"Close file",0,0
					
					Write_manifest(Filename$)
					
					WB3D_AddGadgetItem Listbox,"WindowsXP manifest created",0,0

					EndIf
					
					
				EndIf
			End Select
			
		
		Case WB3D_EVENT_KEYPRESS
		
			; wb_eventdata holds the key code that was pressed.
			keypressed = WB3D_EventData()
			Select keypressed
				
				Case WB3D_KEY_ESCAPE	
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
				
		Case WB3D_EVENT_WINDOW_CLOSE
		
			; wb3d_eventsource hold the handle to the window that close button was selected
			window = WB3D_EventSource()
			Select window
			
				Case MyWindow
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
	End Select
	
Wend

; use notify using external winapi constants. 
WB3D_EndGUI()
EndGraphics
End

Function Write_manifest(file_name$)
	
	manifest_create = WriteFile(file_name$+".manifest")
	
	
	WriteLine manifest_create,"<?xml version="+Chr(34)+"1.0"+Chr(34)+" encoding="+Chr(34)+"UTF-8"+Chr(34)+" standalone="+Chr(34)+"yes"+Chr(34)+"?>"
	WriteLine manifest_create,"<assembly xmlns="+Chr(34)+"urn:schemas-microsoft-com:asm.v1"+Chr(34)+" manifestVersion="+Chr(34)+"1.0"+Chr(34)+">"
	WriteLine manifest_create,"<assemblyIdentity"
	WriteLine manifest_create,"version="+Chr(34)+"1.0.0.0"+Chr(34)
	WriteLine manifest_create,"processorArchitecture="+Chr(34)+"X86"+Chr(34)
	WriteLine manifest_create,"name="+Chr(34)+"MyCompany.MyLabel.MyAppName"+Chr(34)
	WriteLine manifest_create,"type="+Chr(34)+"win32"+Chr(34)
	WriteLine manifest_create,"/>"
	WriteLine manifest_create,"<description>Filax powaa</description>"
	WriteLine manifest_create,"<dependency>"
	WriteLine manifest_create,"<dependentAssembly>"
	WriteLine manifest_create,"<assemblyIdentity"
	WriteLine manifest_create,"type="+Chr(34)+"win32"+Chr(34)
	WriteLine manifest_create,"name="+Chr(34)+"Microsoft.Windows.Common-Controls"+Chr(34)
	WriteLine manifest_create,"version="+Chr(34)+"6.0.0.0"+Chr(34)
	WriteLine manifest_create,"processorArchitecture="+Chr(34)+"X86"+Chr(34)
	WriteLine manifest_create,"publicKeyToken="+Chr(34)+"6595b64144ccf1df"+Chr(34)
	WriteLine manifest_create,"language="+Chr(34)+"*"+Chr(34)
	WriteLine manifest_create,"/>"
	WriteLine manifest_create,"</dependentAssembly>"
	WriteLine manifest_create,"</dependency>"
	WriteLine manifest_create,"</assembly>" 


	CloseFile manifest_create
	
End Function

Many thanks Kev :)

OK, please be gentle..., but Im assuming WinBlitz3d is for making windowed only programs so it cant be used to make a GUI for a fullscreened program?

<ducks behind the desk...>

I wouldn't recommend making a fullscreen program that isn't a game or a screensaver, and I wouldn't recommend using the Windows GUI for a game :)

Server down? Can't load the website.

@Xyle, yes winblitz3d is designed for window'ed mode GUI only, athough it should be possable to fake full screen.

@PCD GUY, server up now.

kev

@Danny

Any news about SCHNOK!, even an "undocumented beta" would make my day :)

I'm waiting for it too..:))

Thanks Kev!

@Lab/Alien,

I'll try and post an 'undocumented beta' later tonight..

Sir Danny, You are a gentleman!

Danny i look forward to the next beta, whats new/updated with this new beta?

kev

Ok, SCHNOK! 0.95 undocumented sloppy beta released! (It's a gui editor for WinBlitz3D)

check the post on: http://www.blitzbasic.com/Community/posts.php?topic=62516

@Kev, the last version was 6 months ago ;) Mostly they're stability and bug fixes. I know there's quite some issues here and there but haven't had much time to tackle all of 'em...

Kev, I definitely have a graphical glitch here with the:

temp = WB3D_CreateGroupBox "Camera",5,200,180,50,panel1,0)

WB3D_Usefont temp,uni_font

uni_font is just the ms sans serif font..it's nothing special...but I get a piece of the original word left over and it shows behind the new font. Probably an easy fix...lemme know if you can correct this plz.

@Danny
what its been that long since the last beta.

@Chroma
Im aware of this problem and still not got round to fixing it, I will though.

kev

Kev, is there a RefreshAll type command? If I hide the tab then show it the font artifacts go away!! If there's something that will refresh all the gadgets I'd gladly use that instead of you chasing that bug down.

Kev/Chroma,

These minor graphic glitches are still a bit of a mystery. And (as you pointed out Chroma) ony happen when you set (alter) the font of a gadget other than the original one.

Also note that sometimes you will see minor glitches like this whilst editing in the Schnok Editor but NOT when you actually export and run the gui from your app! (except for the groupbox, that one's always been like that)..

Danny

Very nice! Thanks Kev!

@Chroma/Danny, the problem with the graphical glitch when using groupbox's has been fixed. it was an over sight on my side i was not correctly redrawing after font changes.

@Danny, did you not encounter a simular problem with the top of the window.

i hope to have an updated version soon, this includes some little fixes

kev

@kev, err.. yes... Ah! This was when you created a window and set the styles for it to be a ToolWindow. But I just checked it in schnok and seems ok!

I don't know what it is, but there's always been something different with the gadgets you're building in schnok (talking about (re)painting) as opposed to exported code.
For example, I just heard that when you create a windowmenu that it isn't painted untill you move the mouse over it! And if you move another window over it, it won't repaint the windowmenu (gets dirty). But Schnok's own pull down menu looks fine!

I don't (cant?) set styles on a windowmenu so that's all default. But perhaps the window it's parented to needs a certain style to make it paint it's menu properly? I use these default styles to reproduce yours:

WS_CHILD, WS_VISIBLE, WS_CLIPCHILDREN, WS_CLIPSIBLINGS, WS_POPUP, WS_CAPTION, WS_MINIMIZEBOX, WS_MAXIMIZEBOX, WS_SYSMENU, WS_THICKFRAME.

D.

Kev, I just redownloaded WB3D and I'm still getting the graphical error with the group box.

Chroma, Ive not uploaded the updated version just yet im still finalizing a couple of extra fixes, it will be soon though.

kev

Kev - can you also check the spinners - I don't seem to be able to capture any events from them - thanks.

I've been playing about with this for a few days now and its really good, particularly the 3D/GUI integration which was possible with previous versions but quite fiddly. So thanks again for all your hard work Kev - a donation is on its way.

Now I've got you in a good mood, can I just ask if there's a way to lose those little highlight things (dotted black rectangles) which appear over the most recently-used gadget? They don't look too bad most of the time but I'd still prefer to be rid of them.

EDIT - I've just noticed that they disappear if I use a manifest file. But I'm still curious to know if there's another way.

Hi guys,

Ive uploaded a new version that fixes a couple of the problems you guys encounterd.

you will notice the addition of some extra commands, ie gadget creation these dont work yet and are templates for some new features im currently adding.

ive also added a new command WB3D_GetOSVersion() this will return the os your .exe is running under.

finaly WB3D_Force_BlitzKeys() has been added, this enables control when using blitz internal input. flag it with true/false to stop key repeats.

@Smiff,
missed that one ;) anyway re-download the latest version for spinner events.

@JoeGr
many thanks for your donation, when a gadget has keyboard focus windows auto draws the selection box within the gadgets frame. im unsure if its possable to by-pass, i will look into it though.

kev

The focus rectangle can be accessed with the function DrawFocusRect:

BOOL DrawFocusRect(
HDC hDC, // handle to device context
CONST RECT* lprc // logical coordinates
);

Kevin

@Kev: could you possibly put in a window-centering routine? Possible code:

Function CreateWindowCentered(caption$,width,height,parent,style)
x=api_GetSystemMetrics(0) ; width of screen in pixels
x=(x/2)-(width/2)
y=api_GetSystemMetrics(1) ; height of screen in pixels
y=(y/2)-(height/2)
Return (WB3D_CreateWindow(caption$,x,y,width,height,parent,style))
End Function

Thanks Kevs.

kevin8084, why don't you just use the function you posted above?

@JoeGr - I do use it, but I've seen others asking how to center their windows. Seems that it would just be more convenient for people if they can call the function from within WinBlitz.

He, you can make a blitzcc.exe.manifest in the \bin directory!

Perhaps I'm missing something or being obtuse, but I can't seem to use the spinner control. Would somebody explain to me how to set the control up in code?

hi kevin8084, then creating spinners the gadget created before the spinner becomes it buddy.

heres an example.

; WB3D styles
Include "WB3DStyles.bb"

Graphics3D 800,480,16,2
SetBuffer BackBuffer()

Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,800,500)
WB3D_SetQuitMessage "WB3D 3D/GUI quit","Sure To Quit Test.bb" 

window = WB3D_CreateWindow("test",100,100,500,300,0,0)


spinner_value = WB3D_CreateEditField("",40,5,100,20,window,0,0)
spinner = WB3D_CreateSpinner(141,5,40,20,window,1,0)
WB3D_SetSpinnerRange spinner,0,100

While Not KeyDown(1)
	
		
	Select WB3D_WaitEvent()
		
		Case $401
			Select WB3D_EventSource()
				Case spinner
					If WB3D_GetSpinnerPos(spinner) = 50 Then
						WB3D_Notify "spinner gadget","spinner position at 50",0
					EndIf
					
			End Select
		
	End Select
	
Wend

WB3D_EndGUI()
End

kev

Thank you for the explanation, Kevin. Much appreciated.

Spinner range seems limited ... kev, did you used a 16 or 32 bit value for theses? Also when not linking to a buddy I got strange results from getspinnerpos... I still don't get really how buddy/spinner/range interacts but it seems to be all dependent of this 16 or 32 bit value and of a "base" which is either decimal or hex.

Hi Kev, pretty cool work. Thanks a lot for sharing.

One whish i had. A command to setup the default font for all gadgets would be pretty cool. So that i can setup a font at startup and all created gadgets (after that) would use this font.

Otherwise i have to change the font for all created gadgets piece by piece and this is ... well ... not so nice.

Btw. the "width" option in the OpenFont command is a little bit confusing to find the correct font. This option as an optional parameter makes more sense in my eyes, but, it's ok if not.

EDIT: Is it possible to use "multiselection" with the ListBox Gadget? And if yes how can i recieve the choosed Itemlist? A example would be great. If not, can you add this feature PLEASE, PLEASE, PLEASE :-))

that's my whishlist and ... sorry for my english

@LAB[au], realy i do need to change the way spinners are handled. values are int when passed to winblitz3d, there then combined as a long using 2 shorts. ie 'MAKELONG((short) max, (short) min)'. spinners as far as im aware and the way i have always used them have had a buddy.

@East-Power-Soft

sounds like a good idea, i will have a look at adding this.


this will be added but when i dont now, when ive some time free.

@Easy Power Soft,

At default the listbox has the LVS_SINGLESEL style included; so you can only select 1 item at a time. So when you create a listbox, in stead of the default '0' style use the following to get a multi selection listbox:

WB3D_CreateLisBox (x,y,width,height,parent, WS_CHILD or WS_CLIPSIBLINGS or WS_CLIPCHILDREN or WS_VISIBLE or LVS_NOCOLUMNHEADER or LVS_NOLABELWRAP or LVS_REPORT)

If you('re new to wb3d and) don't know what the above means and/or scares the hell out of you ;) then use the style editor in Schnok! (a free WB3D gui editor) to do it for you, get it here: http://www.blitzbasic.com/Community/posts.php?topic=62613

Danny

@Easy Power Soft

its possable like danny's post, although you would need to do some extra coding to handle the selected items.

setup LV_ITEM item structure using a bank and send the meesgae LVM_GETITEM you would need to check the structs LV_ITEM.state to see if the items selected. it would take a little bit of work but it could be done.

kev

Re the spinners - any way to use floats rather than just ints ?

Thanks a lot for this Info.

Kev, when the button style is XP and you make a button a child of a groupbox, the button has rounded corners but you can still see the square button behind it. I can supply a pic if you don't already know about this one.

Smiff: Sample ...

CommaPos = Int(2)
MySpinValue = Int(100) * (10 * CommaPos)

If CommaPos = 2 so the value from 100 (MySpinValue) is later 1.00
See code for calculation:

MyValue# = Float(MySpinValue / (10 * CommaPos))

You must set Int(YourMaxValue) * (10 * CommaPos) as maximally value on spinner gadget for powerful calculation.

This works good, but this have a little problem: In this sample MySpinValue works with "10000" as value instead of "100". Problem: Integers can have max. 4294967295 unsigned and signed max. 2147483647.

bye


sry for my bad english

Thanks for that useful routine - I use a similar conversion like this for trackbars which also only have int values.
The problem with spinners is one of display.
A label or textbox placed next to a spinner automatically becomes a "buddy" and I was seeing if I could avoid having to manually update the value shown in it or having to have a "dummy" buddy and then showing my "decimal" value in yet another label - seems like a lot of additional overhead.

@Chroma. I will look into this thanks.

@Smiff. im currently looking into using float, however there seems to be problems.

soon as ive some more info i will let you guys now.

kev

The spinners also cannot return negative values.
Its possible to set the range to a negative number but WB3D_GetSpinnerPos() cannot return it - unsigned ints ?

what I do is get the buddy's text and check for sign such as:

If picked_object <> 0 And picked_object <> terrain Then
     xs#=Float#(WB3D_GetGadgetText$(txtXScale))
     ss=Sgn(xs)
     If xs# <> 0 Then
          If ss>0 Then ScaleEntity picked_object,xs,xs,xs
     Else
      xs#=Float#(Abs(1/xs))
     ScaleEntity picked_object,xs#,xs#,xs#
      End If
End If

small update uploaded, this fixes spinners so they return negative values.

@Chroma, yes just seen this when creating groupboxs its best to first create the gadgets that are displayed within the groupbox then overlay the groupbox on the gadgets. the gadgets created show through the groupbox.

kev

Oops -with the last update the spinners now are disabled as soon as you set a value and always return zero !

@Smiff, did you copy the .decls to userlib as there updated.

if you have can you test this.

; WB3D styles
Include "WB3DStyles.bb"

Graphics3D 800,480,16,2
SetBuffer BackBuffer()

Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,800,500)
WB3D_SetQuitMessage "WB3D 3D/GUI quit","Sure To Quit Test.bb" 

window = WB3D_CreateWindow("test",100,100,500,300,0,0)

spinner_value = WB3D_CreateEditField("",40,5,100,20,window,0,2)
spinner = WB3D_CreateSpinner(141,5,40,20,window,1,0)
WB3D_SetSpinnerRange spinner,-100,100

While Not KeyDown(1)
	
		
	Select WB3D_WaitEvent()
		
		Case WB3D_EVENT_GADGET
			Select WB3D_EventSource()
			
			
			End Select
		
	End Select
		
Wend

WB3D_EndGUI()
End

kev

Yep - the decls fixed the disabling but negative values are still being returned as the value + 65536 . Easy enough work around I suppose.
Try this and move the spinner to a negative value :

; WB3D styles
Include "WB3DStyles.bb"

Graphics3D 800,480,16,2
SetBuffer BackBuffer()

Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,800,500)
WB3D_SetQuitMessage "WB3D 3D/GUI quit","Sure To Quit Test.bb" 

window = WB3D_CreateWindow("test",100,100,500,300,0,0)

spinner_value = WB3D_CreateEditField("",40,5,100,20,window,0,2)
spinner = WB3D_CreateSpinner(141,5,40,20,window,1,0)
WB3D_SetSpinnerRange spinner,-100,100
label=WB3D_CreateLabel("",141,40,60,20,window,0)

While Not KeyDown(1)
	
		
	Select WB3D_WaitEvent()
		
		Case WB3D_EVENT_GADGET
			Select WB3D_EventSource()
			Case spinner
			WB3D_SetGadgetText (label,WB3D_GetSpinnerPos(spinner))
			
			End Select
		
	End Select
		
Wend

WB3D_EndGUI()
End

Well, Ive spent some time now with WinBlitz3d but have now ground to a halt due to some major problems.
It is very promising but it still needs a lot of work in some areas.

The biggest problem is that quite often and for no apparent reason the Gui stops responding to events.

This also happens when you are manually updating the position of a trackbar or spinner. It seems that the sytem get flooded by events.

The spinners still do not return correct negative values - the buddy displays the correct value but the value obtained with GetSpinnerPos() is the value + 65536. If you use the buddy value this seems to be a lot slower for some reason.

My GUI is extremely demanding and I use most of the gadgets to their limit.
For simple interfaces this should be fine but for anything more complex where there is interaction between gadgets it currently is not working for me.
I shall keep an eye on this and hope that its updated/fixed in the future.

Hi Smiff


try removing the events using WB3D_FlushEvents().

for example

 ; window / gadget creation

select wb3d_eventsource()
       case trackbar
           trackbarpos = WB3D_GetTrackBarPos(trackbar)
           WB3D_FlushEvents()
end select

im gettin there but i am busy right now, with the next version WB3D_EventData() will return the correct value. this does seem strange as WB3D_GetSpinnerPos(spinner) Or $ffff0000 does return the correct negative. although the possitve numbers become negative ;)

any way dont worry i will try and get to the bottom of this a.s.p

kev

Thanks Kev - I tried the WB3D_FlushEvents(), but it seems that spinner and trackbar events are generated when modifying their positon via code ?? If they do is there any way to filter them out ?
I really apreciate all your work on this by the way - WB3d is so close to being the perfect gui for Blitz3d. My interface now looks so much better and has so much more scope for expansion that I don't want to use anything else !

Hi Smiff,
WB3D and the Windows API in general take some time and effort to get your head around, it's a rather complex beast, especially when you start playing with styles.
But I can guarantee you that's it's totally capable of effeciently handling very complex gui's. But I had to adjust my programming style a bit to match the way it operates.

For every big gui element or floating window I typically have 3 functions:
gui_myWindow_show() - which sets up, positions and prepares the window, fills gadgets with static values (eg. combo boxes with a certain selection of values).
gui_myWindow_update() - to capture events specific to this window and act upon it. This is called from you main loop.
gui_myWindow_refresh() - which refreshes the gadget's values when something has changed (either internally or externally).

So yes, to prevent a recursive loop/event re-entry, you have to do a flushevents at the end of the function where you fill gadgets and don't want to trigger an event (in my example the _show and _refresh functions).

With spinners and trackbars/sliders I find it easier to always set them to a 0 to 100 range at design time - and use a function at runtime to get or set whatever range I want to use for a specific value (for example -2.5 to +2.5 or 0 to 255). Here's two example functions I use for a trackbar together with an edit box to display the value in text/numbers; If the slider is touched I call the first, if the edit box is edited, I use the second function. Both complement each other and return me the exact value within the given range:

Function PEDIT_SliderToValue#( textGadget, sliderGadget, minValue#, maxValue#, doInteger=False)

;| min/max could be for example: 0..180 or -0.05...+0.05 or 0..1
;| NOTE: Slider/Trackbar MUST be set to 0 to 100 range!!

	merge# = Float#(WB3D_GetTrackBarPos(sliderGadget))/100.0
	val# = (merge# * maxValue#) + ((1.0-merge#) * minValue#)
	If doInteger Then
		WB3D_SetGadgetText textGadget, Int(val)
	Else
		WB3D_SetGadgetText textGadget, val#
	EndIf
	WB3D_FlushEvents()
	
	Return val#

End Function

Function PEDIT_ValueToSlider#( textGadget, sliderGadget, minValue#, maxValue#)

	;trans value to slider (within min/max range)
	range# = maxValue# - minValue#
	Val# = WB3D_GetGadgetText(textGadget)
	sliderval = ((val# - minValue#)/range#) * 100
	WB3D_SetTrackBarPos sliderGadget, sliderval
	WB3D_FlushEvents()
	Return val#

End Function

Hope this helps,
Danny

Many Thanks Danny - that's extremely helpful !

I have a problem with this. It is great, don't get me wrong! When I compile it everything goes fine. I end the compile, thats when everything goes whacky. On task manager under the Processes tab says that blitzcc.exe (the compiler) is still running. But every time I compile there is a new one there along with the old one. So after a while I get 43 blitzcc.exe processes. Thats when I get an error message telling me that my virtual memory is violently low. Can anyone help me with this??

Ked, sounds like a very old bug there. does this happen with the included examples? are you using the debuggers end(exploding bomb) to quit your compiled run?


kev

Hey. I got it working. I had Waitkey() in there so when I exit the window its still compiled and running because the runtime window is in there hidden. But its all good.

Hey is there going to be an HTMLView sometime? Just wondering. Right now I'm trying to get a TCP/IP thing going in WinBlitz3D. A chat.

Sorry for the fuss.

is SCHNOK completely functional?, say, could I make GUIs and used it with Winblitz3d is a normal way without expecting so many bugs?

This is my first contact with this post and with Winblitz and Schnok..

Sorry if someone has wrote before about that..


Thanks in advance,

@Ked, good its working. you can always use wb3d's WB3D_EVENT_KEYPRESS to get keyhit events, Ive looked into HTMLView gadgets but not sure if/when they will be added.

@Pinete, SCHNOK completely functional all it lacks the the mouse size&move gadget features most GUI designers have. although it does make up for it in other areas.

kev

Hey.

I'm not sure of how to make a menu. I can't figure it out. (That shows you how smart I am) But I try to make a File menu and it won't show up.

Hi Ked

quickly put togther menu example

Include "WB3DStyles.bb"

; setup gfx mode.
Graphics3D 640,480,16,2
Global switch=0

; install winblitz3d.
Global RuntimeWindow_hWnd = WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,300,200)
WB3D_SetQuitMessage "WinBlitz3D 3D/GUI","Sure To Quit" 
;WB3D_HideGadget RuntimeWindow_hWnd

; create winapi window, setting its title, and position on screen. use default style creation.
example_window = WB3D_CreateWindow("WB3D_CreateWindow Example",200,100,450,275,0,0)

; menus
menus = WB3D_WindowMenu(example_window)
file = WB3D_CreateMenu("File",0,menus,0)
	NewItem = WB3D_CreateMenu("New",1,file,0) : WB3D_AddMenuIcon(file,1,"menuBMPS/MENUNEW.BMP")
	OpenItem = WB3D_CreateMenu("Open",2,file,1) : WB3D_AddMenuIcon(file,2,"menuBMPS/MENULOAD.BMP")
	
		OpenItem_1 = WB3D_CreateMenu("Open Sub Item 1",43,OpenItem,0) 
		OpenItem_2 = WB3D_CreateMenu("Open Sub Item 2",20,OpenItem,0) 
		
			SUBOpenItem_1 = WB3D_CreateMenu("Sub Item 1",44,OpenItem_2,0) : WB3D_AddMenuIcon(file,44,"menuBMPS/MENULOAD.BMP") 
			SUBOpenItem_2 = WB3D_CreateMenu("Sub Item 2",45,OpenItem_2,1) 
				SUBOpenItem_5 = WB3D_CreateMenu("Sub Item 2",46,SUBOpenItem_2,0)
			
	WB3D_CreateMenu("",0,file,0)
	SaveItem = WB3D_CreateMenu("Save",3,file,0)  : WB3D_AddMenuIcon(file,3,"menuBMPS/MENUSAVE.BMP")
	WB3D_CreateMenu("",0,file,0)
	QuitItem = WB3D_CreateMenu("Quit",4,file,0) : WB3D_AddMenuIcon(file,4,"menuBMPS/MENUQUIT.BMP")

editmenu_window_1 = WB3D_CreateMenu("Edit",0,menus,0)
	CutItem = WB3D_CreateMenu("Cut",5,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,5,"menuBMPS/MENUCUT.BMP")
	CopyItem = WB3D_CreateMenu("Copy",6,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,6,"menuBMPS/MENUCOPY.BMP")
	PasteItem = WB3D_CreateMenu("Paste",7,editmenu_window_1,0) ;: WB3D_AddMenuIcon(editmenu_window_1,7,"menuBMPS/menupaste.BMP")
 
	WB3D_RadiocheckMenu editmenu_window_1,5,7,6
		
WB3D_UpdateWindowMenu(example_window)

; cleanup any old creation events, its better to do this before we enter the main
; event loop, when some gadgets are created they generate events.
WB3D_FlushEvents 

; setup out quit flag, and loop until the flag is set.
QUIT = 0
While Not QUIT = 1
	
	; generate an internal blitz event
	Flip
	Cls
	
	; get an event of the event queue.
	event = WB3D_WaitEvent()
	
	Select event
		
		Case WB3D_EVENT_KEYPRESS
		
			; wb_eventdata holds the key code that was pressed.
			keypressed = WB3D_EventData()
			Select keypressed
				
				Case WB3D_KEY_ESCAPE	
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
				
		Case WB3D_EVENT_WINDOW_CLOSE
		
			; wb3d_eventsource hold the handle to the window that close button was selected
			window = WB3D_EventSource()
			Select window
			
				Case example_window
					
					; set the flag to leave the loop.
					QUIT = 1
					
			End Select
	End Select
	

Wend

; use notify using external winapi constants. 
WB3D_Notify "WB3D GUI Window Example","Bye, Thats It I Quit",MB_OK Or MB_ICONASTERISK
WB3D_EndGUI()
EndGraphics
End

Thanks Kev, it's a great work!

btw: is there a way to paint 3dview (camera viewport) over a GUI?

OK, great. Thanks, Kev!

FiNegirO, see here.

http://www.winblitz3d.co.uk/forum/viewtopic.php?t=77

kev

@Kev:
Hey, how did you make all of this? How did you know how to do it??

Ked, I spent years learning basic,c++ and assembly language.

the winapi stuff was learned over the last 3 to 4 years, basicly through other peoples examples like one does :)

kev

Is there a way to create a window like the "About Blitz3D!" window? Where there is no X button or minimize button or maximize button??

Ked

window = WB3D_CreateWindow("Test About Style",100,100,100,100,0,WS_VISIBLE Or WS_ACTIVECAPTION)

you need to define styles when creating your window.

kev

I know, but I don't know what styles do what.

Hey! I have a function that that helps put text into textareas. It's not much just something I put together to help me out. Maybe it will help out others?

Function AddTextAreaText(textarea,txt$)
SetTextAreaText textarea,txt$+Chr$(13)
End Function

Is there anyway to add scrollbars onto textareas?
Thanks!
Ked

To add scrollbars, use the ES_AUTOHSCROLL and ES_AUTOVSCROLL styles.

Kev, is there a way yet to 'clear' a textarea's text?

d.

hi there,

im thinking on trying out winblitz3d for a small tool, but i would need something like a propertiesgrid:


do you think this (or something similar) is possible with winblitz3d? would make a donation for it, of course :)

thanks a lot!

cheers

@Danny, did i not add that before winblitz3d left beta? i will look into it.

@OJay, yes you would need to use listviews, and donations always welcome.

kev

hm, ok...but how would i hook in the appropriate gadget to the current selected item to edit it? see: there can be a few different types of items within the grid; such as: text (normal editfield), list (listbox), slider, spinner, color (opens a color requester), font (font requester), file (file requester) etc...

how would i calculate the exact position of the gadget where it has to be placed?

i now understand OJay, you can have standard 'propertiesgrids' using listviews although its not possable to add gadgets to its items container.

kev

i see.

ok, i'll stay with blitzui than i think, because there i can write a propertygrid-gadget on my own; although with a considerably amount of work...but at least its possible in theory...

sorry

have you seen this one: http://blitzbasic.com/Community/posts.php?topic=61612#688672 ?

sure, its blitzmax, but it uses the winapi, too...so maybe it can be applied to winblitz3d as well? or do you see any functions/features missing?

worth a try, i would guess :)

Yes, but when you use those it just scrolls without the scrollbars. Maybe I'm not doing it right?

yes you're right sorry... use WS_VSCROLL instead. Then the vertical scroll bar will be visible as soon as it's needed.

In case you haven't got it (or aren't using it), maybe you can use Schnok (a free wb3d gui editor) to help you out. You can tweak styles as much as you want and instantly see the result, tweak and play around with it - and export straight to blitz3d code that you can include in your project.

Get it here: http://www.blitzbasic.com/Community/posts.php?topic=62516#698450

Hope that helps

Hey guys, I have something else that should help out! Instead of having to always install WinBlitz3D yourself you could just make a function like below to do it for you.

Function Start(quitmessage$,hide$,bodytext$,titletext$)
If quitmessage$="no" And hide$="hide" Then
appwnd=WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_HideGadget appwnd
ElseIf quitmessage$="no" And hide$="show" Then
appwnd=WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
Elseif quitmessage$="yes" And hide$="hide" Then
appwnd=WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_SetQuitMessage(bodytext$,titletext$)
WB3D_HideGadget(appwnd)
Elseif quitmessage$="yes" And hide$="show" Then
appwnd=WB3D_InitializeGUI(SystemProperty("AppHwnd"),10,10,500,500)
WB3D_SetQuitMessage(bodytext$,titletext$)
EndIf
End Function

Hope this helps also!

...

What?