How do I use the "EntityVisible()" command

Hey guys, it's me again. I was wondering if someone could give me a correct example of how to use the EntityVisible() command in B-3D. I am trying to see if it will help me in my program, but I am not sure how this command works exactly. Can anyone help me out here????

GRAPHICS3D 640,480,32,2
SETBUFFER BACKBUFFER()

Sphere1 = CREATESPHERE(25)
POSITIONENTITY Sphere1,0,0,-3
ENTITYCOLOR Sphere1,255,0,0
ENTITYPICKMODE Sphere1,2,1

Box = CREATECUBE()
SCALEENTITY Box,2.4,1.5,0.2
POSITIONENTITY Box,0,0.75,0
ENTITYCOLOR Box,200,200,200
ENTITYPICKMODE Box,2,1

Plain = CREATECUBE()
SCALEENTITY Plain,5,0.000001,5
POSITIONENTITY Plain,0,-1,0

Texture = CREATETEXTURE(128,128)
SETBUFFER TEXTUREBUFFER(Texture)
CLSCOLOR 0,0,0 : CLS

FOR X = 0 TO 128 STEP 7.7
   COLOR 255,0,0 : LINE X,0,X,128
NEXT

FOR Y = 0 TO 128 STEP 7.7
   COLOR 255,0,0 : LINE 0,Y,128,Y
NEXT

ENTITYTEXTURE Plain,Texture
SETBUFFER BACKBUFFER()

Sphere2 = CREATESPHERE(25)
POSITIONENTITY Sphere2,0,0,3
ENTITYCOLOR Sphere2,0,255,0
ENTITYPICKMODE Sphere2,2,1

Camera = CREATECAMERA()
POSITIONENTITY Camera,5,5,5
POINTENTITY Camera,Box

Light = CREATELIGHT(1,Camera)

WHILE NOT KEYHIT(1)
   IF KEYDOWN(205) THEN MOVEENTITY Box,-0.03,0,0
   IF KEYDOWN(203) THEN MOVEENTITY Box, 0.03,0,0

   Visible = ENTITYVISIBLE(Sphere1,Sphere2)

   UPDATEWORLD
   RENDERWORLD

   IF Visible = 1 THEN
      COLOR 255,255,255
      TEXT 0,0,"balls can see each other"
   ELSE
      COLOR 255,255,255
      TEXT 0,0,"balls are invisible to each other"
   ENDIF
   FLIP
WEND
END

borrowed from the german onlinehelp, use cursor keys to move the wall

Much Thanks

@OJay
You're shouting (excessive use of CAPS). heh heh