Two bits of a model overlapping when the shouldnt

I have one model of a village in 3ds which i export to b3d. I have created a fence and long grass one behind the other. But the grass appears to be infront of the fence when it is geometricly placed behind it.

How would i over come this?

I have tried loading the grass seperatly and using entity order but that just puts the fence infront of the grass instead. I dont want either of these results.

How do i get the grass shoing like it is infront and behind the fence without the fence screwing up?

I have even noticed that the back grass overlaps the front grass.

Eeeaaarrrr!!

How do i stop this?

Using masked textures instead of alpha'ed textures will probably do it. It's not ideal, I know, but any time you have multiple alphaed objects sharing screenspace, this seems to happen.

So there is no way to ACTUALLY fix it?
Thats a real bad bug.

nope not really, I think beaker wrote a alpha sorting algorithm for sorting billboard sprites, but its not really suuitable for meshes like the fence.

Sometimes you can get away with mixing alpha as the alpha for an entity is sorted by how close its pivot is to 0,0,0

so sometimes you can set up layers and move the entities local pivot further from 0 on Y so that it gets drawn behind whatever entity with alpha has its pivot closer to 0

Not much use for a lot of things, and certainly not in your case, but useful to know.

(it's one of those things that realy holds blitz back, shame there can't be an optional alpha sorting flag you can set if you want certain things to get sorted).

Your only real solution is to use a mask, a bit dirtier looking, however its pretty common even in commercial engines like Ghost recon etc to use 1bit masks. It's just a lot quicker to render than an 8bit greyscale, and often people are used to seeing it that they don't really notice.


Actually I don't think I ever used an engine that could cope with more than 4 seperate overlapping arbitrary meshes with alpha properly unless they are billboard type sprites.

Yes, because alpha stuff can not use the Z buffer it is depth sorted at the entity level. So if the origin of the grass is closer to the camera than the origin of the fence it will be drawn after the fence and if it is further away it will be drawn before the fence.

The fix is to use masked textures as already suggested unless you want major headaches.

Here is a quick example that demonstrates how alpha objects are sorted and how using masking instead resolves the issue. Note how I avoid a dirty mask caused by bilinear filtering by setting the mask color to a color close to the unmasked color. Masking usually only masks out black on loaded textures, but you could get around that by loading as alpha then copying to masked, bearing in mind that any pixel with an alpha value less than 129 will be masked out.

Graphics3D 640,480,0,2

texture1=CreateTexture(256,256,1+4)
SetBuffer TextureBuffer(texture1)

For i=0 To 256 Step 4
Color 255,255,255 : Rect i,0,2,256
Color 254,254,254 : Rect i+2,0,2,256
Next
Color 255,255,255 : Rect 0,20,256,8 : Rect 0,200,256,8
SetBuffer BackBuffer()
Color 254,254,254
Setcoloralpha(texture1,0)

texture2=CreateTexture(256,256,1+4+16+32)
SetBuffer TextureBuffer(texture2)
Color 60,140,0 : Rect 0,0,256,256
Color 0,100,0 : Rect 124,60,12,256
For i=0 To 60
x=Rand(40,190) : y=Rand(40,200)
w=Rand(30,60)  : h=Rand(20,30)
r=Rand(50,120) : g=Rand(100,150)
Color 0,100,0
Line 128,y+40,x+w/2,y+h/2
Line 128-1,y+40,x+w/2-1,y+h/2
Line 128,y+40,x+w/2+1,y+h/2
Color r,g,0 : Oval x,y,w,h
Color 255,255,0 : Oval x+w/2-4,y+h/2-2,8,4
Next
SetBuffer BackBuffer()
Color 60,140,0
Setcoloralpha(texture2,0)

camera=CreateCamera()
CameraClsColor camera,0,0,100

plane=CreatePlane()
EntityColor plane,0,100,0
PositionEntity plane,0,-5,0

light=CreateLight()
RotateEntity light,45,45,0

fence=CreateCube()
EntityColor fence,200,100,0
EntityTexture fence,texture1
ScaleMesh fence,0.01,5,50
PositionEntity fence,0,0,20
RotateEntity fence,0,-20,0

trifid=CreateSprite()
ScaleSprite trifid,2,4
EntityBlend trifid,1
PositionEntity trifid,0,-1,10
EntityTexture trifid,texture2

Alpha=False

Repeat

	If KeyHit(57) Then alpha=Not alpha
	If alpha Then 
		EntityAlpha fence,0.5
		EntityAlpha trifid,0.9
	Else
		EntityAlpha fence,1
		EntityAlpha trifid,1
	EndIf
	 
	TurnEntity trifid,0,1,0
	TranslateEntity trifid,(KeyDown(205)-KeyDown(203))*0.1,0,(KeyDown(200)-KeyDown(208))*0.1
	
	RenderWorld
	Color 255,255,255
	Text 0,0,"Move trifid with arrow keys, toggle alpha with spacebar"
	If alpha Then Text 0,12,"Alpha is on" Else Text 0,12,"Alpha is off"
	Text 0,24,"Fence Distance "+EntityDistance(camera,fence)
	Text 0,36,"trifid Distance  "+EntityDistance(camera,trifid)
	
	TFormPoint 0,0,0,trifid,fence
	If TFormedX()>2 Then 
		Text 0,48, "Trifid on our side of the fence!"
	ElseIf TFormedX()<-2 Then 
		Text 0,48, "Trifid on the other side of the fence!"
	Else 
		Text 0,48, "Trifid is on the fence!"
	EndIf
	Flip

Until KeyHit(1)
End

Function Setcoloralpha(texture,alpha)
Local r=ColorRed(), g=ColorGreen(), b=ColorBlue(), rgb=r Shl 16 Or g Shl 8 Or b
Local buffer=TextureBuffer(texture), w=TextureWidth(texture), h=TextureHeight(texture)
Local i,j,pixel
alpha=alpha Shl 24
For i=0 To w-1
For j=0 To h-1
pixel=ReadPixel(i,j,buffer) And $FFFFFF
If pixel=rgb Then WritePixel i,j,alpha Or rgb,buffer
Next
Next
End Function 

BTW Alpha sorting issues are NOT Blitz3D bug or anything; it's just how HW/DX does it. Would be nice to have "automatic" z-sorting but it would be slow and quite case spesific... so don't ask Mark to "fix this" because he can't. Use masked textures instead.

I thought 'EntityOrder' solved problems like this:

http://www.blitzbasic.com/b3ddocs/command.php?name=EntityOrder&ref=3d_a-z


EDIT* Oh! I see you've tried that...

Regards,

Rogue Vector

My Z sorter would be ideal here as long as you combined the fence and grass textures into one. OR you could mask the fence and z-sort the grass.

Beaker, how do i get your Z sorter? Is it in the source archives?