Rotation problem.

I have a game idea that uses a third person perspective viewpoint. Holding down the right mouse button and moving the mouse left or right causes the camera to rotate around the player character. The player steers the on-screen character with the arrow keys. My problem is this:

Regardless of the direction that the character appears to be facing (because the camera can be spun around him, as I said, resulting in the character potentially facing any direction of on screen rotation):

Pressing a directional arrow should make the character model rotate smoothly via the shortest direction until he faces in that direction before moving forward.

In other words:

Pressing the 'up' key will make the character turn to face away from the camera. If the player is already facing 'into' the screen then he will move forward.

Pressing the 'down' key will make the character turn to face the camera. If the player is already facing toward the camera then he will move forward.

Pressing the 'left' key will make the character turn to face the left of the screen. If the player is already facing toward the left of the screen then he will move forward.

Pressing the 'right' key will make the character turn to face the right of the screen. If the player is already facing toward the right of the screen then he will move forward.

Combinations of keys (for example, pressing 'up' and 'left') should, of course, cause the same type of behaviour for diagonal movement.

All of the above should work consistently regardless of the original rotation of the player model, which could be any angle depending on how the player rotates the camera.

Sorry for describing this in such minute, repetative detail, but I've asked for help with this before and people always seem to misunderstand what I'm after.

There does not appear to be any built in commands to exactly match my requirements. I gather that it has something to do with vectors, but I'm really not sure. My knowledge of mathematics sucks.

Can anyone help me with this, please?

I posted this code a while back ... maybe it can help you. User cursors and A+S to rotate the camera.

Stevie

Graphics3D 640,480,16,1

Global LIGHT = CreateLight()
Global PLANE = CreatePlane() 
EntityColor PLANE, 200,100,100
texture = CreateTexture( 32, 32 )
SetBuffer TextureBuffer( texture )
For y = 0 To 1
	For x = 0 To 1
		Color 100, 150+25*( ( x+y) Mod 2 ) , 100
		Rect x*16,y*16,16,16,1
	Next
Next
SetBuffer BackBuffer()
ScaleTexture texture, 50,50
EntityTexture PLANE, texture
FreeTexture texture

Global CUBE = CreateCube() : FitMesh CUBE, -2,0,-2,4,10,4 
Tmp = CreateCube() : FitMesh Tmp, -1,7,2,2,2,2 : AddMesh Tmp, CUBE : FreeEntity Tmp
Global TARGET = CreatePivot()

Global CAMERApivot = CreatePivot()
Global CAMERA = CreateCamera( CAMERApivot )
PositionEntity CAMERA, 0,50,-50
PointEntity CAMERA , CAMERApivot

While Not KeyDown(1)

	PositionEntity CAMERApivot , EntityX( CUBE ) , 0, EntityZ( CUBE )
	TurnEntity CAMERApivot, 0 , KeyDown(31) - KeyDown(30) , 0
	
	;move relative to camera
	Mx# = KeyDown(205) - KeyDown(203)
	Mz# = KeyDown(200) - KeyDown(208 )

	If Mx <> 0 Or Mz <> 0
		;move relative to camera
		TFormVector Mx, 0, Mz , CAMERApivot , 0
		TranslateEntity CUBE, TFormedX(), 0, TFormedZ()
		;turn relative to movement
		PositionEntity TARGET, EntityX( CUBE ) + TFormedX() , 0, EntityZ( CUBE ) + TFormedZ()
		TurnEntity CUBE, 0 , DeltaYaw( CUBE, TARGET ) * .25, 0
	EndIf
	
	RenderWorld()
	Flip

Wend

Here is some of my test code, not sure if it will work though, just wrote it on the spot here at work....

Graphics3D(800,600,32,2)
SetBuffer(BackBuffer())


ThisCamera							=CreateCamera()
ThisLight							=CreateLight(1)

ThisPlane							=CreatePlane()
EntityColor(ThisPlane,120,120,120)

For ThisCubeCnt = 1 To 20
	ThisCube							=CreateCube()
	EntityColor(ThisCube, Rnd(10,255), Rnd(10,255), Rnd(10,255))
	PositionEntity(ThisCube, Rnd(-50.0,50.0), 1, Rnd(-50.0,50.0))
Next


ThisPlayer							=CreatePivot()
ThisPivot							=CreatePivot(ThisPlayer)
ThisModel							=CreateCone(8,1)
EntityColor(ThisModel,Rnd(100,255), Rnd(100,255), Rnd(100,255))
RotateMesh(ThisModel, 90,0,0)
ScaleMesh(ThisModel, .5,.5,1)
EntityParent(ThisCamera, ThisPivot)
MoveEntity(ThisCamera,0,0,-10)
MoveEntity(ThisPlayer,0,1,0)



While Not KeyDown(1)
	ThisMX								=(GraphicsWidth() / 2) - MouseX()
	ThisMY								=MouseY() - (GraphicsHeight() / 2)
	MoveMouse((GraphicsWidth() / 2) , (GraphicsHeight() / 2))
	
	If MouseDown(2) Then 
		ThisRX								=ThisRX + ThisMX
		ThisRY								=ThisRY + ThisMY
		If ThisRY >  89 Then ThisRY =  89
		If ThisRY < -89 Then ThisRY = -89
	EndIf
	RotateEntity(ThisPlayer,0,ThisRX,0)
	RotateEntity(ThisPivot,ThisRY,0,0)
	ThisSpeed#							=.5
	ThisVX#								=EntityX#(ThisPlayer,1)
	ThisVZ#								=EntityZ#(ThisPlayer,1)
	If KeyDown(200) Then MoveEntity(ThisPlayer,0,0, ThisSpeed)
	If KeyDown(208) Then MoveEntity(ThisPlayer,0,0,-ThisSpeed)
	If KeyDown(203) Then MoveEntity(ThisPlayer,-ThisSpeed,0,0)
	If KeyDown(205) Then MoveEntity(ThisPlayer, ThisSpeed,0,0)
	ThisVX#								=ThisVX - EntityX#(ThisPlayer,1)
	ThisVZ#								=ThisVZ - EntityZ#(ThisPlayer,1)
	If ThisVX > 0 Or ThisVZ <> 0 Then
		AlignToVector(ThisModel,-ThisVX,0,-ThisVZ,3,.3)
	EndIf
	PositionEntity(ThisModel, EntityX(ThisPlayer,1), EntityY(ThisPlayer,1), EntityZ(ThisPlayer,1))
	RenderWorld()
	Flip()
Wend
End

The method posted by stevie G is best and simplest and i think you should use that one :)

But it doesn't do what he wants it to do. Read what he is saying carefully, then run the two versions and see which accomplishes the task he wants....

I don't see any calls to the mouse for view rotation in Stevie's code, yet:


Perhaps I misread.....

@ Dark Half,
I was under the impression that the guy just wanted movement similar to Mario 64 which is what the code example I posted does. Sure, the camera rotation is done using keys rather than mouse but it's a one line change to implement the mouse look.

I haven't tried your code so it may well work better. That said, I really couldn't care less whether he uses your code, mine or the bastard son of both ;)

Stevie

@Stevie
I could care less who's code he uses as well, hell, he might as well come up with his own.

Stevie G wrote:

I chose the third option and it works very well. Thanks, guys!

aligntovector isn't that good to use, watch the angles using it, it can take an eternity using it to get to the next angle as it really slows closer to the new angle( you might overcome it with some math, i never did.)

Even with the rate parameter you don't get the desired effect.
Also the feel of the turn is better using the other method.