JV-ODE Physics Thread 6

Now available for Blitz3D & BlitzMax (Win32)

The JV-ODE Physics Wrapper is an advanced user library supporting almost all of the Open Dynamics Engine functions wrapped inside a DLL (Dynamic Link Library).

The library can be used with any programming language that supports DLL's, including Blitz3D and BlitzMax (Win32). The Euler rotation system in JV-ODE has been adapted to match the left-handed Euler rotation used in Blitz3D, however functions for accessing Quaternion and Axis Angle rotation systems are also included. The full versions contain all of the necessary files to get you started, including over 30 demos showing the various features found in ODE and a complete Function Reference document.

The BlitzMax (Win32) version also features a built-in 'bare-bones' OpenGL 3D engine module and B3D mesh loader module for demo purposes.

To view more information and screenshots click here.

Options are now available to purchase the wrapper using either PayPal or Share*it.

The Blitz3D restricted demo version is now available for download here (169KB)

The BlitzMax (Win32) restricted demo version is now available for download here (238KB)

Have Fun :)

Previous JV-ODE Threads: 1 2 3 4 5
JV-ODE Player Factory Forum

Useful Links: ODE.org Website - ODE User Guide (PDF) - ODE User Guide (HTML) - ODE Archives

cannot seem to get collision with trimesh, sphere seems to be colliding with non existant tris.

If you post (or send me via email) the problematic code including the mesh, I'll take a look for you.

What mesh format are you converting into a TriMesh?

same prob happens with *.x and *.b3d, emailed ya

Thanks for sending it :)

Ok, the mesh appears to be colliding correctly. I think you may be getting caught out by the mirror here, if a mesh is positioned lower than the mirror/plane, the part that's submerged appears as an inverted solid mesh above the plane level.

Try the following code with the 'CarDemo-TriMesh-Sphere.bb' demo and add your mesh to the media folder to see the mesh colliding correctly...

; ###################################################################################################

; ### CREATE TRIMESH

demomesh=LoadMesh("media\test.b3d")
ScaleMesh demomesh,1,0.3,1

trimesh=CreateTriMesh(Space,demomesh)
dGeomSetRotation(trimesh,0,0,0)
dGeomSetPosition(trimesh,0,30,0)

RotateEntity demomesh,0,0,0
PositionEntity demomesh,0,30,0

EntityColor demomesh,255,255,255
EntityAlpha demomesh,1

demotexture=LoadTexture("media\terrain.png")
ScaleTexture demotexture,0.08,0.08
EntityTexture demomesh,demotexture

; ###################################################################################################

thing is, there is no mirror in what im trying, its like there is some invisible plane blocking it (but there isnt in code)

Well, I'm having to speculate as there wasn't any code in the archive you sent over, only two mesh files. I can't find any problems with those two meshes, the mirror was the only obvious cause that springs to mind.

Can you resend the meshes with the source code (or an example) so that I can see the exact problem?

Your TriMesh sounds like it isn't aligned with the visible mesh, but without seeing your TriMesh setup it's hard to say for sure what's causing the problem.

it seems to work if i dont scale the mesh down, (btw i thought i sent code) but it seems ok if i dont scale.. so i wont

edited: was using scaleentity instead of scale mesh on pieces i was cloneing, changed to scalemesh fixed it

Yep, you need to use ScaleMesh.

The CreateTriMesh() function uses the source mesh dimensions for its own scale, ScaleEntity doesn't change the actual mesh structure hence the mis-alignment. In your case the visible mesh would be scaled ok, but the TriMesh would be the same size as the original source mesh dimensions prior to re-sizing.

I didn't receive any code in the archive, only the two test meshes. I could've saved you some head-scratching if I saw your TriMesh setup code, oh well at least you've cracked it now :)

Hi,

The ultimate RagDoll :-)

http://www.planetdan.net/pics/misc/georgie.htm

Use the mouse

erm, cannot seem to return if a collision has happened on a geo, any ideas?

DebugLog dGeom1CountCollisions(MainPlayer\PhysEntity\Geom)

ok ZJP, now do that in blitz+ode ;)

btw: ^^
[a http://user.blue-cable.de/ojay/ups.JPG] sorry vip3r, you're damn right :D

Nice RagDoll considering it's made in Flash :)

OJay, can you either shrink or remove the image please, it's too damn ugly :P [edit] Thanks ;)


Well, going on the incredibly detailed explanation of the problem, I can deduce that 'MainPlayer\PhysEntity\Geom' isn't a geom class or it doesn't exist :P

Does it give any error or return a constant zero?

Are you using single or multiple spaces?

Have you tried 'dGeom2CountCollisions(MainPlayer\PhysEntity\Geom)'?

Have you tried the 'CarDemo-DetailedC.bb' demo?

The more info you give, the better and faster the solution ;)

Can someone please provide an example of a slider joint? Something like a cube on an invisible bungey cord that drops under gravity but is pulled back by the slider joint.

According to the docs there's no dJointSetSliderAnchor() to position the joint, and I can't get the params to do what I thought they'd do. My slider works just like a rigid Fixed joint :(

Here you go Shifty...

; ###################################################################################################
; #										JV-ODE - Slider Demo										#
; #									Code by Jim Williams (VIP3R)									#
; ###################################################################################################

AppTitle "JV-ODE - Slider Demo"

Include "JV-ODE.bb"

Graphics3D 800,600,0,2

Global SliderRange=30

Type ODEGeom
	Field body
	Field geom
	Field mesh
End Type

Dim Sphere(10)
Dim Joint(10)

; ###################################################################################################

; ### Setup ODE

Global World=dWorldCreate()
Global Space=dHashSpaceCreate(0)
Global ContactGroup=dJointGroupCreate(0)

dWorldSetAutoDisableFlag(World,1)
dWorldSetGravity(World,0,-0.98,0)
dContactSetMode(dContactBounce)
dContactSetBounce(0.1)
dContactSetMu(48)

; ### Create Slider

For count=1 To 2
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	Sphere(count)=ode\body
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,-30,100-(count*30),0)
	dBodySetAutoDisableFlag(ode\body,1)
	ode\geom=dCreateSphere(Space,4)
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateSphere()
	ScaleMesh ode\mesh,4,4,4
	RotateMesh ode\mesh,0,0,0
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,Rand(255),Rand(255),Rand(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
	If count=1
		Joint(count)=dJointCreateBall(World,0)
		dJointAttach(Joint(count),0,Sphere(count))
		dJointSetBallAnchor(Joint(count),dBodyGetPositionX(Sphere(count)),dBodyGetPositionY(Sphere(count)),dBodyGetPositionZ(Sphere(count)))
		Else
		Joint(count)=dJointCreateSlider(World,0)
		dJointAttach(Joint(count),Sphere(count-1),Sphere(count))
		dJointSetSliderAxis(Joint(count),0,1,0)
		dJointSetSliderParam(Joint(count),dParamLoStop,-SliderRange)
		dJointSetSliderParam(Joint(count),dParamHiStop,SliderRange)
		End If
Next

; ### Create light

Global Light=CreateLight()

RotateEntity Light,45,-90,0
LightColor Light,255,255,255
AmbientLight 130,130,130

; ### Create camera

Global Camera=CreateCamera()
CameraClsColor Camera,0,0,0
CameraRange Camera,1,1000
PositionEntity Camera,0,90,-100
RotateEntity Camera,30,0,0

; ### Create plane

dCreatePlane(Space,0,1,0,0)

Plane=CreatePlane()

EntityAlpha Plane,0.8

PlaneTexture=CreateTexture(128,128,9)

ClsColor 0,200,80
Cls

Color 255,255,255

Rect 0,0,64,64,1
Rect 64,64,64,64,1

CopyRect 0,0,128,128,0,0,BackBuffer(),TextureBuffer(PlaneTexture)
ScaleTexture PlaneTexture,20,20
EntityTexture Plane,PlaneTexture,0,0

Mirror=CreateMirror()

; ###################################################################################################

While Not KeyHit(1)

	UpdateKeys()

	PTime=MilliSecs()

	If MilliSecs()-Timer>700
		AddObject()
		Timer=MilliSecs()
		End If

	UpdateGeoms()

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.1)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime

	UpdateWorld

	RenderWorld

	Text 0,0,"JV-ODE Version "+dGetVersion()
	Text 0,15,"Physics Time:"+PhysicsTime
	Text 640,0,"Add Force To Slider"
	Text 640,15,"Using Arrow Keys"
	Text 640,55,"Add Motor Velocity"
	Text 640,70,"Using F1 & F2"

	Text 0,80,"Slider Position: "+dJointGetSliderPosition(Joint(2))
	Text 0,95,"Slider Rate: "+dJointGetSliderPositionRate(Joint(2))

	Flip

Wend

dJointGroupDestroy(ContactGroup)
dSpaceDestroy(Space)
dWorldDestroy(World)
dCloseODE()

End

; ###################################################################################################

Function AddObject()

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,30,80,0)
dBodySetAutoDisableFlag(ode\body,1)
ode\geom=dCreateBox(Space,10,5,10)
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,5,2.5,5
EntityColor ode\mesh,Rand(255),Rand(255),Rand(255)
EntityAlpha ode\mesh,1
EntityShininess ode\mesh,0.7

End Function

; ###################################################################################################

Function UpdateKeys()

dBodyEnable(Sphere(2))

If KeyDown(59)
	dJointSetSliderParam(Joint(2),dParamVel,-3)
	dJointSetSliderParam(Joint(2),dParamFMax,100)
	End If

If KeyDown(60)
	dJointSetSliderParam(Joint(2),dParamVel,3)
	dJointSetSliderParam(Joint(2),dParamFMax,100)
	End If

If dJointGetSliderPosition(Joint(2))=SliderRange Or dJointGetSliderPosition(Joint(2))=-SliderRange
	dJointSetSliderParam(Joint(2),dParamVel,0)
	dJointSetSliderParam(Joint(2),dParamFMax,100)
	End If

If KeyDown(203) Then dBodyAddForce(Sphere(2),-10,0,0)
If KeyDown(205) Then dBodyAddForce(Sphere(2),10,0,0)
If KeyDown(200) Then dBodyAddForce(Sphere(2),0,10,0)
If KeyDown(208) Then dBodyAddForce(Sphere(2),0,-10,0)

End Function

; ###################################################################################################

Function UpdateGeoms()

For ode.ODEGeom=Each ODEGeom
	If dBodyIsEnabled(ode\body)
		RotateEntity ode\mesh,dGeomGetPitch#(ode\geom),dGeomGetYaw#(ode\geom),dGeomGetRoll#(ode\geom)
		PositionEntity ode\mesh,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)
		End If
Next

End Function

; ###################################################################################################

The demo shows how to setup the slider, it doesn't have any spring/dampening yet though.

There's no need to specify an anchor position for a slider, it actually has two anchors - anchor 1 is positioned at body 1, anchor 2 is positioned at body 2.

Many thanks. I was trying to attach the Slider to 'the world' with an object on the other end. Adding bungy-bounce was easy enough (dParamBounce). Of course, now I have to think how to create this in my limited joint description system. It's not straightforward referencing a body in a linked-list ;)

any idea on the best frame limiting method? tried out shiftys stuff in another post but it doesnt really work all that well, erm someone must have a solution

The best method is to use a fixed frame speed (30-60 fps etc) for the physics and separate timing for the rendering.

Here's a 10 Pin Bowling demo for Jeff...

; ###################################################################################################
; #									JV-ODE - 10 Pin Bowling Demo									#
; #									Code by Jim Williams (VIP3R)									#
; ###################################################################################################

AppTitle "JV-ODE - 10 Pin Bowling Demo"

Include "JV-ODE.bb"

Graphics3D 800,600,0,2

Global Ball

Global Aim=0
Global BallMass#=200

Dim PinBody(10)
Dim PinGeom(10)
Dim PinMesh(10)

Type ODEGeom
	Field body
	Field geom
	Field mesh
End Type

; ###################################################################################################

; ### Setup ODE

Global World=dWorldCreate()
Global Space=dHashSpaceCreate(0)
Global ContactGroup=dJointGroupCreate(0)

dWorldSetAutoDisableFlag(World,1)
dWorldSetGravity(World,0,-0.98,0)
dContactSetMode(dContactBounce)
dContactSetBounce(0.2)
dContactSetMu(48)

; ### Create light

Global Light=CreateLight()

RotateEntity Light,45,-90,0
LightColor Light,255,255,255
AmbientLight 130,130,130

; ### Create camera

Global Camera=CreateCamera()
CameraClsColor Camera,0,0,0
CameraRange Camera,1,1000
PositionEntity Camera,0,20,-50
RotateEntity Camera,30,0,0

; ### Create plane

dCreatePlane(Space,0,1,0,0)

Plane=CreatePlane()

EntityAlpha Plane,0.8

PlaneTexture=CreateTexture(128,128,9)

ClsColor 0,200,80
Cls

Color 255,255,255

Rect 0,0,64,64,1
Rect 64,64,64,64,1

CopyRect 0,0,128,128,0,0,BackBuffer(),TextureBuffer(PlaneTexture)
ScaleTexture PlaneTexture,20,20
EntityTexture Plane,PlaneTexture,0,0

Mirror=CreateMirror()

; ###################################################################################################

AddBall(0,4,-40)
AddPins()

While Not KeyHit(1)

	UpdateKeys()

	PTime=MilliSecs()

	UpdateGeoms()

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.1)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime

	UpdateWorld

	RenderWorld

	Text 0,0,"JV-ODE Version "+dGetVersion()
	Text 0,15,"Physics Time:"+PhysicsTime
	Text 640,0,"F1 - Add New Ball"
	Text 640,15,"Space - Push Ball"
	Text 640,30,"Arrows - Adjust Aim"
	Text 0,50,"Aim: "+Aim

	Flip

Wend

dJointGroupDestroy(ContactGroup)
dSpaceDestroy(Space)
dWorldDestroy(World)
dCloseODE()

End

; ###################################################################################################

Function AddBall(xp#,yp#,zp#)

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
Ball=ode\body
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,xp,yp,zp)
dBodySetAutoDisableFlag(ode\body,1)
mass=dMassCreate()
dMassSetSphereTotal(mass,BallMass,2.4)
dBodySetMass(ode\body,mass)
dMassDestroy(mass)
ode\geom=dCreateSphere(Space,2.4)
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateSphere()
ScaleMesh ode\mesh,2.4,2.4,2.4
EntityColor ode\mesh,Rand(255),Rand(255),Rand(255)
EntityAlpha ode\mesh,1
EntityShininess ode\mesh,0.7

End Function

; ###################################################################################################

Function AddPins()

xp#=0
yp#=6
zp#=70

padding=7

For count=1 To 10
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	PinBody(count)=ode\body
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,xp,yp,zp)
	dBodySetAutoDisableFlag(ode\body,1)
	ode\geom=dCreateCylinder(Space,1.4,10)
	PinGeom(count)=ode\geom
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateCylinder(8)
	PinMesh(count)=ode\mesh
	ScaleMesh ode\mesh,1.4,5,1.4
	EntityColor ode\mesh,Rand(255),Rand(255),Rand(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
	xp=xp+padding
	If count=1 Then xp=xp-((padding*1)+(padding*0.5)) : zp=zp+padding
	If count=3 Then xp=xp-((padding*2)+(padding*0.5)) : zp=zp+padding
	If count=6 Then xp=xp-((padding*3)+(padding*0.5)) : zp=zp+padding
Next

End Function

; ###################################################################################################

Function UpdateKeys()

If KeyHit(59)=1
	AddBall(0,4,-40)
	End If

If KeyDown(203)=1
	Aim=Aim-1
	End If

If KeyDown(205)=1
	Aim=Aim+1
	End If

If KeyDown(57)=1
	dBodyEnable(Ball)
	dBodyAddForce(Ball,Aim*0.5,0,400)
	End If

End Function

; ###################################################################################################

Function UpdateGeoms()

For ode.ODEGeom=Each ODEGeom
	If dBodyIsEnabled(ode\body)
		RotateEntity ode\mesh,dGeomGetPitch#(ode\geom),dGeomGetYaw#(ode\geom),dGeomGetRoll#(ode\geom)
		PositionEntity ode\mesh,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)
		End If
Next

End Function

; ###################################################################################################

My code was actually about getting the same physics timing with different screen refresh rates. It doesn't help keep things smooth.

What's wrong with your system?

The only way to really get smooth, constant framerate is to ensure your rendering and updates are completed within the time of a frame. If you split rendering and physics timings, at some point they're going to be executed at the same program cycle and you'll need to render both. If the processing takes longer than a frame you're going to ruin the smoothness.

By my reckoning, if there's going to be occassions where physics and rendering are rendered simultaneously, to get that framerate smooth I need to keep physics+render < frametime for those frames. And if I can manage physics+render < frametime for those frames, I can amange it for all frames. Hence in my program I lock to the screen refresh and keep everything executing in 1 screen refresh period (about 16 ms at 60 Hz).

Things like frame tweening allow you to calculate only some frames and interpolate the rest at less overhead. I guess in theory it would be possible to render graphics on one frame, update physics the next tweening the graphics, giving more time for processing yet keeping a 60 fps update, though physics would be less accurate.

Otherwise, there's no real solution that I know of. I've yet to find a professional full-price game that doesn't have slowdowns and poor framerates at times!

The term 'frame limiting' would imply that there is enough processing time per frame for at least one pass of the physics, rendering and logic. Frame limiting is used to prevent the physics/render/logic updating too quickly on faster machines than the minimum requirements.

Let's assume we have our game loop frame time split as follows:

Logic: ~3 fps
Physics: ~7 fps
Rendering: ~50 fps

Total: ~60 fps (minimum design framerate)

Limiting the frame speed to 60 fps will work fine here on all machines except those which cannot reach the minimum design speed of 60 fps, then we get the poor frame rates.

The only time you will benefit from separate timing is if you have redundant processing time available during each frame update. If a machine has a refresh rate of 85Hz in the above situation, we will have 25 fps free per frame to update the rendering or process more logic. But not the physics, which -must- run at an identical frame rate on both the 85Hz machine and the 60Hz machine for the simulation to remain accurate and consistent on both machines.

If you need the physics to run faster or with increased accuracy, you will have to sacrifice render/logic frame time, like so...

Logic: ~3 fps
Physics: ~7 fps (two passes at 7 fps or one at 14 fps)
Physics: ~7 fps
Rendering: ~43 fps (minus 7 fps)

Total: ~60 fps (minimum design framerate)

You can't process the physics during any spare frame time available on faster machines, because it simply defies the minimum requirements of the design. It would mean the physics will never run at full speed on the 60Hz machines.

In a nutshell, the physics MUST run at a constant frame rate, regardless of render/logic timing and free processor time during a frame. But most importantly, the physics MUST be able to run at full speed (whatever it is) at the minimum design framerate.

I think that dBodyDestroy command doesn't remove objects from the world. How do I remove objects from the world? The ball and the pins that were knocked down should be removed before the next roll of the ball and all pins should be removed and 10 new pins set up before the next frame of the game. In Frame 10, you get three rolls of ball if you get a spare or a strike.

Which is where my physics timing method works, where the game is 'frame-limited' to the refresh rate. I guess I'm not really understanding what {cYanide} wants. If he's not capped to VWait : Flip, he ought to be to frame limit and keep things smooth and at a constant speed. If he is capped to frame rate and not processing quickly enough every frame so some frames overrun the wait and you get jitters, the only fix I know of is to reduce processing requirements, or cap to a sub frame-rate at say half the screen refresh rate.

What other options are there? What's the problem {cYanide}'s having?

i ended up just forcing the physics to run at a certain "fps", works fine,

erm one more Q, ive noticed that when 2 or more trimeshes are overlapping the physics time goes rather high, im not really sure this is, as i wouldnt expect trimeshes to be tested against eachother... if thats even whats happening.

is there a way to stop this as currently i have to position my map pieces with a lil gap (visible) so it wont inc the phys time like mad

Assuming for trimeshes you mean static scenery, drop them into a subspace and disable internal collisions for that.

ODE_world=dWorldCreate()
ODE_space=dHashSpaceCreate(0)
ODE_scenery_space=dHashSpaceCreate(ODE_space)
dSetInternalSpaceCollideMode(0)

And create your trimeshes in ODE_scenery_space instead of ODE_space. Create your moving objects in ODE_space so they collide with each other.

that did it;)

You don't need to destroy them, you can re-use them by resetting their position and rotation. When you destroy an ODE body or geom, you must also delete the ODEGeom type objects associated with them (ode\body, ode\geom etc). Btw, where did you learn your manners? because you need a refresher course.


Exactly right, the code either needs streamlining or you have to settle for a lower design frame rate. Your alternative timing method is one of the best I've seen so far, but the simulation would suffer from inconsistency across different frame rates ;)

Okay, I see what you're getting out, having experienced a frusting couple of days. With my ODE scaling system, ODE progresses at the same rate on different refreshes, but my custom force functions applied every frame were of course running at different speeds between systems. I've just implemented a straightforward tweening system and it works very well, with the same smooth framerate as I was getting before, yet with physics locked to 50 Hz regardless of system, (50 Hz is every 20 ms, which can be measured properly unlike 60 Hz's 16.666667 ms and won't exceed one update per frame)

I'll write a proper explanation later in the Tweening thread.

I've ran against a wall with my current project and hopefully one of you can point me the right direction. I need no ready solution, just some ideas how to do it.

Here's the scenario:

Plastic coins (Cylinders,2x1) dropping into a 'slimy'/high viscosity fluid(Plane). The coins should penetrate the fluid/swim in it. If two coins collide (one dropping onto another), they should slip off each other (better: the bottom coin should dive a bit into the fluid and then evade to the side while the upper coin slips into the fluid).

I experimented a lot with Soft-ERP/CFM, but no matter what I do, either the coins do sink or bounce off with high speed.

Any ideas what contactmodes are best for the coins/plane ?

Thanks in advance
Jake

Have you tried using a box for the slime instead of a plane? The plane might be too 'thin'.

It might also be due to incorrect mass/density of the coins/slime.

Another thing that could cause problems is the ODE dCylinder geom, when two cylinders are dropped directly on top of each other (end on end, like a stack of coins) it can create faulty contacts causing them to fly off at high speed. The dCylinder isn't part of the original ODE library (like dCCylinder), so its reliability is suspect.

CFM probably isn't ideal as there's a limit on penetration. You'd probably be better off writing your own force routine where if object is in fluid, apply force upwards greater than gravity.

This dCylinder problem is exactly what happens. I'll give CCylinder a try, though this will make collisions appear inaccurate. Maybe I could stick to dCylinder and try to limit this "Fly off" manually.

If I manage to get this stable I will let you know and post an example. This could take a week or two due spare time to code.

Jake

CCylinders won't work for coins becausae they have spherical ends. A CCylinder is a Pill shape.

If you have to use a coin shape (you can't get away with using thin boxes) your best solution is to use several box geometries each rotated slightly, creating a multi-pronged star (still with a cylinder mesh), or more difficult to calculate placing them around the edge with one in the centre for a 16 edge polygon

Cylinders aren't well supported in ODE.

Shifty is quite right, the capped cylinder isn't really suitable for coins due to the semi-sphere caps.

Another solution is to add a box geom transform to the cylinder geom. You need to make the box slightly larger in height so that the cylinder 'ends' are covered by the box geom and thus won't generate any faulty contacts. The rim of the cylinder will still generate normal contacts. The box corners can remain within the cylinder rim, there's no need to make it cover the entire cylinder end.

Let me know if you need any more help trying the above solution, I can knock you up a simple demo to show this in no time ;)

JV-ODE V1.12 Update Released

Please check your inbox :)

The new update fixes the dSpaceDestroy() MAV issue reported here

Please let me know if you experience any problems with the new update.

Thanks VIP3R,

Appreciate your efforts once more.
Keep up the good work!

cheers,

Mark

cool.
cool.
cool.

D

Hi,

Received. Good job.

Thanks

JP

Thanks all, you're welcome :)

VIP3R,

JV/ODE can load tri-meshes with a mesh, but I'd like to see example of it loading specified layer of and AnimMesh.

Be nice to see this included with JV/ODE to give users little more flexibility in dealing with meshes and terrains.

I do have some code laying around to do this so it's not too difficult, just a piece I'd like to see added.

Please consider adding this feature.

Thanks.

Hi Wayne,

I'll certainly take a look at it :)

Can you send me the code you mention and the necessary media for testing?

Will get it together and send it.

Here it is my code to create full trimesh from animmesh. It should be easy to choose what meshes to export and what not:

;-------------------------------------------------;
Function KODE_dTriMeshCreateRecursive%(space,mesh%)
; USE THIS IF USING LOADANIMMESH
;-------------------------------------------------;
	tris_count% = 0
	vert_count% = 0

	RecursiveCount(mesh)

	vertices_bank% = CreateBank(vert_count * 4 * 4)
	indices_bank% = CreateBank(tris_count * 3 * 4)

	offset% = 0
	offset_tris% = 0
	baseverts=0
	
	RecursiveAdd(mesh)
	
	t_data = KODE_dGeomTriMeshDataCreate()
	KODE_dGeomTriMeshDataBuildSimple(t_data, vertices_bank, vert_count, indices_bank, tris_count * 3)

	Return KODE_dCreateTriMesh(space, t_data)
End Function

;-----------------------------;
Function RecursiveCount(mesh%)
; Add to the Global Values the Vertex and Tris Count
;-----------------------------;
children = CountChildren(mesh)

If (children = 0)
	For k = 1 To CountSurfaces(mesh)
		tris_count = tris_count + CountTriangles(GetSurface(mesh, k))
		vert_count = vert_count + CountVertices(GetSurface(mesh, k))
	Next
Else
	For k = 1 To Children
		RecursiveCount(GetChild(mesh,k))
	Next
EndIf

End Function

Function RecursiveAdd(mesh%)

children = CountChildren(mesh)

If (children = 0)	
	For i = 1 To CountSurfaces(mesh)
		sf = GetSurface(mesh, i)
		For v = 0 To CountVertices(sf) - 1	
			v1x# = VertexX(sf,v)
			v1y# = VertexY(sf,v)
			v1z# = VertexZ(sf,v)			
			TFormPoint v1x,v1y,v1z,mesh,0
			
			PokeFloat vertices_bank, offset, TFormedX()
			offset = offset + 4
			PokeFloat vertices_bank, offset, TFormedY()
			offset = offset + 4
			PokeFloat vertices_bank, offset, TFormedZ()
			offset = offset + 8
		Next
		For t = 0 To CountTriangles(sf) - 1
			For j = 0 To 2
				v = TriangleVertex(sf, t, j)+baseverts
				PokeInt indices_bank, offset_tris, v
				offset_tris = offset_tris + 4
			Next
		Next
		baseverts=baseverts+CountVertices(sf)
	Next
Else
	For k = 1 To Children
		RecursiveAdd(GetChild(mesh,k))
	Next
EndIf

End Function

Cheers, KuRiX

Thanks for the code Kuri, it MAVs for me though on the following line...

For k = 1 To CountSurfaces(mesh)

...any idea why?


Here's a See-Saw Ramp demo requested by {Devious}...

; ###################################################################################################
; #										  JV-ODE Car Demo											#
; #									Code by Jim Williams (VIP3R)									#		#
; #						Feel free to use this code, any credit appreciated							#
; ###################################################################################################

AppTitle "JV-ODE Car Demo - See-Saw"

Include "JV-ODE.bb"

Graphics3D 800,600,0,2

Global CMass#=200			; ### Car Mass
Global WMass#=14			; ### Wheel Mass
Global RampMass#=100		; ### Ramp Mass

Global WorldERP#=1			; ### World Error Correction
Global WorldFriction#=70	; ### World Friction

Global Torque#=24			; ### Joint Torque
Global SuspensionHS#=0.01	; ### Suspension Hardness/Softness (Higher=Softer - Lower=Harder)

Global Force#=0
Global Steer#=0

Global Car
Global CGeom
Global CMesh

Global CarStartY=20

Dim Wheel(4)
Dim WGeom(4)
Dim Joint(4)

Type ODEGeom
	Field body
	Field geom
	Field mesh
End Type

; ###################################################################################################

; ### Setup ODE

Global World=dWorldCreate()
Global Space=dHashSpaceCreate(0)
Global ContactGroup=dJointGroupCreate(0)

dWorldSetAutoDisableFlag(World,1)
dWorldSetGravity(World,0,-0.98,0)
dWorldSetERP(World,WorldERP)

dContactSetMode(dContactSlip1)
dContactSetMu(WorldFriction)

; ### Create car body

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
Car=ode\body
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,0,CarStartY,0)
mass=dMassCreate()
dMassSetBoxTotal(mass,CMass,3,1,4)
dMassTranslate(mass,0,-1,0)
dBodySetMass(ode\body,mass)
dMassDestroy(mass)
ode\geom=dCreateBox(Space,3,1,4)
CGeom=ode\geom
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateCube()
CMesh=ode\mesh
ScaleMesh ode\mesh,1.5,0.5,2
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0
EntityColor ode\mesh,40,80,255
EntityAlpha ode\mesh,1

; ### Create wheels

For count=1 To 4
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	Wheel(count)=ode\body
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,0,0,0)
	mass=dMassCreate()
	dMassSetSphereTotal(mass,WMass,0.7)
	dBodySetMass(ode\body,mass)
	dMassDestroy(mass)
	ode\geom=dCreateSphere(Space,0.7)
	WGeom(count)=ode\geom
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateCylinder(8)
	ScaleMesh ode\mesh,0.7,0.25,0.7
	RotateMesh ode\mesh,0,0,90
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,255,255,255
Next

dBodySetPosition(Wheel(1),-2,CarStartY-0.5,+2)
dBodySetPosition(Wheel(2),+2,CarStartY-0.5,+2)
dBodySetPosition(Wheel(3),-2,CarStartY-0.5,-2)
dBodySetPosition(Wheel(4),+2,CarStartY-0.5,-2)

; ### Create some objects

SeedRnd MilliSecs()

For spheres=1 To 20
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,Rnd(-100,100),30,Rnd(-100,100))
	ode\geom=dCreateSphere(Space,4)
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateSphere()
	ScaleMesh ode\mesh,4,4,4
	RotateMesh ode\mesh,0,0,0
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
Next

For cylinders=1 To 20
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	dBodySetRotation(ode\body,90,0,0)
	dBodySetPosition(ode\body,Rnd(-100,100),30,Rnd(-100,100))
	ode\geom=dCreateCCylinder(Space,1,8)
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateCylinder(8)
	ScaleMesh ode\mesh,1,5,1
	RotateMesh ode\mesh,90,0,0	; <<< Mesh X-Axis must be rotated 90 degrees to fix cylinder alignment
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
Next

; ### Create light

Global Light=CreateLight()

RotateEntity Light,45,-90,0
LightColor Light,255,255,255
AmbientLight 130,130,130

; ### Create camera

Global CameraPivot=CreatePivot(CMesh)
PositionEntity CameraPivot,0,2,-7

Global Camera=CreateCamera()
CameraClsColor Camera,0,0,0
CameraRange Camera,1,1000

; ### Create plane

dCreatePlane(Space,0,1,0,0)

Plane=CreatePlane()

EntityAlpha Plane,0.8

PlaneTexture=CreateTexture(128,128,9)

ClsColor 0,200,80
Cls

Color 255,255,255

Rect 0,0,64,64,1
Rect 64,64,64,64,1

CopyRect 0,0,128,128,0,0,BackBuffer(),TextureBuffer(PlaneTexture)
ScaleTexture PlaneTexture,20,20
EntityTexture Plane,PlaneTexture,0,0

Mirror=CreateMirror()

; ###################################################################################################

; ### BLITZ STATIC OBJECT (White)

blitzobject=CreateCube()
ScaleMesh blitzobject,1,4,20
RotateMesh blitzobject,-10,8,4
PositionMesh blitzobject,10,5,40

EntityColor blitzobject,255,255,255
EntityAlpha blitzobject,1

; ### ODE STATIC OBJECT (Blue)

ode.ODEGeom=New ODEGeom
ode\geom=dCreateBox(Space,2,8,40)
dGeomSetRotation(ode\geom,-10,8,4)
dGeomSetPosition(ode\geom,20,5,40)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,1,4,20
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0

EntityColor ode\mesh,0,100,200
EntityAlpha ode\mesh,1

; ###################################################################################################

; ### Ramp (Red)

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
RampBody=ode\body
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,-20,5,40)
mass=dMassCreate()
dMassSetBoxTotal(mass,RampMass,18,0.2,40)
dBodySetMass(ode\body,mass)
dMassDestroy(mass)
ode\geom=dCreateBox(Space,18,0.2,40)
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,9,0.1,20
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0

EntityColor ode\mesh,200,0,100
EntityAlpha ode\mesh,1

; ### Ramp Base (Purple)

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
BaseBody=ode\body
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,-20,2.5,40)
mass=dMassCreate()
dMassSetBoxTotal(mass,RampMass,18,5,0.5)
dBodySetMass(ode\body,mass)
dMassDestroy(mass)
ode\geom=dCreateBox(Space,18,5,0.5)
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,9,2.5,0.25
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0

EntityColor ode\mesh,200,0,200
EntityAlpha ode\mesh,1

; ### Ramp Joints

StaticJoint=dJointCreateFixed(World,0)	; ### Fix base to ODE world
dJointAttach(StaticJoint,0,BaseBody)
dJointSetFixed(StaticJoint)

HJoint=dJointCreateHinge(World,0)
dJointAttach(HJoint,RampBody,BaseBody)
dJointSetHingeAxis(HJoint,1,0,0)
dJointSetHingeAnchor(HJoint,-20,5,40)
dJointSetHingeParam(HJoint,dParamLoStop,-0.4)
dJointSetHingeParam(HJoint,dParamHiStop,0.4)

; ### Roll ramp

dJointSetHingeParam(HJoint,dParamVel,-1)
dJointSetHingeParam(HJoint,dParamFMax,10)

; ###################################################################################################

SetupCar()

While Not KeyHit(1)

	UpdateKeys()

	PTime=MilliSecs()

	UpdateCar()

	UpdateGeoms()

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.1)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime

	UpdateCam()

	UpdateWorld

	RenderWorld

	Text 0,0,"JV-ODE Version "+dGetVersion()
	Text 0,15,"Physics Time:"+PhysicsTime
	Text 0,50,"Force:"+Force
	Text 0,65,"Torque:"+Torque
	Text 640,0,"A - Accelerate"
	Text 640,15,"Z - Brake/Reverse"
	Text 640,30,"Arrows - Steering"
	Text 640,45,"Space - Reset Car"

	Flip

Wend

dJointGroupDestroy(ContactGroup)
dSpaceDestroy(Space)
dWorldDestroy(World)
dCloseODE()

End

; ###################################################################################################

Function SetupCar()

For count=1 To 4
	Joint(count)=dJointCreateHinge2(World,0)
	dJointAttach(Joint(count),Car,Wheel(count))
	dJointSetHinge2Anchor(Joint(count),dBodyGetPositionX(Wheel(count)),dBodyGetPositionY(Wheel(count)),dBodyGetPositionZ(Wheel(count)))
	dJointSetHinge2Axis1(Joint(count),0,1,0)
	dJointSetHinge2Axis2(Joint(count),-1,0,0)
	dJointSetHinge2Param(Joint(count),dParamSuspensionERP,0.8)
	dJointSetHinge2Param(Joint(count),dParamSuspensionCFM,SuspensionHS)
	If count>2
		dJointSetHinge2Param(Joint(count),dParamLoStop,0)
		dJointSetHinge2Param(Joint(count),dParamHiStop,0)
		End If
Next

Force=0

End Function

; ###################################################################################################

Function UpdateKeys()

If KeyDown(30)=1
	Force=Force+0.08
	If Force>30 Then Force=30
	End If

If KeyDown(44)=1
	Force=Force-0.1
	If Force<-10 Then Force=-10
	If Force>0 Then Force=Force*0.97
	End If

If KeyDown(30)=0 And KeyDown(44)=0 Then Force=Force*0.99

If KeyDown(203)=1 Or KeyDown(205)=1
	If KeyDown(203)=1
		Steer=0.5
		Else
		Steer=-0.5
		End If
	Else
	Steer=0
	End If

If KeyHit(57)=1
	Force=0
	dBodySetRotation(Car,dGeomGetPitch#(CGeom),dGeomGetYaw#(CGeom),0)
	End If

End Function

; ###################################################################################################

Function UpdateCar()

For count=1 To 4
	dBodyEnable(Wheel(count))
Next

dBodyEnable(Car)

For count=1 To 4
	dJointSetHinge2Param(Joint(count),dParamVel2,Force)
	dJointSetHinge2Param(Joint(count),dParamFMax2,Torque)
Next

For count=1 To 2
	angle#=Steer-dJointGetHinge2Angle1(Joint(count))
	dJointSetHinge2Param(Joint(count),dParamVel,angle)
	dJointSetHinge2Param(Joint(count),dParamFMax,400)
Next

End Function

; ###################################################################################################

Function UpdateCam()

PositionEntity CameraPivot,0,3,-12

camx#=EntityX(CameraPivot,1)-EntityX(Camera)
camy#=EntityY(CameraPivot,1)-EntityY(Camera)
camz#=EntityZ(CameraPivot,1)-EntityZ(Camera)

TranslateEntity Camera,camx*0.5,camy*0.5,camz*0.5

PointEntity Camera,CMesh

End Function

; ###################################################################################################

Function UpdateGeoms()

For ode.ODEGeom=Each ODEGeom
	RotateEntity ode\mesh,dGeomGetPitch#(ode\geom),dGeomGetYaw#(ode\geom),dGeomGetRoll#(ode\geom)
	PositionEntity ode\mesh,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)
Next

End Function

; ###################################################################################################

Testing some slightly modified VIP3R code to load the full animesh, and will send ASAP, things just taking longer today.

No problem Wayne ;)

I've not had much experience with animated meshes tbh, how is each frame stored? Is each frame a set of children meshes to the parent mesh?

That's what Kuri seems to be doing above, cycling to the last child mesh and creating the TriMesh from that, is this right?

This is untested:

; ###################################################################################################

Function CreateAnimTriMesh(trispace,mesh)

tricount=0
vertcount=0
For child=1 To CountChildren(mesh)
	For count=1 To CountSurfaces(GetChild(mesh,child))
		tricount=tricount+CountTriangles(GetSurface(GetChild(mesh,child),count))
		vertcount=vertcount+CountVertices(GetSurface(GetChild(mesh,child),count))
	Next
Next

tribank=CreateBank(tricount*3*4)
vertbank=CreateBank(vertcount*4*4)

offset=0
trioffset=0
vertoffset=0

For child=1 To CountChildren(mesh)
	For count=1 To CountSurfaces(GetChild(mesh,child))
		surface=GetSurface(GetChild(mesh,child),count)
		For vert=0 To CountVertices(surface)-1
			PokeFloat(vertbank,offset,VertexX(surface,vert)+EntityX(GetChild(mesh,child),1))
			offset=offset+4
			PokeFloat(vertbank,offset,VertexY(surface,vert)+EntityY(GetChild(mesh,child),1)))
			offset=offset+4
			PokeFloat(vertbank,offset,VertexZ(surface,vert)+EntityZ(GetChild(mesh,child),1)))
			offset=offset+8
		Next
		For tri=0 To CountTriangles(surface)-1
			For corner=0 To 2
				PokeInt(tribank,trioffset,TriangleVertex(surface,tri,corner)+vertoffset)
				trioffset=trioffset+4
			Next
		Next
		vertoffset=vertoffset+CountVertices(surface)
	Next

trimeshdata=dGeomTriMeshDataCreate()

dGeomTriMeshDataBuildSimple(trimeshdata,vertbank,vertcount,tribank,tricount*3)

Return dCreateTriMesh(trispace,trimeshdata)

End Function

Viper, be sure to load the mesh with loadanimmesh before calling the function

dtrimeshcreaterecursive()

That is the only function you should call, the others are helpers to that one.

Tell me if it works for you!

Yep, it's loaded with loadanimmesh ;)

The function Wayne posted MAVs for me too, it's the Zombie mesh I'm testing it with that's the cause of the MAV by the looks of it. I'm sure I had problems finding children in that mesh before.

Have you got any animated meshes I could try Wayne? I don't have any meshes here that would be suitable.

Yes I do, T.ED the terrain editor can create animeshes, I'll whipe up a small one right now.

This code appeared to work prefect for me.
All that was required was a few small additions to Vip3r code.

I'll post a link to the animmesh right after I try loading just one layer.

Function CreateAnimTriMesh(trispace,mesh)

tricount=0
vertcount=0
For child=1 To CountChildren(mesh)
	For count=1 To CountSurfaces(GetChild(mesh,child))
		tricount=tricount+CountTriangles(GetSurface(GetChild(mesh,child),count))
		vertcount=vertcount+CountVertices(GetSurface(GetChild(mesh,child),count))
	Next
Next

tribank=CreateBank(tricount*3*4)
vertbank=CreateBank(vertcount*4*4)

offset=0
trioffset=0
vertoffset=0

For child=1 To CountChildren(mesh)
	For count=1 To CountSurfaces(GetChild(mesh,child))
		surface=GetSurface(GetChild(mesh,child),count)
		For vert=0 To CountVertices(surface)-1
			PokeFloat(vertbank,offset,VertexX(surface,vert))
			offset=offset+4
			PokeFloat(vertbank,offset,VertexY(surface,vert))
			offset=offset+4
			PokeFloat(vertbank,offset,VertexZ(surface,vert))
			offset=offset+8
		Next
		For tri=0 To CountTriangles(surface)-1
			For corner=0 To 2
				PokeInt(tribank,trioffset,TriangleVertex(surface,tri,corner)+vertoffset)
				trioffset=trioffset+4
			Next
		Next
		vertoffset=vertoffset+CountVertices(surface)
	Next
Next

trimeshdata=dGeomTriMeshDataCreate()

dGeomTriMeshDataBuildSimple(trimeshdata,vertbank,vertcount,tribank,tricount*3)

Return dCreateTriMesh(trispace,trimeshdata)

End Function

This function will load single layer (child)

Function CreateAnimLayerTriMesh(trispace,mesh,child)

tricount=0
vertcount=0

For count=1 To CountSurfaces(GetChild(mesh,child))
	tricount=tricount+CountTriangles(GetSurface(GetChild(mesh,child),count))
	vertcount=vertcount+CountVertices(GetSurface(GetChild(mesh,child),count))
Next


tribank=CreateBank(tricount*3*4)
vertbank=CreateBank(vertcount*4*4)

offset=0
trioffset=0
vertoffset=0


For count=1 To CountSurfaces(GetChild(mesh,child))
	surface=GetSurface(GetChild(mesh,child),count)
	For vert=0 To CountVertices(surface)-1
		PokeFloat(vertbank,offset,VertexX(surface,vert))
		offset=offset+4
		PokeFloat(vertbank,offset,VertexY(surface,vert))
		offset=offset+4
		PokeFloat(vertbank,offset,VertexZ(surface,vert))
		offset=offset+8
	Next
	For tri=0 To CountTriangles(surface)-1
		For corner=0 To 2
			PokeInt(tribank,trioffset,TriangleVertex(surface,tri,corner)+vertoffset)
			trioffset=trioffset+4
		Next
	Next
	vertoffset=vertoffset+CountVertices(surface)
Next


trimeshdata=dGeomTriMeshDataCreate()

dGeomTriMeshDataBuildSimple(trimeshdata,vertbank,vertcount,tribank,tricount*3)

Return dCreateTriMesh(trispace,trimeshdata)

End Function

Terrain Editor (T.ED) created the B3d AnimMesh with each layer being a surface. Example: Dirt, grass, rock.. and the last layer representing the entire terrain. By using the animmesh world builders can process the layers separately and add trees, rocks.. sample code fragment:

; Load animMesh
mesh=LoadAnimMesh("AnimTer.b3d")
; Load Last child layer (full terrain) into ODE Trimesh trispace
tmesh=CreateAnimLayerTriMesh(trispace,mesh,CountChildren(mesh))

Excellent work Wayne! :)

I'll take a good look at it later, are you happy for me to add your new function to the JV-ODE Wrapper?

There are two functions to use and distribute as you wish.

I do have application that tests the two functions, it's a little large but I'd like to send it to you.

Be my guest to make any changes and apply the Vip3r touch.
If you'd like to see the app let me know what email you'd like it sent to.

8)

Thanks Wayne, I really appreciate your efforts :)

I've had a good few hours experimenting with the animated mesh terrain, I think we could get away with the second function alone as it can be made recursive to create a TriMesh for each layer if need be. Also, I've noticed part of the code doesn't appear to do anything on your terrain mesh...

+EntityX/Y/Z(GetChild(mesh,child),1)?

The child positions are the same as the parent in the terrain mesh, so these functions always return a zero. Are they needed?

Can the terrain and texture media you've posted above be used in a JV-ODE demo and included with the wrapper?

Remove the stuff that always returns zero.

I replaced the texture set with free ones.
I reapplied the textures to the original anim.

Here is media and b3d for inclusion into JV/ODE:
http://www.bz911.com/postnuke/index.php?name=PNphpBB2&file=download&id=67

Screen shot showing animmesh terrain with new textures.
(trees, grass not in this demo, next one)

8)

Looks great Wayne :)

Yikes! how big are those textures :O

I need to keep the download size as low as possible, can you trim a few KBs off and re-size them to 512x512 or 256x256?

The new CreateAnimTriMesh(trispace,mesh,layer) function will be added to the next JV-ODE update, thanks again for your help Kuri/Wayne ;)

Here's the low fat version:
http://www.bz911.com/postnuke/index.php?name=PNphpBB2&file=download&id=69

Manipulating and positioning ODE bodies

I believe it would be most helpfull to have the following B3D functions to manipulate ODE bodies. The functions would operate on the specified ODE body as if it were a pivot. The functions would also act on the attached joints and attached bodies to perform the operation. Inaddition the linear and anglular velocities would be set to zero by default.

Summary allow simple non physics like functions to quickly setup and position simple and complex ode objects.

MoveBody
PositionBody
RotateBody
ScaleBody
TranslateBody
TurnBody

Does this seem usefull to you guys?

Thanks for the updated 'low fat' terrain files Wayne, I'll add them to the new AnimTriMesh demo for the next JV-ODE update ;)

Yep, it's official...

JV-ODE is now working in BlitzMax (Win32)

TriMeshes are supported but not yet implemented in demo form, the demos will use bare-bones OpenGL routines for the 3D graphics. As there are many options for 3D graphics engines in BlitzMax, it might be best to build-in the basic graphics for demo purposes for the time being. Once some of the engines have matured, dedicated demos for each engine will be looked at.

Coming soon...

:)

Outstanding VIP3R

I'll buy BlitzMax if you're going to get JV/ODE working and some barebones OpenGL for the demos.

Will this be a new product ?
What is the expected MSRP ?

Nope, the new BlitzMax functionality and demos will be included in the Blitz3D version of JV-ODE.

I'm not planning to make additional charges for it at the moment.

Any donations would be most welcome and extremely helpful though ;)

I'd certainly consider paying again for MAX support, though the chances of me using MAX are none until it gets aproper, simple 3D method like BlitzBasic. That's what made Blitz so good and without that, MAX sounds like just another language (unless you're doing 2D).

It would be worth paying for again!

If you've got it working in Max, this is pretty much perfect timing for me, well done man!

BlitzMax JV-ODE Preview Now Available

Please visit the following blitzmax.com showcase link for more information, to download the demos or post any feedback or questions...

http://www.blitzmax.com/Community/posts.php?topic=57233

Thanks :)

Update:

The BlitzMax version is almost ready for release. All of the Blitz3D demos are now in and working, including fully working TriMesh demos! The only exception is the Zombie demo, the built-in 3D engine can't do animated meshes at the moment.

The BlitzMax version will include:

All Blitz3D demos converted to run in BlitzMax (except Zombie demo)
Built-in bare-bones 3D OpenGL engine (for demo purposes only)
Built-in B3D Mesh Loader

More soon...

:)

VIP3R,

I am interested in purchasing this. I have some questions...

1. Is there a manual I could download prior to purchase?

2. Can I use the examples as basis for my application?

3. Are updates free?

4. Also in the sphere demo the balls keep on moving. Is there a way to get them to act under friction, i.e. slow down and stop?

1. There's an online user manual for ODE here. The full version of JV-ODE comes with a Function Reference which covers every JV-ODE/ODE function, it's not a user manual though.

2. Yes, provided you don't break any of the license conditions.

3. Yes

4. Yes, Shifty Geezer did some nice work in this field. Check the previous JV-ODE threads for more info and code.

:)

4. Could you be a bit more specific there is a lot of posts here :-(

Yes there is indeed a lot of posts, which is why I wasn't more specific.

Check Thread 4 about 1/2 way down.

Thank the lord for Google.

Whats next.. JV/3D ?

8)

JV-ODE V1.14 Update Released

Please check your inbox :)

Added new rotation functions:

dBodySetAxisAngle(body,angle#,rx#,ry#,rz#)
dBodyGetAxisAngle(body)
dGeomSetAxisAngle(geom,angle#,rx#,ry#,rz#)
dGeomGetAxisAngle(geom)

Added CreateAnimTriMesh(trispace,mesh,layer) function

Added CarDemo-AnimTriMesh demo

Please let me know if you experience any problems with the new update.

:)

Nice one Vip3r!

Either you are a tiny bit supersticious or you forgot to send me version 1.13 :))))))

Excellent work!

Danny

Thanks Danny, much appreciated :)

Don't worry there wasn't a V1.13, it's gone up by two version numbers because it's a Blitz3D update and also a new release for BlitzMax.

;)

Many thanks again, new demo works really well.
Might have to get into MAX now so i can try the other flavour of JV-ODE.....

cheers,

Mark

Thanks Mark, you're welcome :)

Can't wait for the launch of Tricky Tracks!

Maybe we'll see a BlitzMax version of it some day ;)

Hi Vip3r,

I understand there are some historical issues with 'cylinders', but what is this exactly about?!
I just wanted to make something and found out that a normal cylinder WILL NOT collide with a trimesh terrain! :( and just sink through. I don't think this is a matter of tweaking other values since any other geometry will act normally...

When checking your demo's for some inspiration I noticed that you have everything 'except' a trimesh-cylinder demo :)

Cheers,
Danny

The cylinder geom isn't part of the original ODE package, but an external contribution to ODE. That's why the cylinder functions are listed separately under 'External ODE User Library Functions' in the JV-ODE Function Reference. At the moment cylinder to TriMesh collision isn't supported by the core of the library.

The workaround for achieving cylinder to TriMesh collision is to 'sphere-wrap' the cylinders, have a look at the SphereWrapCylinder car demo. The only drawback is that it will only work with cylinders which are at least 2x the radius in length. The demo uses fixed joints to attach the spheres, but geom transforms would probably work better. I need to look at that :)

aha. ok. that does explain a lot yes...

funny... I'm no math crack, but you'd think that simple cylinders would be easier to do than capped cylinders..

ok thanks!

d.

You want JV-ODE to work with 2D projects eh?

No problem :)

Here's a 2D JV-ODE Spheres demo...

; ###################################################################################################
; #									  JV-ODE - 2D Spheres Demo										#
; #									Code by Jim Williams (VIP3R)									#
; ###################################################################################################

AppTitle "JV-ODE - 2D Spheres Demo"

Include "JV-ODE.bb"

Graphics 800,600,0,2

Type ODEGeom
	Field body
	Field geom
	Field r
	Field g
	Field b
End Type

; ###################################################################################################

; ### Setup ODE

Global World=dWorldCreate()
Global Space=dHashSpaceCreate(0)
Global ContactGroup=dJointGroupCreate(0)

dWorldSetAutoDisableFlag(World,1)
dWorldSetGravity(World,0,-9.8,0)
dContactSetMode(dContactBounce)
dContactSetBounce(0.8)
dContactSetMu(48)

; ### Create plane

dCreatePlane(Space,0,1,0,0)

; ### ODE STATIC BARRIER (Near)

ode.ODEGeom=New ODEGeom
ode\geom=dCreateBox(Space,1000,1000,1)
dGeomSetRotation(ode\geom,0,0,0)
dGeomSetPosition(ode\geom,0,500,-15)
dGeomContactSetMu(ode\geom,0.0)

; ### ODE STATIC BARRIER (Far)

ode.ODEGeom=New ODEGeom
ode\geom=dCreateBox(Space,1000,1000,1)
dGeomSetRotation(ode\geom,0,0,0)
dGeomSetPosition(ode\geom,0,500,15)
dGeomContactSetMu(ode\geom,0.0)

; ###################################################################################################

SetBuffer BackBuffer()

While Not KeyHit(1)

	Cls

	PTime=MilliSecs()

	If MilliSecs()-Timer>800
		AddObject()
		Timer=MilliSecs()
		End If

	UpdateGeoms()

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.05)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime

	Text 0,0,"JV-ODE Version "+dGetVersion()
	Text 0,15,"Physics Time:"+PhysicsTime

	Flip

Wend

dJointGroupDestroy(ContactGroup)
dSpaceDestroy(Space)
dWorldDestroy(World)
dCloseODE()

End

; ###################################################################################################

Function AddObject()

xp=Rand(-80,80)

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,xp,500,0)
dBodySetAutoDisableFlag(ode\body,1)
ode\geom=dCreateSphere(Space,14)
dGeomSetBody(ode\geom,ode\body)
ode\r=Rand(255)
ode\g=Rand(255)
ode\b=Rand(255)

End Function

; ###################################################################################################

Function UpdateGeoms()

For ode.ODEGeom=Each ODEGeom
	If ode\body
		Color ode\r,ode\g,ode\b
		xpos#=400+dGeomGetPositionX#(ode\geom)
		ypos#=580-dGeomGetPositionY#(ode\geom)
		Oval xpos,ypos,28,28,1

		Color 255,255,255
		angle#=-dGeomGetRoll#(ode\geom)
		px#=Cos(angle)*10+xpos
		py#=Sin(angle)*10+ypos
		Oval 10+px,10+py,8,8,1
		End If
Next

End Function

; ###################################################################################################

All I've done is restrict motion on the z-axis using two very large slim boxes (barriers). You can think of these two boxes as two sheets of glass in a double glazed window, then the spheres are dropped between them. To make sure the spheres don't snag on the insides of the two barriers, their friction has been set to zero. There is also a plane at the base to stop them falling below ground level.

Hopefully this will help anyone trying to work out how to use JV-ODE in 2D, let me know if you have any questions.

:)

I rigged a quick 2D ODE engine by just setting Z speed to 0 every frame and Z postion to 0 for each object. That allowed collisions as normal with arbitary shapes and no 'container' overhead.

Are you sure that isn't abusing the simulation Shifty? How well did it work?

If you run the 2D Spheres demo without the barriers present, it would still work ok because the spheres never stray off course on the z axis anyway. The barriers are there to prevent the odd chance that a sphere might go off course, only then will a sphere make contact with the barriers. Whether the barriers are used or not, the physics processing time remains the same, so there is in fact no overhead in this particular example.

How you approach the problem depends on what you're trying to simulate in 2D.

It worked fine for me. I had a static mesh hitting spheres. Well, i also had static mesh hitting static mesh but we know that's crazy ;). I actually though to implement '2D' meshes, an outline of the 3D object viewed from above turned into a polyhedron, so collisions would always been along the plane with no z component. In theory that alone with zero gravity should be another. But certainly my results were very good. Didn't have any wierdness issues. I may have set rotation in the z axis (or whichever one) to zero each frame too.

Hi, need some help!

I am having problems with speed. My game has 64 terrain tiles each 32X32 totalling 256X256 ie 131072 triangles in total. I tried adding all of them but things just freeze up. it dus work when I just add 4 tiles. I still need to add lots of trees a rocks. Here is the problem code.



If s=0 Then

trimesh(xx,yy)=CreateTriMesh(Space,Land_mesh(xx,yy))
trimesh(xx+4,yy)=CreateTriMesh(Space,Land_mesh(xx,yy))
trimesh(xx,yy+4)=CreateTriMesh(Space,Land_mesh(xx,yy))
trimesh(xx+4,yy+4)=CreateTriMesh(Space,Land_mesh(xx,yy))

dGeomSetPosition(trimesh(xx,yy),1024+(xx*2048),0,1024+(yy*2048))
dGeomSetPosition(trimesh(xx+4,yy),1024+(xx*2048)+8192,0,1024+(yy*2048))
dGeomSetPosition(trimesh(xx,yy+4),1024+(xx*2048),0,1024+(yy*2048)+8192)
dGeomSetPosition(trimesh(xx+4,yy+4),1024+(xx*2048)+8192,0,1024+(yy*2048)+8192)
EndIf

Any ideas to speed things up?

It sounds like your TriMesh tiles are colliding with each other.

You need to create a sub-space containing all of the TriMesh tiles...

Global Space=dHashSpaceCreate(0)
Global SceneSpace=dHashSpaceCreate(Space) ; <<< Sub-Space for TriMesh tiles

Then disable internal space collisions to prevent them colliding with each other...

dSetInternalSpaceCollideMode(0)

Make sure you specify 'SceneSpace' instead of 'Space' in the CreateTriMesh function calls...

trimesh(xx,yy)=CreateTriMesh(SceneSpace,Land_mesh(xx,yy))

The 'CarDemo-TriMesh-X4' demo shows the above method in action.

Thanks it's working nicely now.

I have been trying to fix this code but with out much susses. The problem is that the objects vanish and then come back every frame or so. I want the to move to a new location and stay there. he is the code. any help would be gratefully received.

For ode.ODEGeom=Each ODEGeom

RotateEntity ode\mesh,dBodyGetPitch#(ode\geom),dBodyGetYaw#(ode\geom),dBodyGetRoll#(ode\geom)
obx#=dBodyGetPositionX#(ode\body)
oby#=dBodyGetPositionY#(ode\body)
obz#=dBodyGetPositionZ#(ode\body)
ch=0
If obx#>(Local_Player_x#+HalfmapSizeX) Then
obx#=obx# - FullmapSizeX
ch=1
Else If Rx<(Local_Player_x#-HalfmapSizeX) Then
obx#=obx# + FullmapSizeX
ch=1
EndIf

If obz#>(Local_Player_z#+HalfmapSizeY) Then
obz#=obz# - FullmapSizeY
ch=1
Else If obz#<(Local_Player_z#-HalfmapSizeY) Then
obz#=obz# + FullmapSizeY
ch=1
EndIf

dBodyDisable(ode\body)
If ch=1 Then dBodySetPosition(ode\body,obx,oby,obz)
PositionEntity ode\mesh,obx,oby,obz
dBodyEnable(ode\body)

Next

Try changing the last part to the following:

dBodyDisable(ode\body)

if ch=1 then
     dBodySetPosition(ode\body,obx,oby,obz)
     ; Set linear velocity and rotational velocity to zero
     dBodySetLinearVel  (ode\body, 0,0,0)
     dBodySetAngularVel (ode\body, 0,0,0)
end if

PositionEntity ode\mesh,obx,oby,obz
dBodyEnable(ode\body)

Next

Sorry did not work. I also need them to keep moving the same direction too. Any other Idears

JV-ODE Users:

The video card in my dev machine has just developed a serious fault, or in other words it's @#!*ed and won't display any hardware accelerated graphics :/

I've requested a service call but obviously it limits my ability to help folks until it's fixed, hopefully it won't take too long.

ViP3R, hang in there buddy.

Battle Tanks,
Need more information. What are you trying to do in general? More code would also be helpfull.

8)

@Battle Tanks: You're going to run into problems if you're manually repositioning objects in ODE. It isn't necessary to tile the ODE geometry, you can create the entire scene in ODE without affecting render speed, then apply your tile system to the visible geometry only. This will avoid the need to reposition the geoms. Btw, it's easier to read code when posted using the codebox tags... [ codebox ] Your Code Here [ / codebox ] - Without the spaces ;)

@Wayne: Will do :)

that's bad news...

I have a couple of cards (through my day job) which are 'spare' for indefinte loan - let me know if you want one posting today.

cheers,

Mark

Wow Mark thanks, that's extremely generous of you :)

It would be very helpful to borrow one until this one gets replaced, I'll send you an email ;)

This is what I am up to

I have created 4 identical worlds, when the player can see the edge of one of the worlds he is transported to an Identical location in the world behind him with out the player noticing what has happed. Using this method the player can keep going in one direction with out running out of land.

To get object to work in this system I use the following system.

If the object is beyond a 4096 units in x or z from the player the object is then transported to an Identical location on one of the other three Identical worlds.

Info:
Worlds: 4 Identical worlds in total
A world contains 4x4 Land Tiles each with it own Hash Space. All the trees and rocks on a tile have their own Hash Space linked to the Tiles Hash Space. Non of these are ever moved. (Note that no all the surfaces are added to the Physic system as leaves should to be able to stop a Oil barrels)

Physic Objects:
Are anything that moves except internet controlled objects (local objects can collide with Internet/Lan controlled objects ), Physic Objects are Ai players, Projectiles. Oil barrels, bricks, rocks ect

Problems I am encountering are;


1) The more objects I add the more likely the game will crash. The error give is memory violation on this line dSpaceCollide(Space,World,ContactGroup)

I have managed to fix the other problem somehow

What would be the best way to make a shock wave that knocked other object out the way with out being move its self, just growing is size.

Thanks for your help VIP3R.

here's a dum question for you, how do you post a picture.

Here is some of the code

	
	Global WorldERP#=2			; ### World Error Correction
	Global WorldFriction#=200	; ### World Friction
	
	Global Force#=0
	Global Steer#=0
	
	Global Car
	Global CGeom
	Global CMesh
	Global SceneSpace
	Global HalfmapSizeX=4096,HalfmapSizeY=4096


	Global CarStartY=48
	Global ode.ODEGeom
	
	Global Local_Player_x#
	Global Local_Player_z#
	
	Dim Wheel(4)
	Dim WGeom(4)
	Dim Joint(4)
	Dim mesh(7,7)
	Dim Rock(4)
	

	
	Type ODEGeom
		Field body
		Field geom
		Field mesh
	End Type


	Global World,Space,ContactGroup,PhysicsTime#

Function Setup_Physics()


	
	
	; ###################################################################################################
	
	; ### Setup ODE
	
	World=dWorldCreate()
    Space=dHashSpaceCreate(0)
	SceneSpace=dHashSpaceCreate(Space) ; <<< Sub-Space for TriMesh tiles
	For x=0 To 7
		For y=0 To 7
			Space64(x,y)=dHashSpaceCreate(SceneSpace)
		Next
	Next

	ContactGroup=dJointGroupCreate(0)
	
	dSetInternalSpaceCollideMode(0)
	

	dWorldSetAutoDisableFlag(World,1)
	dWorldSetGravity(World,0,-2.5,0)
	dWorldSetERP(World,0.4)
	dContactSetMode(dContactBounce)
	dContactSetBounce(0.1)
	dContactSetMu(120)

	
	; ### Create some objects
	
	SeedRnd MilliSecs()
	For a=1 To 1
		Rock(a)= LoadMesh("Media\Trees\Rock\MoreRock"+a+".3ds")
	Next
	rock_texture=LoadTexture("Media\Land\rock2.jpg")
	For spheres=1 To 10
		ode.ODEGeom=New ODEGeom
		ode\body=dBodyCreate(World)
		dBodySetRotation(ode\body,0,0,0)
		tdx#=Rnd(1*2048,6*2048)
		tdz#=Rnd(1*2048,6*2048)
		dBodySetPosition(ode\body,tdx#,256,tdz#);Rnd(4094,12288),300,Rnd(4094,12288))
		mass=dMassCreate()
		dMassSetSphereTotal(mass,2500,40)
		dBodySetMass(ode\body,mass)
		dMassDestroy(mass)
		
		ode\geom=dCreateSphere(Space,40)
		dGeomSetBody(ode\geom,ode\body)
		dGeomContactSetMu(ode\geom,3600)
		dGeomContactSetBounce(ode\geom,-1)
		ode\mesh=CopyMesh(Rock(Rand(1,1)));CreateSphere()
		ScaleMesh ode\mesh,0.75,0.75,0.75
		RotateMesh ode\mesh,0,0,0
		PositionMesh ode\mesh,0,0,0
		EntityTexture ode\mesh,rock_texture
		;EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
		;EntityAlpha ode\mesh,1
		;EntityShininess ode\mesh,0.7
	Next
	For a=1 To 1
		FreeEntity Rock(a)
	Next
	FreeTexture rock_texture
	oildrum = LoadMesh("Media\msh\oildrum2.3ds")
	For cylinders=1 To 15
		ode.ODEGeom=New ODEGeom
		ode\body=dBodyCreate(World)
		tdx#=Rnd(1*2048,6*2048)
		tdz#=Rnd(1*2048,6*2048)
		dBodySetPosition(ode\body,tdx#,256,tdz#)
		mass=dMassCreate()
		dMassSetSphereTotal(mass,50,40)
		dBodySetMass(ode\body,mass)
		dMassDestroy(mass)
		ode\geom=dCreateCCylinder(Space,12,40)
		dGeomSetBody(ode\geom,ode\body)
		dGeomContactSetMu(ode\geom,3)
		dGeomContactSetBounce(ode\geom,0.02)
		ode\mesh=CopyMesh(oildrum);CreateCylinder(8)
		
		;ScaleMesh ode\mesh,10,10,10
		RotateMesh ode\mesh,270,0,0	; <<< Mesh X-Axis must be rotated 90 degrees to fix cylinder alignment
		PositionMesh ode\mesh,0,0,0
		;EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
		;EntityAlpha ode\mesh,1
		;EntityShininess ode\mesh,0.7
	Next
	FreeEntity oildrum
	
End Function


Function UpdateGeoms()

Local_Player_x# = EntityX(Ship,True)
Local_Player_z# = EntityZ(Ship,True)

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.1)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime
	


For ode.ODEGeom=Each ODEGeom


		If EntityX(ode\mesh,True)>(EntityX(ship,True)+HalfmapSizeX) Then
			dGeomDisable(ode\geom)
			dGeomSetPosition(ode\geom,dGeomGetPositionX#(ode\geom)-FullmapSizeX,dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom))	
			dGeomEnable(ode\geom)
		Else If EntityX(ode\mesh,True)<(EntityX(ship,True)-HalfmapSizeX) Then
			dGeomDisable(ode\geom)
			dGeomSetPosition(ode\geom,dGeomGetPositionX#(ode\geom)+FullmapSizeX,dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom))
			dGeomEnable(ode\geom)
		EndIf
	
		If EntityZ(ode\mesh,True)>(EntityZ(ship,True)+HalfmapSizeX) Then
			dGeomDisable(ode\geom)
			dGeomSetPosition(ode\geom,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)-FullmapSizeY)	
			dGeomEnable(ode\geom)
		Else If EntityZ(ode\mesh,True)<(EntityZ(ship,True)-HalfmapSizeX) Then
			dGeomDisable(ode\geom)
			dGeomSetPosition(ode\geom,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)+FullmapSizeY)
			dGeomEnable(ode\geom)
		EndIf


	If dBodyIsEnabled(ode\body)
		RotateEntity ode\mesh,dGeomGetPitch#(ode\geom),dGeomGetYaw#(ode\geom),dGeomGetRoll#(ode\geom)
		PositionEntity ode\mesh,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)
	End If
Next

End Function

;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;++++++++++++++++++  Make Terrian Mesh  +++++++++++++++++++
;++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Function Make_Terrian_Mesh()
	Make_Pick_Maps()
	;LandTexture=Colormap
	BlockSize=64
	ts%=32
	start=0-((BlockSize*ts%)/2)
	Adjust=75
	For xx=0 To 3 
       	For yy=0 To 3
			Land_mesh(xx,yy) = CreateMesh()
			
			;EntityFX Land_mesh(xx,yy),34;*****************
			For s=0 To Level\Land_Texture_Number%-1 ;
				
				First_Vertex%=0
				For lx# = 0 To ts%
					For ly# = 0 To ts%
						x=((xx*ts%)+lx)
						y=((yy*ts%)+ly)
						If Land_Texture_Mask(s,x,y)=1 Then
							If First_Vertex=0 Then 
								Land_surf(s,xx,yy) = CreateSurface(Land_mesh(xx,yy))
								First_Vertex=1
							EndIf
							tr(lx#,ly#) = AddVertex(Land_surf(s,xx,yy), start + (lx * BlockSize) , map(0,x*8,y*8) * Level\LandHi%, start + (ly * BlockSize), (Float(x)/128.0) , 1-(Float(y)/128.0))
							
							
							Red=Land_Red(x,y)-Best_Red(s):If Red>Adjust Then Red=Adjust ElseIf Red<(0-Adjust) Then Red=0-Adjust
							Green=Land_Green(x,y)-Best_Green(s):If Green>Adjust Then Green=Adjust ElseIf Green<(0-Adjust) Then Green=0-Adjust						
							Blue=Land_Blue(x,y)-Best_Blue(s)	:If Blue>Adjust Then Blue=Adjust ElseIf Blue<(0-Adjust) Then Blue=0-Adjust
							Red=Red+(255-Adjust)
							Green=Greed+(255-Adjust)
							Blue=Blue+(255-Adjust)
							VertexColor Land_surf(s,xx,yy),tr(lx#,ly#), Red, Green, Blue,Land_Texture_Picker#(s,x,y)
						EndIf
					Next
				Next	
				If First_Vertex=1 Then
					For lx = 0 To ts%-1
						For ly = 0 To ts%-1
							x=((xx*ts%)+lx)
							y=((yy*ts%)+ly)
							If Land_Texture_Mask(s,x,y)=1 And Land_Texture_Mask(s,x,y+1)=1 And Land_Texture_Mask(s,x+1,y)=1 Then
								AddTriangle Land_surf(s,xx,yy), tr(lx#,ly#), tr(lx#,ly#+1), tr(lx#+1,ly#)
							EndIf
						
							If Land_Texture_Mask(s,x,y+1)=1 And Land_Texture_Mask(s,x+1,y+1)=1 And Land_Texture_Mask(s,x+1,y)=1 Then
								AddTriangle Land_surf(s,xx,yy), tr(lx#,ly#+1), tr(lx#+1,ly#+1), tr(lx#+1,ly#)
							EndIf
						
						Next
					Next

					
				EndIf
				If s=0 Then
				
					trimesh(xx,yy)=CreateTriMesh(Space64(xx,yy),Land_mesh(xx,yy))
					trimesh(xx+4,yy)=CreateTriMesh(Space64(xx+4,yy),Land_mesh(xx,yy))
					trimesh(xx,yy+4)=CreateTriMesh(Space64(xx,yy+4),Land_mesh(xx,yy))
					trimesh(xx+4,yy+4)=CreateTriMesh(Space64(xx+4,yy+4),Land_mesh(xx,yy))

					dGeomSetPosition(trimesh(xx,yy),1024+(xx*2048),0,1024+(yy*2048))
					dGeomSetPosition(trimesh(xx+4,yy),1024+(xx*2048)+8192,0,1024+(yy*2048))
					dGeomSetPosition(trimesh(xx,yy+4),1024+(xx*2048),0,1024+(yy*2048)+8192)
					dGeomSetPosition(trimesh(xx+4,yy+4),1024+(xx*2048)+8192,0,1024+(yy*2048)+8192)
				EndIf
			Next	
				
				
				Land_mesh(xx+4,yy)=CopyEntity(Land_mesh(xx,yy))
				Land_mesh(xx,yy+4)=CopyEntity(Land_mesh(xx,yy))
				Land_mesh(xx+4,yy+4)=CopyEntity(Land_mesh(xx,yy))
				PositionEntity Land_mesh(xx,yy), 	1024+(xx*2048),				0,	1024+(yy*2048)
				PositionEntity Land_mesh(xx+4,yy), 	1024+(xx*2048)+8192,		0,	1024+(yy*2048)
				PositionEntity Land_mesh(xx,yy+4), 	1024+(xx*2048),				0,	1024+(yy*2048)+8192
				PositionEntity Land_mesh(xx+4,yy+4),1024+(xx*2048)+8192,		0,	1024+(yy*2048)+8192
				
				
			For xxx=0 To 4 Step 4
				For yyy=0 To 4 Step 4

					EntityPickMode Land_mesh(xx+xxx,yy+yyy),2
				Next
			Next
       	Next
    Next

End Function

	If Scenery_Obj_Class\Is_added_to_Collision>0 Then ; add the Scenery object to the Collision system
				
		test_Space=dHashSpaceCreate(Space64(Floor(bx/2048),Floor(by/2048)))
		test = CreateTriMesh_First_Surface(test_Space,NewTree)
		dGeomSetPosition(test, bx, byy#, bz)
					
		test_Space=dHashSpaceCreate(Space64(Floor((bx + FullmapSizeX)/2048),Floor(by/2048)))
		test = CreateTriMesh_First_Surface(test_Space,NewTree)
		dGeomSetPosition(test, bx + FullmapSizeX, byy#, bz)
					
		test_Space=dHashSpaceCreate(Space64(Floor(bx/2048),Floor((by + FullmapSizeY)/2048)))
		test = CreateTriMesh_First_Surface(test_Space,NewTree)
		dGeomSetPosition(test, bx, byy#, bz + FullmapSizeY)
					
		test_Space=dHashSpaceCreate(Space64(Floor((bx + FullmapSizeX)/2048),Floor((by + FullmapSizeY)/2048)))
		test = CreateTriMesh_First_Surface(test_Space,NewTree)
		dGeomSetPosition(test, bx + FullmapSizeX, byy#, bz + FullmapSizeY)
	EndIf
 

Quite a few things can cause SpaceCollide to MAV so it isn't always easy to pinpoint. It can happen if you create geoms inside the boundary of other geoms, for example adding more than one geom in the exact same location (overlapping the previous geom). Another cause can be if too many collision contacts are generated causing memory/stack issues.

Here are some things to check that you may have missed...
- Make sure all of your Space variables are global or a dim array (I can't see where you're defining the Space64 array).
- Check for memory leaks.
- Try lowering/raising the max contacts value with dContactSetMaxContacts(maxvalue) to see if that helps, its default is 128.
- Make sure your Space64 sub-spaces are not colliding with each other or the ground plane (if used).
- Make use of the body auto disable feature so that it cuts down the amount of contacts generated when objects are stationary.

I still think tiling the ODE geometry like you're doing will give you headaches, so that may be at the center of the MAV issue. Try destroying and recreating the geometry instead of repositioning, it may work better and should certainly be fast enough.

Not sure about the best way to do the shock wave, have you tried adding force to the surrounding objects based on their distance from the epicentre. Be careful changing the geom size while the simulation is running, I'm not sure how ODE will react to that. You can try using the dGeomSphereSetRadius(sphere,radius) etc functions for this purpose.

Hope this helps :)

Oh, and the forum codes...

http://www.blitzmax.com/faq/faq_entry.php?id=2

I have found where the problem is, well most of it. It seems that the Cylinder to trimesh is the course of most of the crashes. I will add a Spheres to each end and see if that fix’s the crashing problem

I am also adding dContactSetMaxContacts(512)

I am not moving any of the trimeshes only the Cylinders and Spheres. The crashing stated before I add the code to translate them to their new locations.

I was thinking along the same lines with the shock wave thing

One thing I would like to do is make a house with bricks and then blow it up. speed will be a problem. I have tried optimising it but still need some tips. I will use about 200 bricks. any speed tips.

I will make a demo for you all to mess with. Call it something like

Demolition house on trimesh.bb

Thanks for your help

You might be better off using capped cylinders if the standard ones are giving you problems.

Hmm, speed tips for 200 bricks? Try lowering your dContactSetMaxContacts() value down as low as possible. You could also try increasing the QuickStep step size. Use body auto disable on the bricks.

Credit where credit is due!

Hehe, 24/7... I'm not sure about that but I do check on the troops regularly.

Thanks BT :)

Wow 3 hours, you are letting yourself go ;)

Battle Tanks Earth Level. Still early days.

Ooh I hope that's a tank game with physics, can't wait to see something like that done with ODE :)

PS: Gasp! 9 hours late ;)

Can anyone confirm the DSpaceCollide2 function works 100% under BlitzMax? (Sorry, there's no Bmax thread yet so I posted here in hope!)

dSpaceCollide2(ray,Space.Space,world.world,group.group) - Memory Exception Error

dSpaceCollide2(ray,0,world.world,group.group) - Memory Exception error.

Ray, Space,World and Group are all valid.

The second line throwing an error makes sense, 0 space. I was toying with it to see if it would allow me to use that instead of Ode's DCollide function. (Could do with that function ;) )

I fail to see why this fails, I can use DSpaceCollide in the same place to collide spaces with other spaces no problem?

If i don't bother trying to do this, and call DspaceCollide, then the ray returns values on the next frame so it *does* work, but trying to use DSpaceCollide2 doesn't.

Perhaps i've got the wrong function?

You should be supplying two geoms Cygnus, not a geom and space...

dSpaceCollide2(geom1,geom2,world,group)

[edit] Confirmed, it's working ok in BlitzMax ;)

I see, I thought that would be the case, The official ODE Docs read:


So, I need a command where i can check one single geom against a space, like Dcollide or the Official DSpaceCollide2 command. How can I do this? :D

Checking for collisions with spaces using dSpaceCollide2() isn't implemented in JV-ODE, only geoms are currently supported with this function.

dCollide() is of absolutely no use externally, hence it isn't wrapped.

I can look into whether it's possible to implement space collisions with dSpaceCollide2() for the next JV-ODE update if you wish?

If you can, Yeah, I looked at Dcollide, since it doesnt return any details it is indeed useless.

I do need the ability to check geom>Space though so if you could implement that i'd be extremely greatful! :D

Ok, I've just done a few quick tests and it looks like it will indeed be possible with a little bit of work. It would give the ability to check geom/space>geom/space using dSpaceCollide2().

I'll add it to the 2do for the next update.

Thanks Viper. When it comes to customer support, you can't be beaten! :D

I think their are three Viper. Entreating , I hear you say, that is what the 3 is for in VIP3R. They each take 8 hours shift answering our questions. So what dues it all stand for? Very Intelligent Person with 3 Replicas. In-fact I think the original one is on holiday. Which I think is very unfair on the them poor Replicas. I think we should start campaign. So come on Viper get back here and do your fare share. Before will let the authority know about your Clones! !We have photo graphic evidence! ;)

[qupte]Very Intelligent Person with 3 Replicas.[/quote]

LMFAO! :D

On a more informative note. For all you JV-ODE fans out there eager to get every last bit of speed out of an already fast Physic system, here some speed tips.

Speed Tip 1) Only add the surfaces of an model to the Physic system that you really need to i.e. no need to add the leaves of a tree just the trunk

Speed Tip 2) Use a program like milkshake to reduce the number of polygons in our models. The DirectX mesh tool is grate for this. Now Export it as a new model something like “phy-(oldname).3ds”.
Now in your program when you use the model of a Tree for instance you will and a hi poly model for Eye Candy and a low poly model for the Physic system. I used these two methods on a tree with over 6000 triangles and made a Physic trimesh with 136 triangles, why not try it.

If fact it would be really cool if Viper could include a triangle reduction tool like this into the next update. Something like Newmesh=ReduceTriangles(oldmesh, % Reduction)

http://www.blitzbasic.com/codearcs/codearcs.php?code=1285 ;)

:)
:)
:)

I Did Try that one.
It's good but has some bad side effects and is slow. I found the DirectX tool gives the best finish but you have to use it out side of blitz. The code Is a start but needs some work.

you're never satisfied, are you? your poor mom/wife... >;P

I've been helping a JV-ODE user out with AMotor joints via email and thought that this info would be helpful to everyone, so here it is...

Creating and using AMotor joints:
Attach two bodies using a Ball joint, then attach an AMotor joint to the same two bodies. The Ball joint will keep the two bodies attached to each other and will allow movement in all directions. In the car demo below, you will see that the rear wheels are attached using Ball joints instead of Hinge2 joints like the two front wheels.

Without the AMotor joints on the rear wheels, they would collapse as Ball joints move in any direction. Try commenting out all of the AMotor stuff in the SetupCar() and UpdateCar() functions in the AMotor demo and you will see the rear wheels wobble and collapse.

One ability of the AMotor joint is to restrict motion on any axis, in the car demo it stops the wheels collapsing by restricting movement of the Ball joint in all directions except the z axis to allow the Ball joint (or wheel) to rotate.

The dJointSetAMotorAxis() functions will allow you to set whether rotation is allowed on each axis of the joint. A value of 0 (zero) will not allow movement, a value of 1 (or -1 to reverse) will allow movement.

Next, you need to set the 'dParamLoStop' and 'dParamHiStop' parameters with the dJointSetAMotorParam() function to define how much rotation is allowed. The value should be in radians, not degrees. A value of zero for both LoStop and HiStop will not allow any movement. As you can see in the car demo we need full rotation to allow the wheel to spin completely, so it is set with -4 radians for the LoStop and 4 radians for the HiStop which will allow full rotation. Try changing them to -2 and 2 and you will see that the wheels lock after approx 1/2 a rotation. Remember that the LoStop value must always be the lowest value and the HiStop must be the highest value.

The second ability is that you are able to supply a force to AMotor joints to make them rotate, like an electric motor. See the third For/Next loop in the UpdateCar() function in the car demo, you can use 'dParamVel' (force) and 'dParamFMax' (torque) to do this.

You need to set all of the AMotorAxis and AMotorParam settings for the AMotor joint to function correctly.

Here's the AMotor demo... (it will be included in the next JV-ODE update)

; ###################################################################################################
; #										  JV-ODE Car Demo											#
; #									Code by Jim Williams (VIP3R)									#		#
; #						Feel free to use this code, any credit appreciated							#
; ###################################################################################################

AppTitle "JV-ODE Car Demo - AMotor"

Include "JV-ODE.bb"

Graphics3D 800,600,0,2

Global CMass#=200			; ### Car Mass
Global WMass#=14			; ### Wheel Mass

Global WorldERP#=0.8		; ### World Error Correction
Global WorldFriction#=70	; ### World Friction

Global Torque#=24			; ### Joint Torque
Global SuspensionHS#=0.01	; ### Suspension Hardness/Softness (Higher=Softer - Lower=Harder)

Global Force#=0
Global Steer#=0

Global Car
Global CGeom
Global CMesh

Global CarStartY=20

Dim Wheel(4)
Dim WGeom(4)
Dim Joint(4)

Type ODEGeom
	Field body
	Field geom
	Field mesh
End Type

; ###################################################################################################

; ### Setup ODE

Global World=dWorldCreate()
Global Space=dHashSpaceCreate(0)
Global ContactGroup=dJointGroupCreate(0)

dWorldSetAutoDisableFlag(World,1)
dWorldSetGravity(World,0,-0.98,0)
dWorldSetERP(World,WorldERP)

dContactSetMode(dContactSlip1)
dContactSetMu(WorldFriction)

; ### Create car body

ode.ODEGeom=New ODEGeom
ode\body=dBodyCreate(World)
Car=ode\body
dBodySetRotation(ode\body,0,0,0)
dBodySetPosition(ode\body,0,CarStartY,0)
mass=dMassCreate()
dMassSetBoxTotal(mass,CMass,3,1,4)
dMassTranslate(mass,0,-1,0)
dBodySetMass(ode\body,mass)
dMassDestroy(mass)
ode\geom=dCreateBox(Space,3,1,4)
CGeom=ode\geom
dGeomSetBody(ode\geom,ode\body)
ode\mesh=CreateCube()
CMesh=ode\mesh
ScaleMesh ode\mesh,1.5,0.5,2
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0
EntityColor ode\mesh,40,80,255
EntityAlpha ode\mesh,1

; ### Create wheels

For count=1 To 4
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	Wheel(count)=ode\body
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,0,0,0)
	mass=dMassCreate()
	dMassSetSphereTotal(mass,WMass,0.7)
	dBodySetMass(ode\body,mass)
	dMassDestroy(mass)
	ode\geom=dCreateSphere(Space,0.7)
	WGeom(count)=ode\geom
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateCylinder(8)
	ScaleMesh ode\mesh,0.7,0.25,0.7
	RotateMesh ode\mesh,0,0,90
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,255,255,255
Next

dBodySetPosition(Wheel(1),-2,CarStartY-0.5,+2)
dBodySetPosition(Wheel(2),+2,CarStartY-0.5,+2)
dBodySetPosition(Wheel(3),-2,CarStartY-0.5,-2)
dBodySetPosition(Wheel(4),+2,CarStartY-0.5,-2)

; ### Create some objects

SeedRnd MilliSecs()

For spheres=1 To 20
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	dBodySetRotation(ode\body,0,0,0)
	dBodySetPosition(ode\body,Rnd(-100,100),30,Rnd(-100,100))
	ode\geom=dCreateSphere(Space,4)
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateSphere()
	ScaleMesh ode\mesh,4,4,4
	RotateMesh ode\mesh,0,0,0
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
Next

For cylinders=1 To 20
	ode.ODEGeom=New ODEGeom
	ode\body=dBodyCreate(World)
	dBodySetRotation(ode\body,90,0,0)
	dBodySetPosition(ode\body,Rnd(-100,100),30,Rnd(-100,100))
	ode\geom=dCreateCCylinder(Space,1,8)
	dGeomSetBody(ode\geom,ode\body)
	ode\mesh=CreateCylinder(8)
	ScaleMesh ode\mesh,1,5,1
	RotateMesh ode\mesh,90,0,0	; <<< Mesh X-Axis must be rotated 90 degrees to fix cylinder alignment
	PositionMesh ode\mesh,0,0,0
	EntityColor ode\mesh,Rnd(255),Rnd(255),Rnd(255)
	EntityAlpha ode\mesh,1
	EntityShininess ode\mesh,0.7
Next

; ### Create light

Global Light=CreateLight()

RotateEntity Light,45,-90,0
LightColor Light,255,255,255
AmbientLight 130,130,130

; ### Create camera

Global CameraPivot=CreatePivot(CMesh)
PositionEntity CameraPivot,0,2,-7

Global Camera=CreateCamera()
CameraClsColor Camera,0,0,0
CameraRange Camera,1,1000

; ### Create plane

dCreatePlane(Space,0,1,0,0)

Plane=CreatePlane()

EntityAlpha Plane,0.8

PlaneTexture=CreateTexture(128,128,9)

ClsColor 0,200,80
Cls

Color 255,255,255

Rect 0,0,64,64,1
Rect 64,64,64,64,1

CopyRect 0,0,128,128,0,0,BackBuffer(),TextureBuffer(PlaneTexture)
ScaleTexture PlaneTexture,20,20
EntityTexture Plane,PlaneTexture,0,0

Mirror=CreateMirror()

; ###################################################################################################

; ### BLITZ STATIC OBJECT (White)

blitzobject=CreateCube()
ScaleMesh blitzobject,1,4,20
RotateMesh blitzobject,-10,8,4
PositionMesh blitzobject,10,5,40

EntityColor blitzobject,255,255,255
EntityAlpha blitzobject,1

; ### ODE STATIC OBJECT (Blue)

ode.ODEGeom=New ODEGeom
ode\geom=dCreateBox(Space,2,8,40)
dGeomSetRotation(ode\geom,-10,8,4)
dGeomSetPosition(ode\geom,20,5,40)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,1,4,20
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0

EntityColor ode\mesh,0,100,200
EntityAlpha ode\mesh,1

; ### ODE STATIC OBJECT (Red)

ode.ODEGeom=New ODEGeom
ode\geom=dCreateBox(Space,18,0.2,40)
dGeomSetRotation(ode\geom,-14,0,0)
dGeomSetPosition(ode\geom,-20,4.9,40)
ode\mesh=CreateCube()
ScaleMesh ode\mesh,9,0.1,20
RotateMesh ode\mesh,0,0,0
PositionMesh ode\mesh,0,0,0

EntityColor ode\mesh,200,0,100
EntityAlpha ode\mesh,1

; ###################################################################################################

SetupCar()

While Not KeyHit(1)

	UpdateKeys()

	PTime=MilliSecs()

	UpdateCar()

	UpdateGeoms()

	dSpaceCollide(Space,World,ContactGroup)
	dWorldQuickStep(World,0.1)
	dJointGroupEmpty(ContactGroup)

	PhysicsTime#=MilliSecs()-PTime

	UpdateCam()

	UpdateWorld

	RenderWorld

	Text 0,0,"JV-ODE Version "+dGetVersion()
	Text 0,15,"Physics Time:"+PhysicsTime
	Text 0,50,"Force:"+Force
	Text 0,65,"Torque:"+Torque
	Text 640,0,"A - Accelerate"
	Text 640,15,"Z - Brake/Reverse"
	Text 640,30,"Arrows - Steering"
	Text 640,45,"Space - Reset Car"

	Flip

Wend

dJointGroupDestroy(ContactGroup)
dSpaceDestroy(Space)
dWorldDestroy(World)
dCloseODE()

End

; ###################################################################################################

Function SetupCar()

For count=1 To 2
	Joint(count)=dJointCreateHinge2(World,0)
	dJointAttach(Joint(count),Car,Wheel(count))
	dJointSetHinge2Anchor(Joint(count),dBodyGetPositionX(Wheel(count)),dBodyGetPositionY(Wheel(count)),dBodyGetPositionZ(Wheel(count)))
	dJointSetHinge2Axis1(Joint(count),0,1,0)
	dJointSetHinge2Axis2(Joint(count),-1,0,0)
	dJointSetHinge2Param(Joint(count),dParamSuspensionERP,0.8)
	dJointSetHinge2Param(Joint(count),dParamSuspensionCFM,SuspensionHS)
Next

For count=3 To 4
	Joint(count)=dJointCreateBall(World,0)
	dJointAttach(Joint(count),Car,Wheel(count))
	dJointSetBallAnchor(Joint(count),dBodyGetPositionX(Wheel(count)),dBodyGetPositionY(Wheel(count)),dBodyGetPositionZ(Wheel(count)))
	Joint(count)=dJointCreateAMotor(World,0)
	dJointAttach(Joint(count),Car,Wheel(count))
	dJointSetAMotorMode(Joint(count),dAMotorEuler)
	dJointSetAMotorAxis(Joint(count),0,0,0,0,0)
	dJointSetAMotorAxis(Joint(count),1,0,0,0,0)
	dJointSetAMotorAxis(Joint(count),2,0,0,0,1)
	dJointSetAMotorParam(Joint(count),dParamLoStop,-4)
	dJointSetAMotorParam(Joint(count),dParamHiStop,4)
	dJointSetAMotorParam(Joint(count),dParamLoStop2,0)
	dJointSetAMotorParam(Joint(count),dParamHiStop2,0)
	dJointSetAMotorParam(Joint(count),dParamLoStop3,0)
	dJointSetAMotorParam(Joint(count),dParamHiStop3,0)
Next

Force=0

End Function

; ###################################################################################################

Function UpdateKeys()

If KeyDown(30)=1
	Force=Force+0.08
	If Force>70 Then Force=70
	End If

If KeyDown(44)=1
	Force=Force-0.1
	If Force<-10 Then Force=-10
	If Force>0 Then Force=Force*0.97
	End If

If KeyDown(30)=0 And KeyDown(44)=0 Then Force=Force*0.99

If KeyDown(203)=1 Or KeyDown(205)=1
	If KeyDown(203)=1
		Steer=0.5
		Else
		Steer=-0.5
		End If
	Else
	Steer=0
	End If

If KeyHit(57)=1
	Force=0
	dBodySetRotation(Car,dGeomGetPitch#(CGeom),dGeomGetYaw#(CGeom),0)
	End If

End Function

; ###################################################################################################

Function UpdateCar()

For count=1 To 4
	dBodyEnable(Wheel(count))
Next

dBodyEnable(Car)

For count=1 To 2
	dJointSetHinge2Param(Joint(count),dParamVel2,Force)
	dJointSetHinge2Param(Joint(count),dParamFMax2,Torque)
Next

For count=3 To 4
	dJointSetAMotorParam(Joint(count),dParamVel,-Force)
	dJointSetAMotorParam(Joint(count),dParamFMax,Torque)
Next

For count=1 To 2
	angle#=Steer-dJointGetHinge2Angle1(Joint(count))
	dJointSetHinge2Param(Joint(count),dParamVel,angle)
	dJointSetHinge2Param(Joint(count),dParamFMax,400)
Next

End Function

; ###################################################################################################

Function UpdateCam()

PositionEntity CameraPivot,0,3,-12

camx#=EntityX(CameraPivot,1)-EntityX(Camera)
camy#=EntityY(CameraPivot,1)-EntityY(Camera)
camz#=EntityZ(CameraPivot,1)-EntityZ(Camera)

TranslateEntity Camera,camx*0.5,camy*0.5,camz*0.5

PointEntity Camera,CMesh

End Function

; ###################################################################################################

Function UpdateGeoms()

For ode.ODEGeom=Each ODEGeom
	RotateEntity ode\mesh,dGeomGetPitch#(ode\geom),dGeomGetYaw#(ode\geom),dGeomGetRoll#(ode\geom)
	PositionEntity ode\mesh,dGeomGetPositionX#(ode\geom),dGeomGetPositionY#(ode\geom),dGeomGetPositionZ#(ode\geom)
Next

End Function

; ###################################################################################################

hm i always wondered what is the real benefit of using motors instead of using normal joints+applying rotational forces to them?

They're good for simulating stuff like motor servos or can be used as motors for insect legs, that kind of thing. They provide more flexibility for joint control in both restriction of movement and when applying forces.

After looking at (and deconstructing) the cardemo's there's one question I like to ask:

First you create a body , then create the geometry for it and then create the mesh. So far so good.

Now, let's say I've modeled a car (including the wheels).
Would it not be possible to create ODE-objects in a reverse order?

Thus:

1) load carmesh (wheels are child-entities within the same file btw)
2) create a body
3) determine size of carmesh (meshwidth,meshheight,meshdepth)
4) position body at location of carmesh
5) use dMassSetBoxTotal as follows: dMassSetBoxTotal ( mass , CarMass , meshwidth*2 , meshheight*2 , meshdepth*2 )
6) create geometry for carmesh
7) bind geometry to body

and because I already know the location and size of each wheel just repeat step (2) through (7) ?

This should do the trick , right?
Unfortunately I get some strange readings in my debuglog , and my screen shows absolutely nothing.
I'll try to reproduce the situation and post a screenshot of it.

In the meantime I would like to know if the aforementioned procedure is acceptable or not?

Thanks in advance!

I've used the procedure when starting what was "Enginev2". it worked fine, so it is possbile :)

Thanks Cygnus. I'm a happy bunny :D
BTW here are a few models I'm using it for (they are not finished yet though)

JV-ODE V1.15 Update Released

Please check your inbox :)

The new update includes:

Added support for Space collision checking in the dSpaceCollide2() function

Added CarDemo-AMotor
Added CarDemo-TruckTrailer

Changed CarDemo-SphereWrapCylinder to include Geom Transform option

Please let me know if you experience any problems with the new update.

:)

You *know* i've been staring at this thread waiting. Thanks man!

Thanks VIP3R - looking good as usual.

One question, the Amotor method of driving a vehicles wheels would not have the inherent suspension settings that a hinge2 joint would have, would it ?

Am i right in thinking that you would need to model the suspension yourself (a little project i've been thinking of for a while).

i.e. use the amotor to drive the wheel whilst it's held in position using a system of connecting rods / hinges to mimic a real suspension unit.

Mark

Cool... updates just keep coming! :)

Thanks all :)

You should be able to use the AMotor as a wheel joint providing you add a separate suspension system as you've decribed. I haven't tried it yet, but the theory seems sound to me.

thx for update!

for what is it good the new "dSpaceCollide2()" ?

You're welcome Barton :)

dSpaceCollide() processes collisions for all Geoms and Spaces.

dSpaceCollide2() processes collisions on only the Spaces/Geoms specified, allowing you to manually select which Geoms or Spaces are checked for collisions.

More control, I like it !!
Thanks for update VIP3R.