Question On Camera Zoom

what i'm trying to do is give the impression of immense size by zooming in the camera... but this causes everything to slow down... especially the particles...

what am i missing... is there any way to keep the speed up when zoomed in (about 12)

thx

--Mike

Changing the CameraZoom changes the FoV, so you see more and render -> everything slows down. Or if you reduce the FoV you'll end up rendering the particles bigger on screen and the fill rate kills the performance.

So high FoV shows so much (polygons) that it can slow down things, and low FoV can make rendering even slower because you stuff on screen gets bigger - even if you don't see more than few dozen particles, because these alone can increase the fillrate too high.

Not the best explanation but I'm sipping only my first morning cup of coffee so I'm not yet fully awake yet :)

I think the highly zoomed particles are essentially the test called Massive Overdraw in some 3D benchmarks. It will bog down just about any graphics card.

When you zoom in you actually see LESS, as the field of view is shorter, but the depth of field remains the same.

Even when you set CameraZoom to 12 you still won't see anything beyond the 'far' limit of the camera.

Try changing the camera 'near' limit to either 1, or 0.1 (whichever you don't currently have it set at) - remember somebody telling me years ago (xMystik?) that he had similar problems, and that was part of the solution.

thx guys...
Gfk... yeah, that's what i thought as well... you would see less, but i wasn't sure... lemme give the near limit thing a shot...

--Mike

a good trick to show size is to not have the entire object on screen at the same time. You can see this in star wars movies etc, where the big imperial ships are often have bits cut off

Umm... I tried to explain problems going BOTH directions with FoV/CameraZoom... CameraZoomXYZ itself doesn't tell me anything because I use the one-and-only way to do this, ie FoV routine from the cod archives. FoV I can understand, CameraZoom makes my head spin. :)

Apparently CameraZoom"verybignumber" gives you narrow FoV, and CameraZoom"almostzero" gives you wide FoV, so decrypt my morning ramblings using these values.

> is there any way to keep the speed up when zoomed in (about 12)

what about not zooming? instead position the camera along a line to the target, that should look exactly like zooming.

ya know... that's a great idea muk...

nice outta the box solution to a problem... i'll look at that tommorrow...

--Mike

hi Red, i read your recent post in general discussion, and suddenly realized that camera position rather than zoom is all that is needed, so i'll credit you with the "out of the box" solution. :)

I did a little test and actually camerazoom is bad, not just because it costs the framerate but because it's technically not right anyway!

camerazoom makes things travel towards orthographic projection which, i think is wrong, in real life there is no orthographic projection, when you looks though binoculars you see what you would see if you were standing closer to the object, so all you need is the maths to position a camera from 3d point A to B then.

I wrote up a quick test actually, just to check what it is like, there's no algo there, just hard-coded values to emulate it but it gives you the impression anyway.

Maybe i'll have a go at the algo too. sounds like fun.

;Zoom test, keys Q/A=camera zoom, W/S=camera position

Graphics3D 640,480,0,2
SetBuffer BackBuffer()

cam=CreateCamera()
light=CreateLight()
RotateEntity light,90,0,0

cube=CreateCube()
PositionEntity cube,0,0,200

While Not KeyHit(1)
 UpdateWorld
 RenderWorld

 If KeyDown(16) ;Q key
  zoom#=zoom#+0.1
  If zoom#>20 Then zoom#=20
  CameraZoom cam,zoom#
 EndIf
 If KeyDown(30) ;A key
  zoom#=zoom#-0.1
  If zoom#<1 Then zoom#=1
  CameraZoom cam,zoom#
 EndIf

 If KeyDown(17) ;W key
  pos#=pos#+(EntityDistance(cam,cube)/50)
  If pos#>190 Then pos#=190
  PositionEntity cam,0,0,pos#
 EndIf
 If KeyDown(31) ;S key
  pos#=pos#-(EntityDistance(cam,cube)/50)
  If pos#<0 Then pos#=0
  PositionEntity cam,0,0,pos#
 EndIf

 TurnEntity cube,0.4,0.2,0.3

 Text 0,0,"camera zoom="+zoom#
 Text 0,12,"camera Z mt="+EntityZ(cam)

 Flip
Wend

Actually, it won't. It will look like the camera is moving (because thats what its doing).

If you have a camera at point A, an object at Point C, and an object mid-way, Point B - zooming the camera you will still be able to see both of the objects.

If you move the camera close to Point C, then you WON'T see object B.

Changing the camera zoom is vastly different to just moving the camera - you're changing the camera's field of view. Its important to understand this difference.

yeah... i just tried it... while the concept was interesting in theory, it just didn't look right in actual practice... for a lot of the reasons that GfK mentions...

but thx anyway muk... it was a good idea, and may come in usefull for other situations...

--Mike

done. no algorithm, just a camera on a pivot.

;Camera Zoom/Position test
;WASD=camera move, left/right mouse=camera zoom, Space=zoom mode

Graphics3D 640,480,0,2
SetBuffer BackBuffer()

camerapivot=CreatePivot() ;pivot
camera=CreateCamera(camerapivot) ;camera on pivot
light=CreateLight()
RotateEntity light,90,0,0

Type cubetype
 Field hent,htex
End Type

For i=0 To 5 ;create and texture 6 cubes
 cube.cubetype=New cubetype
 cube\hent=CreateCube()
 If i=0 Then x=0 : y=0 : z=15 : r=128 : g=64 : b=64 : name$="front"
 If i=1 Then x=0 : y=0 : z=-15 : r=64 : g=128 : b=64 : name$="back"
 If i=2 Then x=15 : y=0 : z=0 : r=64 : g=64 : b=128 : name$="right"
 If i=3 Then x=-15 : y=0 : z=0 : r=64 : g=128 : b=128 : name$="left"
 If i=4 Then x=0 : y=15 : z=0 : r=128 : g=64 : b=128 : name$="upper"
 If i=5 Then x=0 : y=-15 : z=0 : r=128 : g=128 : b=64 : name$="lower"
 PositionEntity cube\hent,x,y,z
 cube\htex=CreateTexture(64,64)
 EntityTexture cube\hent,cube\htex
 SetBuffer TextureBuffer(cube\htex)
 ClsColor r,g,b : Cls : Text 12,12,name$ : Text 12,36,"cube"
 SetBuffer BackBuffer()
Next

MoveMouse 640/2,480/2 ;centre the mouse

While Not KeyHit(1) ;main loop
 UpdateWorld
 RenderWorld

 ;camera movement, using pivot
 If KeyDown(17) ;W key, forward
  MoveEntity camerapivot,0,0,0.1
 EndIf
 If KeyDown(30) ;A key, left
  MoveEntity camerapivot,-0.1,0,0
 EndIf
 If KeyDown(31) ;S key, back
  MoveEntity camerapivot,0,0,-0.1
 EndIf
 If KeyDown(32) ;D key, right
  MoveEntity camerapivot,0.1,0,0
 EndIf

 ;camera mouse look, using pivot
 lastx=msex : If lastx=0 Then lastx=MouseX() ;init lastx/lasty
 msex=MouseX() : movex=lastx-msex
 lasty=msey : If lasty=0 Then lasty=MouseY()
 msey=MouseY() : movey=msey-lasty
 camx#=camx#+Float(movey*0.5) : camy#=camy#+Float(movex*0.5)
 RotateEntity camerapivot,camx#,camy#,0

 If KeyHit(57) Then key=Not key ;Space, zoom mode toggle

 If key ;camera zoom
  camz#=0
  If MouseDown(1) Then zoom#=zoom#+0.1
  If MouseDown(2) Then zoom#=zoom#-0.1
  If zoom#<1 Then zoom#=1
 EndIf

 If Not key ;camera position
  zoom#=1
  If MouseDown(1) Then camz#=camz#+0.2
  If MouseDown(2) Then camz#=camz#-0.2
  If camz#<0 Then camz#=0
  ;do a simple distance collision check
  closest#=1000
  For cube=Each cubetype
   If EntityDistance(camera,cube\hent)<closest#
    closest#=EntityDistance(camera,cube\hent)
   EndIf
  Next
  If closest#<3 Then camz#=camz#-0.2 ;zoom back if too close
 EndIf

 PositionEntity camera,0,0,camz# ;zoom camera from pivot
 CameraZoom camera,zoom# ;normal/real zoom

 ;spin the 6 cubes
 For cube=Each cubetype
  TurnEntity cube\hent,0.4,0.3,0.2
 Next

 ;some info
 Text 0,0,"Space to toggle zoom mode, left/right mouse to zoom"
 Text 0,12,"camera zoom="+zoom#
 Text 0,24,"camera z pos="+EntityZ(camera)

 Flip
Wend