Glass Ball material

Through a rather long story (which I won't waste your time by writing here), I was stricken by a rather good game idea. It started off with a graphics idea, then, after 8 hours in a zen-like state, it expanded to a full game. Quite fun :)

Anyway, what I need help with: I can not figure out how to make a shiny glass orb. I have done my own attempt with a spheremap, and it looks awful. The shininess is way too dull, and it all looks very boring.

;Graphics concept
	;'Go' style TBS game
	
;Do not use this particular file for the main module like you always do... Y`idiot.

AppTitle "Graphics concept - 'Go' style TBS game"
Graphics3D 800,600,0,2
SetBuffer BackBuffer()

camera=CreateCamera()
PositionEntity camera,0,10,0
;AmbientLight 200,200,200
light=CreateLight(2)
PositionEntity light,5,5,-2



char=CreateSphere();LoadMesh("media\meshes\characterA.3ds")
brushMain=CreateBrush()
BrushAlpha brushMain,0.2
sphereMap=LoadTexture("media\gfx\orb_spheremap.png",67)
BrushTexture brushMain,sphereMap
PaintEntity char,brushMain
PositionEntity char,0,1,8

box=CreateCube()
EntityColor box,150,150,150
PositionEntity box,0,-10,0
ScaleEntity box,10,10,10

While Not KeyDown(1)
	TurnEntity camera,MouseYSpeed()/2,-MouseXSpeed()/2,0
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	Local moveSpeed# ;Controlled with Shift key
    If KeyDown(42) Then moveSpeed#=0.05 Else moveSpeed#=0.2
	If KeyDown(30) Then MoveEntity camera,-moveSpeed,0,0
    If KeyDown(32) Then MoveEntity camera,moveSpeed,0,0
	If KeyDown(17) Then MoveEntity camera,0,0,moveSpeed
	If KeyDown(31) Then MoveEntity camera,0,0,-moveSpeed
	RenderWorld
	Flip
Wend

End

Here is media/gfx/orb/spheremap:
And another one I tried that may look better:


So... Can I get some help with doing decent shiny glass orbs? Like this image: http://images.google.com/images?q=tbn:AieH844UI7AJ:http://www.spdesign.co.uk/links/Final.jpg , except transparent (and a tiny bit more shininess, and I don't mind at all if it has one less spot).

(Quite obviously, I know nothing about this stuff)

I would suggest:

Create a sphere, texture it with a mild gradient texture (lighter blue to a slightly less lighter blue),

create a texture which has your reflective lens spot on it and use it as a cube map on the sphere (static cube map)

Then make the sphere have an alpha of .4 or so. Place another sphere inside it slightly smaller with an alpha of say .5 or so (play with the alphas a bit), the inner sphere will have the same blue gradiant tex but no cube mapped light spot.

Play with the alphas a bit though. This should give you a nice glass orb effect.

If you want to go a bit further, change the cube map to dynamic (using a camera)and invert it on the sphere, this should give you a decent refractive image of everything around it.

This is merely theory though :-)

I had similar thoughts to Dark Half. Off the top of my head...

Graphics3D 800,600,0,0
SetBuffer BackBuffer()


cam=CreateCamera()
PositionEntity cam,0,0,-8

light=CreateLight(2)
PositionEntity light,15,40,-28
LightRange light,240

room=CreateCube()
ScaleEntity room,10,10,10
PositionEntity room,0,5,0
FlipMesh room
EntityFX room,1


fixture=CreateCube(room)
ScaleEntity fixture,.1,.1,.1
PositionEntity fixture,0,-.5,.5
EntityColor fixture,100,100,200


roomTex=CreateTexture(32,32,256)
SetBuffer TextureBuffer(roomTex)
Color 200,100,100 : Rect 0,0,32,32,True
Color 100,200,100 : Rect 0,0,16,16,True : Rect 16,16,16,16,True
SetBuffer BackBuffer()
ScaleTexture roomTex,.1,.1
EntityTexture room,roomTex


sphere=CreateSphere(32)
sphereTex=CreateTexture(256,256,256+64)
EntityTexture sphere,sphereTex

EntityShininess sphere,.1



sineBase#=0.0

While Not KeyDown(1)
;movement
PositionEntity sphere,0+Sin(sineBase),0,0
sineBase=sineBase+1.0
If sineBase>360 Then sineBase=sineBase-360

TurnEntity room,0,.1,0

;render sphere texture
CameraViewport cam,0,0,256,256
CameraZoom cam,4
CameraRange cam,5,30
EntityAlpha sphere,0
RenderWorld
CopyRect 0,0,256,256,0,0,BackBuffer(),TextureBuffer(sphereTex)


;render scene
CameraViewport cam,0,0,800,600
CameraZoom cam,1.4
CameraRange cam,.01,30
EntityAlpha sphere,1
RenderWorld


Flip

Wend

Inverting the orb is problematic with spheremaps but I'm sure you can tweak it.

Tweaky:

Graphics3D 800,600,0,0
SetBuffer BackBuffer()


cam=CreateCamera()
PositionEntity cam,0,0,-8

light=CreateLight(2)
PositionEntity light,15,40,-28
LightRange light,240

room=CreateCube()
ScaleEntity room,10,10,10
PositionEntity room,0,5,0
FlipMesh room
EntityFX room,1


fixture=CreateCube(room)
ScaleEntity fixture,.1,.1,.1
PositionEntity fixture,0,-.5,.5
EntityColor fixture,100,100,200


roomTex=CreateTexture(32,32,256)
SetBuffer TextureBuffer(roomTex)
Color 200,100,100 : Rect 0,0,32,32,True
Color 100,200,100 : Rect 0,0,16,16,True : Rect 16,16,16,16,True
SetBuffer BackBuffer()
ScaleTexture roomTex,.1,.1
EntityTexture room,roomTex


sphere=CreateSphere(32)
sphereTex=CreateTexture(256,256,256+64)
EntityTexture sphere,sphereTex

EntityShininess sphere,.1



sineBase#=0.0

While Not KeyDown(1)
;movement
PositionEntity sphere,0+Sin(sineBase),0,0
sineBase=sineBase+1.0
If sineBase>360 Then sineBase=sineBase-360

TurnEntity room,0,.1,0

;render sphere texture
PositionEntity cam,EntityX(sphere),EntityY(sphere),EntityZ(sphere)
CameraViewport cam,0,0,256,256
CameraZoom cam,4
EntityAlpha sphere,0
RenderWorld
CopyRect 0,0,256,256,0,0,BackBuffer(),TextureBuffer(sphereTex)


;render scene
PositionEntity cam,0,0,-8
CameraViewport cam,0,0,800,600
CameraZoom cam,1.4
EntityAlpha sphere,1
RenderWorld


Flip

Wend

That refraction alone makes it ten times more satisfying.

Thanks!

(Now... How to make a procedural whitish sterile landscape that can be refracted... That's a fun puzzle :D )

I've done similar. Using only two textures, create your basic sphere image with a reflection map, and then create a highlights texture with ADDITIVE blending. This gives nice shiny highlights