CP - Alen Breed Remake - 6

Download site

On-Line Todo list




To Do:
Improve collision alien/walls and player/walls
Add more alien types
Add more player types
Front End

can you not just create one zip file.

no because then people would be downloading about 5 MB every time there's a code update, 56k'ers would not be happy chappies if we did that would they?

... alen breed?
you mean alien breed?...lol ;D

Big it up for Alen Breed ;)

I can't believe you guys are on your 6th thread.....

Updated code and Gfx zips ^^^^^



Come on guys!

I'll be back to it soon, but not tonight and probably not tomorrow, I'll be out all day.

This is coming along nicely.

Would you guys want a map editor written in B+ or are you keeping it to B2D\3D so every 1 can add to the editor? I can make sure I only use gadgets\flags that are in 1.1 or whatever the demo version is.

Cus I could make a kick ass easy to use Editor in B+.

Let me know.

We kind of decided to stick with B3D since the majority of Blitzers use it (I don't have B+ for instance).

Rob,

The changes you have made are great! Well done

Well would you believe it... I just got an email from Rico Holmes at Team 17...

That's a nice e-mail! And the game so far looks good too, I will download it when I get home.

(And I bet that e-mail subject gave you a scare!)

Sorry guys, It's been stressful at the moment. I'm changing jobs and I've had little time to contribute anything. But it's all sorted now so I'll be back tonight. Rob what are the immediate TODOs (specifically) so I can get coding/drawing straight away tonight.

* Sort collision with player/walls alien/walls (although I think that's a job for me as it's mostly my code in those bits)

* Death of individual players

* Differences in the players so they can't all pick up all the weapons for example (ie, fast people can't carry the heavy weapons).

* Front End.

I think we're dangerously close to having to create levels and start actually playing the game.

Ok, the OnTimer aliens are a big problem, so many spawned that it ground the game to a halt for me. Perhaps have a count property for them so that it will spawn a maximum number and then stop (or have a limit on the number of aliens that can be in existance at the same time).

Pert I think I broke something there, they seem to spawn even when they in an invisible area. I think you're right with the spawn count so that each spawner only creates x before dying.

Also in the editor it needs to be more flexible for the creation of the aliens, as it's only geared up for types 0 and 1, we should make it so that there's a spawner or an alien and you set what type it is, I think this would be more flexible than having to have seperate objects for each alien type.

I might be able to create a few levels for you if you like, I assume the editor is in the code or should I wait until the file format is finalised?

[edit]
I was going to offer my services with the editor itself but realistically I did not have the time that I wanted to put into it, especially at the very impressive pace that you all have been doing.

Top work everyone.

Will the manual have all the script commands, etc in there and an option to test the level in the game engine? That would be tops.
[/edit]

A

You're more than welcome to have a go at levels although I think we need to create a manual for the editor as it's got quite a lot to it now with destructable blocks, script objects and so on. I'll see if I can knock one up this evening.

This thread might be of interest

- TileTimers only repeat 5 times. You can change this by altering the function runOnLoadScripts() in script.bb
- Players are loaded via the "kind$" param at the end of the player_create function. This gives them classes
- Players are given certain weapons they can carry using flags. So a player with 1+2+4 can carry the first three weapons. A player with 1+32 can carry the lightest and heaviest weapon. These are set in the player_create function.



Here're the updates:

engine.bb (The player_Create has a new param)

btext 40,200,"Creating player/s...":Flip
;Player Initialization - name, x, y, id
Player_Create.player("player2",player_one_start_x,player_one_start_y,1,"light")
;Player_Create.player("player3",player_two_start_x,player_two_start_y,2)

players.bb

; add this to the player type:
Field weaponsAllowed ; flags 1,2,4,8,16,32

; new function
Function allowPlayerToHaveTheseWeapons(p.player,weapons=32) ; 32=all
	If p = Null Then Return
	p\weaponsAllowed =weapons
End Function

;update:
Function Player_Create.player(Name$,X%,Y%,id%,kind$="light")
	Local pl.player = New player
	
	pl\name = Name$
	
	Select Lower(kind)
		Case "light":
			filename$="gfx/player1.png"			
			allowPlayerToHaveTheseWeapons(pl,1+2+4) ; all weapons
			speed#=1.5
			
		Case "medium"
			filename$="gfx/player2.png"
			allowPlayerToHaveTheseWeapons(pl,4+8+16) ; all weapons
			speed#=1.0
			
		Case "heavy"
			filename$="gfx/player2.png"
			allowPlayerToHaveTheseWeapons(pl,8+16+32) ; all weapons
			speed#=0.7			
	End Select	
	
	playergfx(id) = LoadAnimImage(filename,64,64,0,128) : MaskImage playergfx(id),255,0,255
	pl\x = X
	pl\y = Y
	pl\frame = 0
	pl\health = 100
	pl\fpause = 0
	pl\dir = 0
	pl\id = id
	;Ammo stuff
	pl\Clip = 2
	pl\ammo = 15
	pl\lives = 5
	pl\speed=speed
	
	CheckVis(Floor(pl\x/32),Floor(pl\y/32))	
	
	Player(id)=pl
	Return pl
End Function

script.bb

;update:
Type tileTimer
	Field x,y ; map coords to run
	Field time ; in seconds
	Field milli,loops,l
End Type

Function tileTimer(x,y,time,loops=5)
	t.tileTimer=New tileTimer
	t\x=x : t\y=y : t\time=time
	t\milli=MilliSecs()
	t\loops=loops
End Function

;update:
Function handleScriptRunning()
	For i.tileTimer=Each tileTimer
		dcircle(i\x*32,i\y*32,32,255,0,0)
		dtext(i\x*32,i\y*32,i\l+"/"+i\loops)	
		If MilliSecs()-i\milli > (i\time*1000) ; convert to milliseconds (*1000)			
			; do it.
			tile=map(i\x,i\y,LayerObject)
			If tile > 0
				RunScript(First player,objectdef(tile),"onevery",i\x*32,i\y*32); not specific.
				i\milli=MilliSecs() ; reset
				For j=0 To 5
					; if we've got a remove(me) in the script somewhere then delete this
					; tileTimer and stop it from repeating
					; sort of defeats the point of onEvery, but hey...
					If Instr(objectdef(tile)\script[j],"remove")
						Delete i
						Exit
					EndIf
				Next										
			EndIf
			i\l=i\l+1
			If i\l=i\loops				
				puttile(i\x,i\y,LayerObject,0) ; clear object at this location
				Delete i
			EndIf
		EndIf
	Next
End Function

;update:
Function runOnLoadScripts()
	; this is only run once when the map is loaded.
	; it's kept out of map.bb for script compatability reasons.
	For i=0 To 255-1
		For j=0 To 255-1
			tile=map(i,j,LayerObject)
			If tile>0				
				If Instr(objectdef(tile)\trigger,"onload")								
					; run on first player
					;DebugLog "OnLoad running script '"+objectdef(tile)\name+"'"
					RunScript(First player,objectdef(tile),"onload",i*32,j*32); not specific.
				
				ElseIf Instr(objectdef(tile)\trigger,"onevery")
					p=Instr(Lower(objectdef(tile)\trigger),"onevery")
					time=Mid(objectdef(tile)\trigger,p+8,Instr(objectdef(tile)\trigger,")",p+8)-1)					
					tileTimer(i,j,time+Rand(-1,2),5)	; plus add a bit of randomness to the times
					;DebugLog "tile timer created at "+i+","+j+". Duration: "+time+" seconds."
				EndIf
			EndIf
		Next
	Next
End Function

;update:
Function RunScript(pl.player,obj.objdef,trigger$,x,y)
	p=Instr(obj\trigger,trigger)
	n=CountString(Left(obj\trigger,p),"|")
	si.scriptitem=ParseScript(obj\script[n])
	While si<>Null
		Select si\command
			Case "intex"
				IntexMenu(pl):time=MilliSecs()-period
			
			Case "positionplayer"		
				; here we set some global vars ready for when we're created. see engine.bb
				If Int(si\param)=1
					player_one_start_x=x
					player_one_start_y=y
				ElseIf Int(si\param)=2
					player_two_start_x=x
					player_two_start_y=y				
				EndIf				
		
		
			Case "pickupweapon"								
				wee=Int(si\param)
				If wee Then ok=True
				Select wee
					Case 1:
						If (pl\weaponsAllowed And 1)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponBroadhurst))
						Else
							ok=False	
						EndIf
					Case 2:
						If (pl\weaponsAllowed And 2)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponDalton)) 
						Else 
							ok=False
						EndIf
					Case 3:
						If (pl\weaponsAllowed And 4)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponRobinson)) 
						Else 
							ok=False
						EndIf
					Case 4:
						If (pl\weaponsAllowed And 8)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponRyxx)) 
						Else 
							ok=False
						EndIf
					Case 5:
						If (pl\weaponsAllowed And 16)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponStyrling)) 
						Else
							ok=False
						EndIf
					Case 6:
						If (pl\weaponsAllowed And 32)
							giveWeaponToPlayer(pl,getWeaponFromName(weaponImpact)) 
						Else 
							ok=False
						EndIf
				End Select
	
				If ok=False Then 
					; can't pick it up
					DebugLog "can't pick up weapon "+wee
					ClearScriptFrom(si)					
				EndIf

			Case "createalien"				
				Select si\param
					Case "alien":SpawnAlien(x,y,-1,STANDARD_ALIEN)
					Case "hugger":SpawnAlien(x,y,-1,FACE_HUGGER_ALIEN)
				End Select
						
			Case "addammo"
				givePlayerAmmo(pl,Int(si\param$))

			Case "opendoor"
				opendoor(Floor(x/32),Floor(y/32))
				;Update counter for player status
				pl\doors = pl\doors + 1

			Case "checkkey"
			   	If Not keycheck(pl\id,Int(si\param)+2) Then ClearScriptFrom(si):Return

			Case "addkey"
				Pv.pickedup = New pickedup
				Pv\player = pl\id ; allowing for multiple players
				Pv\obj=Int(si\param)+2				

			Case "addcredit" ; TODO: Credits! (done!)
				givePlayerCredits(pl\id,Int(si\param))

			Case "addhealth"				
				pv.pickedup = New pickedup
				pv\player = pl\id ; allowing for multiple players
				pv\obj = 2

			Case "playsoundonce"
				Select si\param
					Case "health_pickup":playoneshot(health_pickup,x,y)
					Case "key_pickup":playoneshot(key_pickup,x,y)
				End Select

			Case "remove"
				If si\param="me" Then puttile(x,y,LayerObject,0)
				If si\param="collision" Then puttile(x,y,LayerCollision,0)
				
			Case "explode"
				explode(x,y)
				
				

			Default:RuntimeError "Unrecognised command : "+si\command

		End Select
		nsi.scriptitem=After si
		Delete si
		si=nsi
	Wend

End Function

Also, I wrote a help file for the editor a while ago. You can find it here: www.3030deathwar.co.uk/downloads/ab/editor.txt

I think that's everything. it's getting a little hard to update as there are bits here and bits there to be changed. I'll be back with more in a few minutes.

Team17! EXCELLENT! You're famous Rob :)
Glad to hear that the lawyers won't be coming out.

I can remember applying for a job at Team17 a few years back but my work must have been crap as I didn't get a reply at all ;)

So when's the 4 player Gauntlet style mode going in?

Enemies need to slide off a bit when they push you up against a wall: once you get stuck your there till death!

Rob, are you looking to recreate the old levels from the games or a whole set of new ones? I admit I only ever played the demo back on the Amiga so I dont know the story or anything.

Im sure I can make something up though.

As a suggestion, if the maps and scripts were self contained files, you could add the files to a directory and the program could scan for a friendly name in the header of each one, then the user could do a "switch data file" and get given a list of available files (games/mod/etc) that are available.

You could even take this as far as letting them skin the menu's, add an animated intro (slideshow with a few sound effects per slide), add more of these small slideshow anims and execute them from the game script language (this will allow the story to progress - for single player modes)

How does it work at the moment (roughly)?

- players are given default weapons upon creation
- Players can die and leave behind a temporary dead body (they fade away) Edit: There used to be a seperate deadbody.bb file but then I realised I could just use your particles..

Re-jig the order in the engine.bb with these bits: The weapons get created before we make the players so we can equip the weapon when we create the players.

btext 40,190,"Clearing VIS...":Flip
ClearVis()


btext 40,200,"Creating Weapons...":Flip
; create the weapons we want in the game
;createWeapon.weapon...
;		...(id,name$,				dmg#,maxclp,aiac,	rate,speed#,bullettype,	frame,s1$="",s2$="",s3$="")
createWeapon(1,weaponBroadhurst,    1.5, 	5, 	25, 	100, 3.0, 	2,			21, "sfx\mgun.mp3", "", "sfx\pistolreload1.mp3")
createWeapon(2,weaponDalton,    	10.0,	1, 	25,  	500, 6.3, 	1,			22, "", "", "")
createWeapon(3,weaponRobinson,  	8.0, 	5, 	25, 	300, 7.6, 	0,			23, "", "", "")
createWeapon(4,weaponRyxx,      	0.4, 	5, 	25, 	100, 3.0, 	-1,			24, "", "", "")
createWeapon(5,weaponStyrling,  	1.5, 	5, 	25, 	100, 3.0, 	3,			25, "", "", "")
createWeapon(6,weaponImpact,    	1.5, 	5, 	25, 	100, 3.0, 	3,			26, "", "", "")




; **************** TEMP BIT ******************
; create 20 aliens in random places
If False
btext 40,210,"Creating aliens...":Flip
For n=1 To 10
	Repeat
		x=Rand(100,2000)
		y=Rand(100,2000)		
	Until gettile(x,y,0)=0 
	spawnalien(x,y,n,Rand(2,3))
Next
EndIf
; ************ End of TEMP BIT ***************


btext 40,220,"Creating Player/s...":Flip
;Player Initialization - name, x, y, id
Player_Create.player("meeeeee",player_one_start_x,player_one_start_y,1,"light")
;Player_Create.player("player3",player_two_start_x,player_two_start_y,2)

Change this bit in players.bb. It gives the player their default weapon depending on their class:

	Select Lower(kind)
		Case "light":
			filename$="gfx/player2.png"			
			allowPlayerToHaveTheseWeapons(pl,1+2+4) ; all weapons
			speed#=1.5
			;default weapon when you start
			giveWeaponToPlayer(pl,getWeaponFromName(weaponBroadhurst))
			
		Case "medium"
			filename$="gfx/player3.png"
			allowPlayerToHaveTheseWeapons(pl,4+8+16) ; all weapons
			speed#=1.0
			giveWeaponToPlayer(pl,getWeaponFromName(weaponRobinson))
			
		Case "heavy"
			filename$="gfx/player3.png"
			allowPlayerToHaveTheseWeapons(pl,8+16+32) ; all weapons
			speed#=0.7			
			giveWeaponToPlayer(pl,getWeaponFromName(weaponRyxx))
	End Select	

add this to the top of the particles.bb

Global dead_body_1 = LoadImage("gfx\body.png"): MaskImage dead_body_1,255,0,255

Update this bit in players.bb->affect health

If p\health =< 0 Then
		; rebirth
		p\health = 100
		p\lives=p\lives-1
		
		DebugLog "player "+p\id+" dies..."
		; create dead body here
		createparticle(p\x,p\y,0,0,5000,0,0,dead_body_1,ImageWidth(dead_body_1)/2,1)
	
		; create death splat *temp*
		n=Rand(20)+5
		For i=1 To n
			d=Rand(359)
			f=Rand(12,15)
			createparticle(p\x,p\y,Sin(d)*2,Cos(d)*2,Rand(10,100),f,f,particles,16)	
		Next
		
		; move then to the start position
		If p=First player
			p\x=player_one_start_x
			p\y=player_one_start_y
		Else
			p\x=player_two_start_x
			p\y=player_two_start_y		
		EndIf
			
		; should we allow the player to keep their weapons or 
		; make their weapons drop onto the floor so they can pick them up?		
		
		; play spinny animation here
		If p\lives=0
			; replaced with end of game bit
			Cls
			Print "End of game"
			WaitKey
			End
		EndIf		
	EndIf	
End Function

Also, you might want to change this in the script.bb->handleRunningScripts functions to only draw when in debugmode

		If debugmode 
			dcircle(i\x*32,i\y*32,32,255,0,0)
			dtext(i\x*32,i\y*32,i\l+"/"+i\loops)	
		EndIf

Big bugger!

It's looking great, but the new player animation never looks like he's facing in the direction you're going.

For example, the screenshot above is obviously facing up from the bullet direction, but he looks like he's facing diagonally up/right.

It's just the way he's holding the gun, richard but I understand your concern.
Rob. Where did you get that beasty? And why? I've already soiled my trousers.

All the models are from polycount, I've emailed the authors to make sure it's ok to use them, I'm sure it'll be fine but it's always good to check these things out.

Richard, the thing is if you're holding a gun from the hip you're going to be side on. Quite frankly when you're playing the game it's not really an issue, the gun should be pointing forward the whole time, but it doesn't look right when you're running. There should be a version of the aninmation for shooting where the gun is pointed straight ahead, it wouldn't be a problem doing it apart from the memory usage for the animations.

I'm not sure what limit we should use really, as in the grand scheme of things with 64mb+ cards we shouldn't worry. Maybe we should think about minimum specs and not go over it.

The big beasty up there is 128x128 x 8 frames x 16 rotations, as a 256 colour png it's 0.5mb which isn't really that much.

So question... do we set a minimum spec? 16mb? 32mb? Discuss.

Oh, I'll upload a new version tomorrow, everything's been a bit hectic this evening as I had to take the cat to the vet!

> So question... do we set a minimum spec?
> 16mb? 32mb? Discuss.

Once the conversion to quads and Blitz3D has been implemented then it will be 128x128 x 8 frames x 1 rotations :)

> take the cat to the vet!

Awwww! Poor puddy cat. Get well soon puss.

What sort of assistance could we ask from Rico? Some more level gfx, sound effects, music?

I have also been thinking about the player firing - Rob, maybe you look at firing animation - re-coil type stuff??

The beast looks awesome!

>> Once the conversion to quads and Blitz3D has been implemented then it will be 128x128 x 8 frames x 1 rotations :)
Enay, the problem with that is the lighting wouldn't work then. I don't think I would ever swap these for quads, I'd be happier swapping them with 3D models.

So the lighting is different in each of the 8 directions? Ah I see exactly what you mean now.

Enay, the sprites are lit from 1 direction (top left), therefore as it turns in all 16 directions the lighting is different.

My cat has to go to the vet too. Because he's stressed (again). And yes, that is for eal, and yes that is their official diagnosis - I have a stressed pussy. ;-)

As for asking for help from Rico - how about the official nod to create a true remake using their original gfx? sfx? music? If so, might that impact on our previous decision to release this as open source (i.e. they might donate us the original gfx, etc if it's closed source?)

And as to the question of levels, I definitely agree with the idea of enabling 'mods', then we can work on an exact remake and our own game based on the original idea (which I think is where we were heading). Or if not us, anyone else can...

I don't think it's possible for us to have exact levels as the original because I think they had some diagonal corridors (if memory serves) and our engine isn't up to the task of that.

Regarding help from Rico he hasn't actually offered anything and quite frankly I don't think we need it. I asked Team17 for help regarding media, maps etc right at the beginning and got nothing back. Now we've got a basic tile set and characters I don't think we need further assistance. I think he was just flattered that people were still insterested in it.

There are plenty of forums available to us for people willing to do mapping, LemonAmiga, Team17, RetroRemakes, BlitzCoder, BlitzBasic, DarkBASIC(?) (maybe get Rico to do one!). So I don't think level creation is going to be a problem, once we've got one or two levels made I think others will pour in.

I think we're in danger of losing sight of what we need to do. We need to concentrate on getting the engine sorted. I've just written the wall collision code so that works properly now.

ToDo:
Editor - Need to make it so we can specify what alien is spawned by alien type number. likewise with respawners.
- The levels need objectives, this would be collect object x, destory object y, go to position z, activate object a. These need to be assigned with boolean type stuff so you'd have something like:

(pick up object x or object y)
and
(destory object v)
and
(gotoposition x,y or gotoposition x-1,y or gotoposition x+1,y)

Something like that anyway.
This stuff needs to be implemented into the game itself too (obviously). Once we've got this stuff in I think we're very close to a game. You will have a level, with bad guys, pick ups, and objectives. That sounds very much like a game to me. Then all you need to do is multiply the level count by several.

Something that has been said is the non-linear approach would be really good, so maybe have the choosing of the level done by having an outside scene where you can enter different buildings (like tower assault)

Intex systems need to be looked at too, although I think this is going to be pretty simple. And of course a front end needs to be added with redefining keys and such like.

I think this is enough for one post.

This evening I'll grab all the code of this thread, I've got a fair few updates I've added on my computer too. Then we'll have a fresh code and gfx zip for everyone to enjoy!

Just noticed a bunch of hits to my site coming from remakes.org... Anyway... On their front page about half way down there is this bit of news...OK, not strictly accuarate, but there it is!

Heh. Cool. But there's only you Rob with the mental illusion ;)
Heheh. BAPS!

Am looking at setting up an online todo list to track what's left, and who's doing what. My (admittedly slightly crappy) Lycos account allows PHP and MySQL, and am looking at some SourceForge ToDoLists...

By the way, gfx.zip just downloaded as a broken archive - you in the middle of updating rob?

Ah yes, that'd be why! (crosspost)

Speaking of sourceforge still had no word back :(

Agree on the death thing, just die once, people are gonna save and reload most times that they die, and it doesn't make contextual sense if we have any kind of RPG elements - even just the basic inventory of weapons keys. Lives is a bit of an arcade hangover that most games can (and should do without).

On that note, we'll need save and load functions sometime soon (although the map structure is in place, and unlikely to change now, we probably need to think a bit more about player structures and inventories / progress in each level, etc.). Also, should we allow saving at any point, or just at the start of a level, or at any intex system, or...? I quite like the idea of just auto-saving when you start a new level.

When doing the save/load, we must make it very easy and quick to reload the last saved game (I hate having to wait for a reload, it really prevents you from staying immersed in the game).

On non-linearity
================
How about: On starting the game (and loading), you see a world map (the image is defined per game module). Available locations appear on this map, and you can choose where to go. Different locations take you a start level, which then is a linear progression of any number of levels. Finding stuff in the levels can then unlock other levels on the map.

This gives the benefits of non-linearity (choice of order to do things, ability to try something else if you get stuck), but without having to worry too much about it when building a 'location' which may consist of 5 levels which you make your way through in a largely linear fashion. Obviously player classes, etc will allow a limited amount of non-linearity within a location (i.e. different solutions to same problem), but essentially they remain linear. Never played tower assault (I know, I know!), so don't know if that's close?

Also, this structure might have an impact on our save/load options - we could restrict saving / loading to only be on the world map, and partial progress in individual locations is NOT remembered, just completion of locations. On death in a level, we simply reset the entire level back to it's original state. It's a simple approach, but makes our save function dead easy...

[snipped another crosspost re: todo lists and sourceforge tasks]

Okay, I've set up "todolist.php" on my site. I've only had a quick play, but it looks okay.

TODO

Feel free to add it to the top post, although better hosting may be in order if we want to use it in anger (get rid of those adverts!). But again, if we do get sourceforge hosting, we may not need it.

UserIDs.
robfarley, Rims, Perturbatio, Matt, Rico, ENAY

Passwords are that four letter word that Rob is so fond of...please change it once you are in, and set up your email if you want notifications. There are two separate projects: Engine & Editor. Go ahead and create all the tasks we can think of!

Anyone else want access?

The todo list is good! Simple, but fine, although I already appear to have added 2 tasks to one thing :(

Bah, never mind! It's a darn sight better than what we've got!

Can you add a user of No-One so tasks can be added unassigned to anyone so people can just pick them up?

Also is there a way to make it so there is a view only version that just shows what's outstanding for Joe Public to look at?

why not just add a read-only user so us spectators can be nosey?

If not, can I be nosey anyway?

:)

To be honest I didn't have any time to play with it. I kind of assumed tasks could be left unassigned - if not, then sure, I'll add a no-one.

I don't think there's a read-only mode, however I know a bit of PHP / MySQL, so I'll try to knock up a simple read-only task list view for anyone to view tonight.

A Mr Unassigned Task has been created.

IDEAS:

Loads/Save, I think should just be at the beginning/end of levels it'll make life loads easier.

Editor: Definately each level needs to hold a slide show type thing (as andy said) and what levels it unlocks once that one is complete.

Non-Linear: If you always start on level one, everyone has to do that, then level one unlocks levels 2,4,6 say which you can then choose from, level 2 once complete unlocks 3,5 and level 4 unlocks 5... etc etc, this way you can work your way through the levels in certain orders but give it some kind of story so you don't have to do all the levels say, and you can choose what order you do them in to a certain extent. Dicuss...

Guys,

Been working a little on getting more of the intex working. Rob, I have sent you an email with a new font to try.

So update the following:

Add:

Players.bb

Function DrawMapPlan()
 	For p.player=Each player
		If p = First player Then xx=p\x/32:yy=p\y/32
	Next
		
	For x=-80 To 80
		For y=-64 To 64
			If x+xx>-1 And x+xx<256 And y+yy>-1 And y+yy<256
				If map(x+xx,y+yy,LayerCollision)>0 And map(x+xx,y+yy,layer_visible)>0
					If map(x+xx,y+yy,LayerCollision)=czVisDynamic 
						; dynamic
						Color 100,200,100
					Else
					 	; static
					 	Color 0,20,0
					EndIf		 
					
					Rect 320+(x*2),240+(y*2),2,2
				EndIf
			EndIf
		Next
 	Next

	c=255
 	For p.player=Each player
		If p = First player Then Color c,0,0 Else Color 0,0,c
		Rect 320+((xx-(Floor(p\x/32)))*2),240+((yy-(Floor(p\y/32)))*2),2,2
		c=c-1
		If c=150 Then c=255
	Next
		
End Function

Update:

;Function handleBullets() - Weapons.bb

			For al.alien = Each alien
				If ImagesCollide(bulletgfx,b\x,b\y,1,		al\image,al\x-al\offset,al\y-al\offset,al\dir)
				;circlesoverlap(al\x,al\y,al\radius,bx+16,by+16,3)
					
					killed = alien_hit(al,b\damage)
					If killed = True And b\scenary<>1 Then
						;Update counter for player status
						b\owner\kills = b\owner\kills + 1

					End If
					ok=False ;bullet hit alien
					
					
				EndIf
			Next

Update:

	;Function Runscript - script.bb
			
			Case "addhealth"				
				;Give health to player
				Player_GiveHealth(pl, si\param)
[/code]

Replace - Intex-New.bb
[code]
;Images 
Global intexBackground = LoadImage("gfx\intexbg.png")
Global intexFrame = LoadImage("gfx\intex-frame.png")
Global intexText = LoadAnimImage("gfx\intex-text-sm4.png",8,10,0,41)
MaskImage intexText,255,0,255
;Global intexWeapon = LoadAnimImage("gfx\intex-weapons.png",320,88,0,6)
;MaskImage intexWeapon,255,0,255

Global bfont = LoadAnimImage("gfx\bitfnt.png",5,5,0,100)

Function btext(x,y,t$,hcentre=False,vcentre=False)
	If hcentre Then x=x-(Len(t)*3)
	If vcentre Then y=y-3
	For n=1 To Len(t)
		DrawImage bfont,x,y,Asc(Mid(t,n,1))-32
		x=x+6
	Next
End Function

Global intexChars$ = "*ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:?!"
Const pauseMax = 75
Const maxLines = 20
Const draw_char_delay_time=5

Const charWidth = 7
Const xOffset = 160
Const yOffset = 112

Type MenuSystem
	Field id
	Field build
	Field bChar
	Field bLine
	Field menuText$[maxLines]
	Field x[maxLines]
	Field y[maxLines]
	Field subMenu[maxLines]
	Field highlight[maxLines]
	Field total
	Field pauseCounter
	Field cursorRow
	Field cursorX
	Field cursorY
	Field bCharCounter
	
End Type

Global intexMenu.MenuSystem
Global gotr
Global gotg
Global gotb

Function GetRGB(image_name,x,y)
	argb=ReadPixelFast(x,y,ImageBuffer(image_name))
	gotr=(ARGB Shr 16) And $ff 
	gotg=(ARGB Shr 8) And $ff 
	gotb=ARGB And $ff
End Function


Function WriteRGB(image_name,x,y,red,green,blue)
	argb=(blue Or (green Shl 8) Or (red Shl 16) Or ($ff000000))
	WritePixelFast x,y,argb,ImageBuffer(image_name)
End Function

Function halfbright(source1,x1,y1,bias#)
	result = CreateImage(ImageWidth(source1),ImageHeight(source1))
	source2 = CreateImage(ImageWidth(source1),ImageHeight(source1))
	GrabImage source2,x1,y1	
	LockBuffer ImageBuffer(source1)
	LockBuffer ImageBuffer(source2)
	LockBuffer ImageBuffer(result)
	
	For x=0 To ImageWidth(source1)-1
		For y=0 To ImageHeight(source1)-1
		
			GetRGB(source1,x,y)
			r1#=gotr
			g1#=gotg
			b1#=gotb
			
			GetRGB(source2,x,y)
			r2#=gotr
			g2#=gotg
			b2#=gotb
			
			r3#=(r1*bias)+(r2*(1-bias))
			g3#=(g1*bias)+(g2*(1-bias))
			b3#=(b1*bias)+(b2*(1-bias))
			
			WriteRGB(result,x,y,r3,g3,b3)
			
		Next
	Next
	
	UnlockBuffer ImageBuffer(source1)
	UnlockBuffer ImageBuffer(source2)
	UnlockBuffer ImageBuffer(result)
	
	Return result
End Function
		


Function IntexMenu(pl.player)
	Local currentMenu = 0
	Local exitMenu = False
	Local preBootCounter = 0
	Local menuUpdateCounter
	
	;Create a menu store
	intexMenu.MenuSystem = New MenuSystem
	
	;Get the boot text
	GetMenuText(currentMenu,pl)
	
	ibg = halfbright(intexbackground,xoffset,yoffset,.8)
	
	
	While Not exitMenu = True
		;Set buffer
		SetBuffer BackBuffer()
		
		;Draw
		DrawBlock intexFrame,xOffset-15,yOffset-12
		DrawBlock ibg,xOffset,yOffset 
			
		;Drawtext
		ProcessMenuText(pl)
		
		;Individual menu functions
		If intexMenu\build = False Or currentMenu = 11 Then
			Select currentMenu
				Case 0	;Intex Boot
					;Set menu to Main Menu 
					currentMenu = 1
					GetMenuText(currentMenu,pl)

				Case 1,2,3	;Main Menu
					DrawImage intexText,32+xOffset,intexMenu\y[intexMenu\highlight[intexMenu\cursorRow]], 0
					
					;Menu Up/Down
					If menuUpdateCounter = 0 Then
						If control(pUp,pl\id) And intexMenu\cursorRow > 1 Then
							intexMenu\cursorRow = intexMenu\cursorRow - 1
							menuUpdateCounter = 10
							
						ElseIf control(pDown,pl\id) And intexMenu\highlight[intexMenu\cursorRow + 1] <> 0 Then
							intexMenu\cursorRow = intexMenu\cursorRow + 1
							menuUpdateCounter = 10
							
						End If
						
					Else
						;Control the speed of the menu movement
						If menuUpdateCounter > 0 Then
							menuUpdateCounter = menuUpdateCounter - 1
						
						End If
						
					End If
					
					;Menu select
					If control(pfire1,pl\id) And intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]] > 0 Then
						currentMenu = intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]]
						GetMenuText(currentMenu,pl)
						
					End If
					
				Case 4	;Radar Service
					DrawMapPlan()
					
					If control(pfire1,pl\id) Then
						currentMenu = 1
						GetMenuText(currentMenu,pl)
						
					End If
										
				Case 7
					If control(pfire1,pl\id) Then
						;Return to main menu
						currentMenu = 1
						GetMenuText(currentMenu,pl)
						
					End If
										
				Case 10	;Disconnect
					exitMenu = True
							
			End Select
			
		End If
		
		;Draw
		Flip True
		
	Wend
	
	;Clear keys
	FlushKeys()
	
	;Tidyup
	Delete Each menuSystem
	
End Function

Function GetMenuText(menu, pl.player)
	Local totalLines, lines
	Local lineText$, x, y, subMenu, max
	Local highlight
	
	;Wait until no fire keys
	While control(pfire1, pl\id)
		
	Wend
	
	;Set remaining fields
	intexMenu\build = True
	intexMenu\bChar = 0
	intexMenu\bLine = 1
	intexMenu\id = menu
	intexMenu\pauseCounter = 0
	intexMenu\cursorRow = 1
	intexMenu\bCharCounter = 0
	
	Select menu
		Case 0	;Intex Boot
			Restore menuIntexBoot
			
		Case 1	;Menu
			Restore menuIntexMain

		Case 2	;Weapon Supplies
			Restore menuIntexWeaponsSupply
			
		Case 3	;Tool Supplies
			Restore menuIntexToolSupply
			
		Case 4	;Radar Service
			Restore menuIntexRadarService
			;intexMenu\build = False
			
		Case 7	;Statistics
			Restore menuIntexStatistics
			
		Case 10	;Disconnect
			Restore menuIntexDisconnect
			
	End Select
	
	;Clear
	For lines = 1 To maxLines
		intexMenu\highlight[lines] = 0
		intexMenu\menuText$[lines] = ""
		
	Next
	
	;Process the data?
	If intexmenu\build = True Then
		;Read the data
		Read totalLines
		
		For lines = 1 To totalLines
			Read lineText, x, y, subMenu, highlight
			intexMenu\menuText$[lines] = UpdateTags(Upper(lineText), pl)
			intexMenu\x[lines] = x + xOffset
			intexMenu\y[lines] = y + yOffset
			intexMenu\subMenu[lines] = subMenu
			
			;Set line selection
			If highlight <> -1 Then
				intexMenu\highlight[highlight] = Lines
				
			End If
			
		Next

		;Set remaining fields
		intexMenu\total = totalLines + 1
	
	End If
	
	;Clear keys
	FlushKeys()

End Function

Function UpdateTags$(lineText$, pl.player)
	;Update tags
	lineText = Replace(lineText,"%PLSCORE%",LSet(pl\score,6))
	lineText = Replace(lineText,"%PLKILLS%",pl\kills)
	;lineText = Replace(lineText,"%PLCREDITS%",LSet(pl\credits,6))
	;lineText = Replace(lineText,"%PLSHOTS%",LSet(pl\shots,6))
	;lineText = Replace(lineText,"%PLDOORS%",LSet(pl\doors,6))
	;lineText = Replace(lineText,"%PLAMMO%",LSet(pl\clip,6))
	lineText = Replace(lineText,"%PLCREDITS%",pl\credits)
	lineText = Replace(lineText,"%PLSHOTS%",pl\shots)
	lineText = Replace(lineText,"%PLDOORS%",pl\doors)
	lineText = Replace(lineText,"%PLAMMO%",pl\clip)
	lineText = Replace(lineText,"%PLENERGY%","GOOD")
	lineText = Replace(lineText,"%PLCURRENTWEAPON%",Upper(pl\weapon\name))	;Current
	lineText = Replace(lineText,"%WBROADHURST%",WeaponStatus(pl\ownedWeapons[1]))
	lineText = Replace(lineText,"%WDALTON%",WeaponStatus(pl\ownedWeapons[2]))
	lineText = Replace(lineText,"%WROBINSON%",WeaponStatus(pl\ownedWeapons[3]))
	lineText = Replace(lineText,"%WRYXX%",WeaponStatus(pl\ownedWeapons[4]))
	lineText = Replace(lineText,"%WSTYRLING%",WeaponStatus(pl\ownedWeapons[5]))
	lineText = Replace(lineText,"%WIMPACT%",WeaponStatus(pl\ownedWeapons[6]))

	;Return
	Return lineText
	
End Function

Function WeaponStatus$(wp.weapon)
	If wp<>Null Then
		Return "YES"
		
	End If
	Return " NO"
End Function

Function ProcessMenuText(pl.player)
	Local currentChar$,x,y,maxChar,char
	Local charCounter = 0
	Local drawCursor = False
	Local finishProcess = False
	
	If intexMenu\build Then
		If intexMenu\bChar > 0 Then
			;Get the current char
			Repeat
				currentChar = Mid(intexMenu\menuText[intexMenu\bLine],intexMenu\bChar,1)
				If currentChar = " " And intexMenu\bChar < Len(intexMenu\menuText[intexMenu\bLine]) - 1 Then
					;Skip over any spaces
					intexMenu\bCharCounter = intexMenu\bCharCounter + 1
					intexMenu\bChar = intexMenu\bChar + 1
					
				ElseIf currentChar = "+" Then
					;We need to pause
					intexMenu\pauseCounter = (intexMenu\pauseCounter +1) Mod pauseMax
				    Exit
				    
				Else
					;Exit out
					Exit
					
			    End If
			    			    
		    Forever
			
		End If
		
		;Continue to process text
		If intexMenu\pauseCounter = 0 Then
			;Increment number of shown characters
			intexMenu\bCharCounter = intexMenu\bCharCounter + 1
			
			;Increment char
			intexMenu\bChar = (intexMenu\bChar + 1) Mod Len(intexMenu\menuText[intexMenu\bLine])
			If intexMenu\bChar = 0 Then
				;Increment line
				intexMenu\bLine = (intexMenu\bLine + 1) Mod intexMenu\total
				If intexMenu\bLine = 0 Then
					finishProcess = True
					
				End If
				
			End If
			
		End If
		
		;Speed up menu process (fire key) - temp?
		If KeyDown(1) Then
			finishProcess = True
	
		End If
		
		;Finish?
		If finishProcess Then
			;Set each item to it's max
			intexMenu\bLine = intexMenu\total - 1
			intexMenu\bChar = Len(intexMenu\menuText[intexMenu\bLine])
			
			;Finish
			intexMenu\build = False
			FlushKeys()
			
		End If

	End If
	
	;Draw text
	For drawLine = 1 To intexMenu\bLine
		;Set co-ords for current line
		x = intexMenu\x[drawLine]
		y = intexMenu\y[drawLine]
			
		;Draw current line
		For drawChar = 1 To Len(intexMenu\menuText[drawLine])
			;Increment letter count
			charCounter = charCounter + 1
			
			;Get current char
			char = Instr(intexChars, Mid(intexMenu\menuText[drawLine],drawChar,1)) - 1
			If char > -1 Then
				DrawImage intexText,x,y,char
			
			End If
			
			;Building the menu, if so pause on last char and display cursor
			If intexMenu\build Then
				;Slight pause when first displaying character?
				If (charCounter = intexMenu\bCharCounter) Then 
					Delay draw_char_delay_time
					intexMenu\cursorX = x
					intexMenu\cursory = y
					drawCursor = True
					Exit
				
				End If
					
			End If
			
			x = x + charWidth
			
		Next
			
		If drawCursor Then
			DrawImage intexText,intexMenu\cursorX,intexMenu\cursorY,0
			Exit
			
		End If
		
	Next
	
End Function

;Data Structure
;No of lines
;Text$,X,Y,SubMenu

.menuIntexBoot
Data 10
Data "INTEX NETWORK CONNECT: CODE ABF01DCC60 ",8,48,-1,-1
Data "CONNECTING..................... ",8,60,-1,-1
Data "INTEX NETWORK SYSTEM V10.0 ",8,84,-1,-1
Data "2G RAM:           OK ",8,96,-1,-1
Data "EXTERNAL DEVICE:  OK ",8,108,-1,-1
Data "SYSTEM V1.10 CS:  OK ",8,120,-1,-1
Data "VIDEODISPLAY:     DAMAGED+ ",8,132,-1,-1
Data "EXECUTING DOS 5.0 ",8,156,-1,-1
Data "SYSTEM DOWNLOADING NETWORKDATA..... OK ",8,168,-1,-1
Data "INTEX EXECUTED!+ ",8,180,-1,-1

.menuIntexMain
Data 8
Data "INTEX MAIN MENU ",96,32,-1,-1
Data "INTEX WEAPON SUPPLIES ",72,68,-1,1
Data "INTEX TOOL SUPPLIES ",80,80,3,2
Data "INTEX RADAR SERVICE ",80,92,4,3
Data "LEVEL INFORMATION UPDATE ",64,104,-1,4
Data "INTEX ENTERTAINMENT ",80,116,-1,5
Data "STATISTICS ",120,128,7,6
Data "EXIT INTEX NETWORK ",88,140,10,7

.menuIntexWeaponsSupply
Data 2
Data "INTEX WEAPON SUPPLIES ",122,24,-1,-1
Data "WEAPON SUPPLIES REQUEST: ",24,48,-1,-1

.menuIntexToolSupply
Data 8
Data "INTEX TOOL SUPPLIES ",80,36,-1,-1
Data "ELECTRONIC HAND MAP        500 CR ",32,72,-1,1 
Data "AMMO NYBBLE               1000 CR ",32,96,-1,2
Data "FIRST AID KIT             2000 CR ",32,120,-1,3
Data "6 KEYS                    4000 CR ",32,144,-1,4
Data "EXTRA LIFE               10000 CR ",32,168,-1,5
Data "EXIT ",144,192,1,6
Data "YOUR CREDIT LIMIT IS: %PLCREDITS% CR ",40,216,-1,-1

.menuIntexRadarService
Data 1
Data "INTEX RADAR SERVICE ",88,36,-1,-1

.menuIntexStatistics
Data 16
Data "INTEX STATISTICS ",96,16,-1,-1
Data " PLAYER SCORES: %PLSCORE% PTS ",16,40,-1,-1
Data " ALIENS KILLED: %PLKILLS% ",16,52,-1,-1
Data "   SHOTS FIRED: %PLSHOTS% BULLETS ",16,64,-1,-1
Data " CREDITS OWNED: %PLCREDITS% CR ",16,76,-1,-1
Data "  DOORS OPENED: %PLDOORS% ",16,88,-1,-1
Data "    AMMO OWNED: %PLAMMO% CLIP",16,100,-1,-1
Data "  ENERGY STATE: %PLENERGY% ",16,112,-1,-1
Data "CURRENT WEAPON: %PLCURRENTWEAPON%",16,124,-1,-1
Data "WEAPONS STATUS: ",16,136,-1,-1
Data weaponBroadhurst + "...  %WBROADHURST% ",40,160,-1,-1		;112
Data weaponDalton + "...            %WDALTON% ",40,172,-1,-1
Data weaponRobinson + "...         %WROBINSON% ",40,184,-1,-1
Data weaponRyxx + "...          %WRYXX% ",40,196,-1,-1
Data weaponStyrling + "...         %WSTYRLING% ",40,208,-1,-1
Data weaponImpact + "...     %WIMPACT% ",40,220,-1,-1

.menuIntexDisconnect
Data 1
Data "DISCONNECTING..............+ ",16,32,-1,-1

This could be done by allowing multiple exit and entry points.
You can simply store the spawn point of another map as the destination.

That sounds like a good idea pert. You could have an overall map that shows how the different levels fall together so you could enter different maps from either side of it for example, that sounds really cool.

Matt, got the email, I'll put your stuff in this evening. What does it all do exactly?!

Rob,

A couple more things in the menu are working and I have been tiding up other stuff. You can now view the 'Radar Service' (map) from the menu.

I will hopefully do a bit more tomorrow night after cricket training. Want to try and get the Tools and Weapon supplies finished. Do we want to buy weapons?

Time for bed

Guns... Lots of guns...

I'll come up with the graphics at some point soon for the weapons, again, I'll download some weapons off polycount and render them for the game.

Sounds good - the gfx are working out really well.

I just updated the code for intex-new.bb again to add a menu to the radar service.

Bye for now!!!

Zips updated:

And so the emails keep on coming...

It's great to see a software house give support to a remake rather than try and close it down!!! Team 17 have always been great

I just had a bash at the latest zips and its all good for alittle while then it drops back to the menu, and once its back at the menu, it doestn let you start a new game or anything.

Is that a known bug?

A

Yes! It drops back to the main menu when you die! And gets stuck there. The structure of the game needs re-arranging for this to work correctly.

We need to do a bit more balancing on how much health loss the aliens inflict etc etc.

Andy,

Rob has justed added that in and has jet to complete it - we need to re-initialise the required objects on the restart. He will probably have an update out soon...

Does anyone like the Intex font? Been having a play the FontText and it seemed to be the nicest one I have done so far.

Um... Actually I preferred the old font Matt... I think the new one looks a bit 80s. Sorry mate.

No worries about the font - just having a play to see if I could squeeze a bit more in. I think we might need to go wide-screen plasma style!!!

Have made a bit more progress on the Intex System (bit more of a tidy also) as you can now go in and buy some of the stuff from the tool supplies - check it out below.

Also with the weapons - I think we need to store the ammo for each weapon separately, which would also mean we need to have a number of different ammo collections - what does everyone think? If so, I will have a look.

Intex-new.bb - replace

;Images 
Global intexBackground = LoadImage("gfx\intexbg.png")
Global intexFrame = LoadImage("gfx\intex-frame.png")
Global intexText = LoadAnimImage("gfx\intex-text-sm4.png",8,10,0,41)
MaskImage intexText,255,0,255
;Global intexWeapon = LoadAnimImage("gfx\intex-weapons.png",320,88,0,6)
;MaskImage intexWeapon,255,0,255

; INTEX
Const intexHandMapCost = 500
Const intexAmmoCost = 1000
Const intexFirstAidCost = 2000
Const intexKeysCost = 4000

Global bfont = LoadAnimImage("gfx\bitfnt.png",5,5,0,100)

Function btext(x,y,t$,hcentre=False,vcentre=False)
	If hcentre Then x=x-(Len(t)*3)
	If vcentre Then y=y-3
	For n=1 To Len(t)
		DrawImage bfont,x,y,Asc(Mid(t,n,1))-32
		x=x+6
	Next
End Function

Global intexChars$ = "*ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:?!"
Const pauseMax = 75
Const maxLines = 20
Const draw_char_delay_time=5

Const charWidth = 7
Const xOffset = 160
Const yOffset = 112

Type MenuSystem
	Field id
	Field build
	Field bChar
	Field bLine
	Field menuText$[maxLines]
	Field x[maxLines]
	Field y[maxLines]
	Field subMenu[maxLines]
	Field highlight[maxLines]
	Field total
	Field pauseCounter
	Field cursorRow
	Field cursorX
	Field cursorY
	Field bCharCounter
	Field selectionCursorShow
	Field selectionCursorX
End Type

Global intexMenu.MenuSystem
Global gotr
Global gotg
Global gotb

Function GetRGB(image_name,x,y)
	argb=ReadPixelFast(x,y,ImageBuffer(image_name))
	gotr=(ARGB Shr 16) And $ff 
	gotg=(ARGB Shr 8) And $ff 
	gotb=ARGB And $ff
End Function


Function WriteRGB(image_name,x,y,red,green,blue)
	argb=(blue Or (green Shl 8) Or (red Shl 16) Or ($ff000000))
	WritePixelFast x,y,argb,ImageBuffer(image_name)
End Function

Function halfbright(source1,x1,y1,bias#)
	result = CreateImage(ImageWidth(source1),ImageHeight(source1))
	source2 = CreateImage(ImageWidth(source1),ImageHeight(source1))
	GrabImage source2,x1,y1	
	LockBuffer ImageBuffer(source1)
	LockBuffer ImageBuffer(source2)
	LockBuffer ImageBuffer(result)
	
	For x=0 To ImageWidth(source1)-1
		For y=0 To ImageHeight(source1)-1
		
			GetRGB(source1,x,y)
			r1#=gotr
			g1#=gotg
			b1#=gotb
			
			GetRGB(source2,x,y)
			r2#=gotr
			g2#=gotg
			b2#=gotb
			
			r3#=(r1*bias)+(r2*(1-bias))
			g3#=(g1*bias)+(g2*(1-bias))
			b3#=(b1*bias)+(b2*(1-bias))
			
			WriteRGB(result,x,y,r3,g3,b3)
			
		Next
	Next
	
	UnlockBuffer ImageBuffer(source1)
	UnlockBuffer ImageBuffer(source2)
	UnlockBuffer ImageBuffer(result)
	
	Return result
End Function
		
Function IntexMenu(pl.player)
	Local currentMenu = 0
	Local exitMenu = False
	Local preBootCounter = 0
	Local menuUpdateCounter
	Local ammoInClip
	
	;Create a menu store
	intexMenu.MenuSystem = New MenuSystem
	
	;Get the boot text
	GetMenuText(currentMenu,pl)
	
	;Set background to lower brightness
	ibg = halfbright(intexbackground,xoffset,yoffset,.8)
	
	While Not exitMenu = True
		;Set buffer
		SetBuffer BackBuffer()
		
		;Draw
		DrawBlock intexFrame,xOffset-15,yOffset-12
		DrawBlock ibg,xOffset,yOffset 
			
		;Individual menu functions
		If intexMenu\build = False Then
			Select currentMenu
				Case 0	;Intex Boot
					;Set menu to Main Menu 
					currentMenu = 1
					GetMenuText(currentMenu,pl)

				Case 4	;Radar Service
					;Draw map 
					DrawMapPlan()
															
				Case 3	;Tool Service
					;Purchase item?
					If control(pfire1,pl\id) Then
						Select intexMenu\cursorRow		;  intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]]
							Case 1
								; Buy map
								
							Case 2
								; Buy Ammo
								If pl\credits > intexAmmoCost Then
									;Decrease credits
									pl\credits = pl\credits - intexAmmoCost
									
									;Update ammo by 2 clips
									givePlayerAmmo(pl,pl\weapon\ammo_in_a_clip * 2)
									
									;Reset menu for new credits
									GetMenuText(currentMenu,pl,False)
									
								End If
								
							Case 3								
								; Buy first aid
								If pl\credits > intexFirstAidCost Then
									;Decrease credits
									pl\credits = pl\credits - intexFirstAidCost
									
									;Update health to max
									Player_GiveHealth(pl,100)
									
									;Reset menu for new credits
									GetMenuText(currentMenu,pl,False)
									
								End If
								
							Case 4
								;Buy keys
								
						End Select
						
						;Clear key press
						;FlushKeys()
						
					End If
										
				Case 10	;Disconnect
					exitMenu = True
							
			End Select
			
		End If

		;Drawtext
		ProcessMenuText(pl)
		
		;Menu select
		If intexmenu\build = False Then
			;Fire
			If control(pfire1,pl\id) Then
				;Determine where to go
				If intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]] > 0 Then
					;Get menu to activate
					currentMenu = intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]]
					GetMenuText(currentMenu,pl)
					
				ElseIf intexmenu\selectionCursorShow = False Then					
					;Return to main menu
					currentMenu = 1	
					GetMenuText(currentMenu,pl)
					
				End If
				
			End If
	
			;Update cursor position
			If intexmenu\selectionCursorShow = True Then
				;Menu Up/Down
				If menuUpdateCounter = 0 Then
					If control(pUp,pl\id) And intexMenu\cursorRow > 1 Then
						intexMenu\cursorRow = intexMenu\cursorRow - 1
						menuUpdateCounter = 10
						
					ElseIf control(pDown,pl\id) And intexMenu\highlight[intexMenu\cursorRow + 1] <> 0 Then
						intexMenu\cursorRow = intexMenu\cursorRow + 1
						menuUpdateCounter = 10
						
					End If
					
				Else
					;Control the speed of the menu movement
					If menuUpdateCounter > 0 Then
						menuUpdateCounter = menuUpdateCounter - 1
					
					End If
					
				End If
	
				;Show selection cursor
				DrawImage intexText,intexmenu\selectionCursorX,intexMenu\y[intexMenu\highlight[intexMenu\cursorRow]], 0
	
			End If
	
		End If
		
		;Draw
		Flip True
		
	Wend
	
	;Clear keys
	FlushKeys()
	
	;Tidyup
	Delete Each menuSystem
	
End Function

Function GetMenuText(menu, pl.player,reset=True)
	Local totalLines, lines
	Local lineText$, x, y, subMenu, max
	Local highlight
	Local selectionCursorOn, selectionCursorX
	
	;Wait until no fire keys pressed
	While control(pfire1, pl\id)
	Wend
	
	;Set fields
	If reset = True Then
		intexMenu\build = True
		intexMenu\bChar = 0
		intexMenu\bLine = 1
		intexMenu\id = menu
		intexMenu\pauseCounter = 0
		intexMenu\cursorRow = 1
		intexMenu\bCharCounter = 0
		
	End If
	
	Select menu
		Case 0	;Intex Boot
			Restore menuIntexBoot
			
		Case 1	;Menu
			Restore menuIntexMain

		Case 2	;Weapon Supplies
			Restore menuIntexWeaponsSupply
			
		Case 3	;Tool Supplies
			Restore menuIntexToolSupply
			
		Case 4	;Radar Service
			Restore menuIntexRadarService
			
		Case 7	;Statistics
			Restore menuIntexStatistics
			
		Case 10	;Disconnect
			Restore menuIntexDisconnect
			
	End Select
	
	;Clear
	For lines = 1 To maxLines
		intexMenu\highlight[lines] = 0
		intexMenu\menuText$[lines] = ""
		
	Next
	
	;Read the data
	Read totalLines
	
	;Selection cursor
	Read selectionCursorOn, selectionCursorX
	intexmenu\selectionCursorShow = selectionCursorOn
	intexmenu\selectionCursorX = selectionCursorX + xOffset
	
	For lines = 1 To totalLines
		Read lineText, x, y, subMenu, highlight
		intexMenu\menuText$[lines] = UpdateTags(Upper(lineText), pl)
		intexMenu\x[lines] = x + xOffset
		intexMenu\y[lines] = y + yOffset
		intexMenu\subMenu[lines] = subMenu
		
		;Set line selection
		If highlight <> -1 Then
			intexMenu\highlight[highlight] = Lines
			
		End If
		
	Next

	;Set remaining fields
	intexMenu\total = totalLines + 1
		
	;Clear keys
	FlushKeys()

End Function

Function UpdateTags$(lineText$, pl.player)
	;Update tags
	lineText = Replace(lineText,"%PLSCORE%",LSet(pl\score,6))
	lineText = Replace(lineText,"%PLKILLS%",pl\kills)
	lineText = Replace(lineText,"%CVHANDMAP%",RSet(intexHandMapCost,5))
	lineText = Replace(lineText,"%CVAMMO%",RSet(intexAmmoCost,5))
	lineText = Replace(lineText,"%CVFIRSTAID%",RSet(intexFirstAidCost,5))
	lineText = Replace(lineText,"%CVKEYS%",RSet(intexKeysCost,5))
	lineText = Replace(lineText,"%PLCREDITS%",pl\credits)
	lineText = Replace(lineText,"%PLSHOTS%",pl\shots)
	lineText = Replace(lineText,"%PLDOORS%",pl\doors)
	lineText = Replace(lineText,"%PLAMMO%",pl\clip)
	lineText = Replace(lineText,"%PLENERGY%","GOOD")
	lineText = Replace(lineText,"%PLCURRENTWEAPON%",Upper(pl\weapon\name))	;Current
	lineText = Replace(lineText,"%WP1NAME%",LSet(WeaponName(1)+"...",29))
	lineText = Replace(lineText,"%WP2NAME%",LSet(WeaponName(2)+"...",29))
	lineText = Replace(lineText,"%WP3NAME%",LSet(WeaponName(3)+"...",29))
	lineText = Replace(lineText,"%WP4NAME%",LSet(WeaponName(4)+"...",29))
	lineText = Replace(lineText,"%WP5NAME%",LSet(WeaponName(5)+"...",29))
	lineText = Replace(lineText,"%WP6NAME%",LSet(WeaponName(6)+"...",29))
	lineText = Replace(lineText,"%WP1STATUS%",WeaponStatus(pl\ownedWeapons[1]))
	lineText = Replace(lineText,"%WP2STATUS%",WeaponStatus(pl\ownedWeapons[2]))
	lineText = Replace(lineText,"%WP3STATUS%",WeaponStatus(pl\ownedWeapons[3]))
	lineText = Replace(lineText,"%WP4STATUS%",WeaponStatus(pl\ownedWeapons[4]))
	lineText = Replace(lineText,"%WP5STATUS%",WeaponStatus(pl\ownedWeapons[5]))
	lineText = Replace(lineText,"%WP6STATUS%",WeaponStatus(pl\ownedWeapons[6]))

	;Return
	Return lineText
	
End Function

Function WeaponStatus$(wp.weapon)
	If wp<>Null Then
		Return "YES"
		
	End If
	Return " NO"
End Function

Function WeaponName$(id)
	For wp.weapon = Each weapon
		If wp\id = id Then
			Return Upper(wp\name)
			
		End If
				
	Next
	
End Function

Function ProcessMenuText(pl.player)
	Local currentChar$,x,y,maxChar,char
	Local charCounter = 0
	Local drawCursor = False
	Local finishProcess = False
	
	If intexMenu\build Then
		If intexMenu\bChar > 0 Then
			;Get the current char
			Repeat
				currentChar = Mid(intexMenu\menuText[intexMenu\bLine],intexMenu\bChar,1)
				If currentChar = " " And intexMenu\bChar < Len(intexMenu\menuText[intexMenu\bLine]) - 1 Then
					;Skip over any spaces
					intexMenu\bCharCounter = intexMenu\bCharCounter + 1
					intexMenu\bChar = intexMenu\bChar + 1
					
				ElseIf currentChar = "+" Then
					;We need to pause
					intexMenu\pauseCounter = (intexMenu\pauseCounter +1) Mod pauseMax
				    Exit
				    
				Else
					;Exit out
					Exit
					
			    End If
			    			    
		    Forever
			
		End If
		
		;Continue to process text
		If intexMenu\pauseCounter = 0 Then
			;Increment number of shown characters
			intexMenu\bCharCounter = intexMenu\bCharCounter + 1
			
			;Increment char
			intexMenu\bChar = (intexMenu\bChar + 1) Mod Len(intexMenu\menuText[intexMenu\bLine])
			If intexMenu\bChar = 0 Then
				;Increment line
				intexMenu\bLine = (intexMenu\bLine + 1) Mod intexMenu\total
				If intexMenu\bLine = 0 Then
					finishProcess = True
					
				End If
				
			End If
			
		End If
		
		;Speed up menu process (fire key) - temp?
		If KeyDown(1) Then
			finishProcess = True
	
		End If
		
		;Finish?
		If finishProcess Then
			;Set each item to it's max
			intexMenu\bLine = intexMenu\total - 1
			intexMenu\bChar = Len(intexMenu\menuText[intexMenu\bLine])
			
			;Finish
			intexMenu\build = False
			FlushKeys()
			
		End If

	End If
	
	;Draw text
	For drawLine = 1 To intexMenu\bLine
		;Set co-ords for current line
		x = intexMenu\x[drawLine]
		y = intexMenu\y[drawLine]
			
		;Draw current line
		For drawChar = 1 To Len(intexMenu\menuText[drawLine])
			;Increment letter count
			charCounter = charCounter + 1
			
			;Get current char
			char = Instr(intexChars, Mid(intexMenu\menuText[drawLine],drawChar,1)) - 1
			If char > -1 Then
				DrawImage intexText,x,y,char
			
			End If
			
			;Building the menu, if so pause on last char and display cursor
			If intexMenu\build Then
				;Slight pause when first displaying character?
				If (charCounter = intexMenu\bCharCounter) Then 
					Delay draw_char_delay_time
					intexMenu\cursorX = x
					intexMenu\cursory = y
					drawCursor = True
					Exit
				
				End If
					
			End If
			
			;Increment
			x = x + charWidth
			
		Next
			
		;Display cursor position?
		If drawCursor Then
			DrawImage intexText,intexMenu\cursorX,intexMenu\cursorY,0
			Exit
			
		End If
		
	Next
	
End Function

;Data Structure
;No of lines
;Show Cursor,CursorXPos
;Text$,X,Y,SubMenu,Position

.menuIntexBoot
Data 10
Data False,-1
Data "INTEX NETWORK CONNECT: CODE ABF01DCC60 ",8,48,-1,-1
Data "CONNECTING..................... ",8,60,-1,-1
Data "INTEX NETWORK SYSTEM V10.0 ",8,84,-1,-1
Data "2G RAM:           OK ",8,96,-1,-1
Data "EXTERNAL DEVICE:  OK ",8,108,-1,-1
Data "SYSTEM V1.10 CS:  OK ",8,120,-1,-1
Data "VIDEODISPLAY:     DAMAGED+ ",8,132,-1,-1
Data "EXECUTING DOS 5.0 ",8,156,-1,-1
Data "SYSTEM DOWNLOADING NETWORKDATA..... OK ",8,168,-1,-1
Data "INTEX EXECUTED!+ ",8,180,-1,-1

.menuIntexMain
Data 8
Data True,32
Data "INTEX MAIN MENU ",96,32,-1,-1
Data "INTEX WEAPON SUPPLIES ",72,68,-1,1
Data "INTEX TOOL SUPPLIES ",80,80,3,2
Data "INTEX RADAR SERVICE ",80,92,4,3
Data "LEVEL INFORMATION UPDATE ",64,104,-1,4
Data "INTEX ENTERTAINMENT ",80,116,-1,5
Data "STATISTICS ",120,128,7,6
Data "EXIT INTEX NETWORK ",88,140,10,7

.menuIntexWeaponsSupply
Data 2
Data True,32
Data "INTEX WEAPON SUPPLIES ",122,24,-1,-1
Data "WEAPON SUPPLIES REQUEST: ",24,48,-1,-1

.menuIntexToolSupply
Data 7
Data True,24
Data "INTEX TOOL SUPPLIES ",88,36,-1,-1
Data "ELECTRONIC HAND MAP       %CVHANDMAP% CR ",40,72,-1,1 
Data "AMMO NYBBLE               %CVAMMO% CR ",40,96,-1,2
Data "FIRST AID KIT             %CVFIRSTAID% CR ",40,120,-1,3
Data "6 KEYS                    %CVKEYS% CR ",40,144,-1,4
Data "EXIT ",144,192,1,5
Data "YOUR CREDIT LIMIT IS: %PLCREDITS% CR ",40,216,-1,-1

.menuIntexRadarService
Data 1
Data False,-1
Data "INTEX RADAR SERVICE ",88,32,-1,-1

.menuIntexStatistics
Data 16
Data False,-1
Data "INTEX STATISTICS ",96,16,-1,-1
Data " PLAYER SCORES: %PLSCORE% PTS ",16,40,-1,-1
Data " ALIENS KILLED: %PLKILLS% ",16,52,-1,-1
Data "   SHOTS FIRED: %PLSHOTS% BULLETS ",16,64,-1,-1
Data " CREDITS OWNED: %PLCREDITS% CR ",16,76,-1,-1
Data "  DOORS OPENED: %PLDOORS% ",16,88,-1,-1
Data "    AMMO OWNED: %PLAMMO% CLIP",16,100,-1,-1
Data "  ENERGY STATE: %PLENERGY% ",16,112,-1,-1
Data "CURRENT WEAPON: %PLCURRENTWEAPON%",16,124,-1,-1
Data "WEAPONS STATUS: ",16,136,-1,-1
Data "%WP1NAME%  %WP1STATUS% ",40,160,-1,-1
Data "%WP2NAME%  %WP2STATUS% ",40,172,-1,-1
Data "%WP3NAME%  %WP3STATUS% ",40,184,-1,-1
Data "%WP4NAME%  %WP4STATUS% ",40,196,-1,-1
Data "%WP5NAME%  %WP5STATUS% ",40,208,-1,-1
Data "%WP6NAME%  %WP6STATUS% ",40,220,-1,-1

.menuIntexDisconnect
Data 1
Data False,-1
Data "DISCONNECTING..............+ ",16,32,-1,-1

Function Player_Create.player add:

	pl\credits = 20000

I totally agree! I'll take a look at the new intex this evening when I get home. Regarding making it a different shape, that's no problem at all. Change the size of the intexbg.png image and intexframe and the halfbright function will just work as it picks up the size of the intexbg image.

I'll take a look at the weapons over the weekend. And I'll go back to the AB Intex font and extend it out a little.

I really like that halfbright function!

Yeah I like it too... Not sure how well it'll handle on lower spec machines as it's pretty intensive, I'm sure we'll find out soon enough!

Have you got any timing code on the intex systems yet? I found that on my work PC the more letters on the screen that appeared the slower it got.

Something else I've just thought of editor-wise:

There should be a sort of compile option that takes a look at all the aliens in the level and when it's loaded into the game only those aliens are loaded. Just a little optimisation.

And, a thought... Should we have a multiple tile sets?

Maybe have a tileset for the transparant layers (detail and over) and a different set for the base layer. I just think this will make the tilesets more manageable.
The only problem I can forsee is working out what tile set you're using on each square... would you set the tileset for the entire level or would you set it per tile? If it were set per tile it would mean an extra layer to describe what tileset you're using. Per level would be much easier.
It just means if we have different themed levels you could set the different base tileset...? Discuss.

I suspect we're going to need a whole bunch of extra level data in addition to the map structure. I suggest that for now we create a further file level.lvl (to go with level.map and level.obj) that can contain all this stuff. Things like which tileset to use (I suggest we do define it once per level), completion criteria, intro graphic (movie?), intro text, whatever.

Once all the file formats are settled we can then compile these back up into a single file (with simple encryption to stop cheats rather than hackers). Or possibly all levels in to a single data pack...

One point for Matt (and anyone else), please use the codebox tag when posting large chunks of code, not the code tag. this will give you code in a smaller scrolly, and prevent oversized web pages! Ta!

Oh, and damned nice to get an email from Martyn Brown. I always liked their stuff on the 'miggy. *misty eyes*

Zips updated.

I've set up a basic framework for the players, each player has their own directory for holding their sounds, graphics and player info (Should probably set something like this up for the aliens too). The player info and sounds isn't in yet but the way I plan to use it is there will be a txt file or something similar that holds the player speed, weapons they can hold, how much damage aliens inflict on them (effectively how strong they are), their max health and so on, we probably need to work out what their stats might be. The sounds will be default sounds for hurt, death, taunts?

As I said, it would probably be a good idea to do the aliens this way too, then we don't have to hard code this stuff like we've been doing, it makes expansion and modding much easier.

The intex systems have been updated a little thanks to Matt, and I've done a bit of optimising and housekeeping on a bit of the code.

The game itself still needs to be converting into a function that gets called from the frontend, I don't think it'll be that difficult a task once we've got all the bits and pieces in for the level.

I've tidied up the graphics set a little and removed more tile graphics from decals so we've got more detail stuff.

Finally I've updated the map and editor a little so when you add a barrel it automatically sets the hit points and collision layers too, maybe we should have an extra file for defaults like this, or just hard code it into a case statement.

Anyway... that's about it!

Ok, have tidied up the engine.bb code to initialise eveything correctly (may have missed some types). Also set a framework around this so it's structured a little better.

I'll have a look at the timer code for the intex system on the weekend.


Engine.bb - replace

; Alien Breed Remake
; Blitz Community Project.

Const VERSION$="14/10/2004"
Const MEDIA_VERSION$="14/10/2004"
Const EDITOR_VERSION$="14/10/2004"

Global debugmode = False


Graphics 640,480,32,0
SetBuffer BackBuffer()

Include "inc\frontend.bb"
Include "inc\consts.bb"
Include "inc\script.bb"
Include "inc\credits.bb"
Include "inc\util.bb"
Include "inc\sounds.bb"
Include "inc\particle.bb"
Include "inc\players.bb"
Include "inc\weapons.bb"
Include "inc\animation.bb"
Include "inc\aliens.bb"
Include "inc\map.bb"
Include "inc\hud.bb"
;Include "inc\intex.bb"
Include "inc\intex-new.bb"
Include "inc\control.bb"
Include "inc\debuglines.bb"

; temp int for using in anything where you need a global
Global temp_int

; cheats:
Global unlimited_ammo 		= True
Global use_music		= False
Global use_sound		= False
Global use_overlay_layer	= True ; for speed issues, disable this
Global unlimited_health		= True
; end of cheats

Global playerHealthDecrease# = 0.1
Global ScreenX,ScreenY ; replaces locals "x,y"
Global GOffsetX,GOffsetY
Global turndelay = 0
Global global_timer=0

If use_music Then btext 40,50,"Music ON" Else btext 40,50,"Music OFF"
If unlimited_ammo Then btext 40,60,"Infinite Ammo ON" Else btext 40,60,"Infinite Ammo OFF"
If use_sound Then btext 40,70,"Sound ON" Else btext 40,70,"Sound OFF"

Global title_pic=LoadImage("gfx\art\title.png")
Global message$=""

ups=120
period=1000/ups

Type pickedup
	Field player
	Field obj
End Type

Repeat
	;Start Menu
	game = showmenu()
	If game = -1 Then Exit
	
	;Initialise system
	InitialiseGame()
	
	time=MilliSecs()-period
	global_timer=MilliSecs() ; set up global timer for scripts

	;FreeImage title_pic
	message=""
	
	Repeat
	
		; ********* TIMING CODE and GAME LOGIC
		Repeat
			elapsed=MilliSecs()-time
		Until elapsed
		tic=elapsed/period
		For k=1 To tic
			time=time+period
			ticks=ticks+1
			
			; the gettile checks the collision layer (0) in the direction that you're trying to move
			; if there's a collsion block there it won't let you.
			; this needs extending a little as you can get half way into a block if you try hard enough!
			
			Player_UpdateAll()
			
			; put screen in average player position
			ScreenX = ScreenX/Player_Count
			ScreenY = ScreenY/Player_Count
			
			ScreenX = ScreenX-320
			ScreenY = ScreenY-240
			
			;Limit movement of screen To map
			If ScreenX < 0 Then ScreenX = 0
			If ScreenX > 8192 - GraphicsWidth() Then ScreenX = 8192 - GraphicsWidth()
			If ScreenY < 0 Then ScreenY = 0
			If ScreenY > 8192 - GraphicsHeight() Then ScreenY = 8192 - GraphicsHeight()
			
			GOffsetX=ScreenX
			GOffsetY=ScreenY
			
			handleAnimations()
			handlebullets()
			update_aliens()
			handleScriptRunning()
			UpdateParticles()
					
			turndelay = (turndelay + 1) Mod 3
		
		Next
		; end of timing code
		
		; ********* RENDER WORLD		
		drawmap(ScreenX,ScreenY,1)
		drawparticles(0)
		drawmap(ScreenX,ScreenY,2)
		drawmap(ScreenX,ScreenY,3)
		drawbullets()
		Alien_DrawAll()
		Player_DrawAll()
		drawAnimations()
		drawparticles(1)
		drawmap(ScreenX,ScreenY,4)
		drawHUD()
		
		If debugmode
			drawdebuglines()
			Color 255,255,255
			bText 5,5,"Version: "+VERSION
		EndIf
		; end of render
		
		If KeyHit(59) Then SaveBuffer BackBuffer(),MilliSecs()+".bmp" ; F1 for screenshot
		
		Flip
		
	Until KeyHit(1)
		
Forever

;Tidyup system here
ReleaseObjects()
End


Function InitialiseGame()
	loading("Version: "+VERSION)
	loading("Media: "+MEDIA_VERSION)
	loading("Editor: "+EDITOR_VERSION)
	
	loading("Resetting Objects...")
	ReleaseObjects()
		
	loading("Setting up the HUD...")
	setupHUD()
	
	loading("Loading GFX...")
	loadGraphics()
	loading(maxtile+" tiles loaded.")
	
	
	loading("Loading the map...")
	; there's a pause because of the map loading...
	; load map
	load("maps\test")
	runOnLoadScripts()
	; display how many objects this map loaded from <map>.obj
	loading(numObjects+" objects loaded.")
	
	
	loading("Clearing VIS...")
	ClearVis()
	
	loading("Creating weapons...")
	; create the weapons we want in the game
	;createWeapon.weapon...
	;		...(id,name$,				dmg#,maxclp,aiac,	rate,speed#,bullettype,	frame,s1$="",s2$="",s3$="")
	createWeapon(1,weaponBroadhurst,    1.5, 	5, 	25, 	100, 3.0, 	2,			21, "sfx\mgun.mp3", "", "sfx\pistolreload1.mp3")
	createWeapon(2,weaponDalton,    	10.0,	1, 	25,  	500, 6.3, 	1,			22, "", "", "")
	createWeapon(3,weaponRobinson,  	8.0, 	5, 	25, 	300, 7.6, 	0,			23, "", "", "")
	createWeapon(4,weaponRyxx,      	0.4, 	5, 	25, 	100, 3.0, 	-1,			24, "", "", "")
	createWeapon(5,weaponStyrling,  	1.5, 	5, 	25, 	100, 3.0, 	3,			25, "", "", "")
	createWeapon(6,weaponImpact,    	1.5, 	5, 	25, 	100, 3.0, 	3,			26, "", "", "")
	
	; **************** TEMP BIT ******************
	; create 20 aliens in random places
	If True
	loading("Creating aliens...")
	For n=1 To 10
		Repeat
			x=Rand(100,2000)
			y=Rand(100,2000)		
		Until gettile(x,y,0)=0 
		spawnalien(x,y,n,Rand(2,4))
	Next
	EndIf
	; ************ End of TEMP BIT ***************
	
	loading("Creating player/s...")
	
	;Player Initialization - name, x, y, id
	
	; uses the game return from the front end
	Player_Create.player("bunker",player_one_start_x,player_one_start_y,1,"light")
	If game = 2 Then Player_Create.player("binky",player_two_start_x,player_two_start_y,2)

	For pl.player=Each player
		giveWeaponToPlayer(pl.player,getWeaponFromName(weaponBroadhurst))
	Next
	
	If use_music	
		SeedRnd(MilliSecs())
		which=Rand(1,4)
		Select which
			Case 1:file$="music\alienb.ogg"
			Case 2:file$="music\creeper.ogg"
			Case 3:file$="music\hollow.ogg"
			Case 4:file$="music\incendiary.ogg"
		End Select
		If FileSize(file)<>0
			loading("Loading music... "+file)
			background_music1 = LoadSound("sfx\back.mp3") 
			channel=PlaySound(background_music1)	
			background_music = LoadSound(file) : PlaySound(background_music)	
		EndIf
	EndIf
		
	;Ready to go
	loading("OK...")
	Delay 1000
	
End Function

function ReleaseObjects()
	Delete Each player
	Delete Each objdef
	Delete Each alien
	Delete Each weapon
	Delete Each tileTimer
	Delete Each animation
	Delete Each particle
	Delete Each bullet
	
End Function

Function loading$(m$)
	DrawBlock title_pic,0,0
	message=message+m+"|"
	menu(message,150,100,0)
	Flip
	Return 
End Function

Code changes have been minor but spread across files. Download the most updated version below. I'll let rob update the history and keep the final version, this is primarily for him when he wakes up tomorrow.

Uploaded and updated: 3:53 am GMT
www.3030deathwar.co.uk/downloads/ab/code.zip
www.3030deathwar.co.uk/downloads/ab/gfx.zip

I've updated the code to reflect the desired changes. There's a fully functioning menu system now. You can go into a game and press ESC to get back to the menu. From there you can resume or create a new game, or load a game, etc.

- Menu systems fully works. It's a bit tricky to understand but it works
- Load menu is ready
- When you die you go directly to the load menu
- LoadGameFromSaveGame is ready for the save game format
- Fixed ammo reloading
- You can restart the game again cleanly
- Added menu constants for ease of use
- Clean up of engine.bb now only important loop() and draw() stuff is in there
- HUD, tiles and weapons are loaded at the very beginning of the game. This means they don't need to be reloaded between loads. Multiple tilesets for specific levels will be loaded when called for. This can be done by seeing what tileset we need when loading then freeing the current one and loading the new one.
- Added initalise.bb to control the running game and menu interactions.

[edit: is it me or is the todo list thing a bit temperamental. I seems to have added the same things three times.

More, more, more:

- Added a basic save game file format. (.breed) which saves a small screenshot of the level you are starting.
- Haven't finalised the format yet. We should all discuss it.
- Fixed health not being given to you bug. (was it a bug?)
- Check out the Load game menu. There are some save games there that I saved a tests. Ctrl+S will save a game at any time. I know we're going to save at the end of levels, but it's only to test at the moment.

updated: 5:03 am (I am not getting any sleep tonight!)
www.3030deathwar.co.uk/downloads/ab/code.zip

Rims,

Here is the health code that will read from the script settings. Very nice changes by the way!

	;Function Runscript - script.bb
			
			Case "addhealth"				
				;Give health to player
				Player_GiveHealth(pl, si\param)

Bloody hell, you guys work overnight!

What do you make of the player and alien folders idea?

I'll look at these changes this evening!

I've just realised I've got webspace with NTL and I don't think there's any bandwidth limit on it so I'll build a little Alien Breed site. No idea if it does anything like PHP but I'll find out this evening.

Just downloaded the bits and pieces, I hate the hearts in the corners and bullets flying up from the bottom of the screen. I was hoping that bullet gfx was going to be a homing missile or something!

I'll have a proper look tonight to give a more balanced view but I look at it and don't really know what's going on.

The screen shake thing is pretty cool though.

I need to look at all the bits of code in some detail this evening... still early... not had a cup of tea yet...

Somewhere along the way, the ability to lower the hit points on a dynamic collision appears to have been removed:

editor.bb - hitpoint layer section

		
		;hitpoint layer
		If MouseHit(1) And activelayer = LayerHits Then 
			If map(xpos,ypos,LayerCollision) >1 Then
				;if left control is held
				If KeyDown(29) Then IncVal = 5 Else IncVal = 1 
				If map(xpos,ypos,LayerHits) < lhMaxHits Then map(xpos,ypos,LayerHits) = map(xpos,ypos,LayerHits) + IncVal
				;limit the maximum value for a dynamic collisions hit points
				If map(xpos,ypos,LayerHits) > lhMaxHits Then map(xpos,ypos,LayerHits) = 0
			EndIf
		EndIf
		If MouseHit(2) And activeLayer = LayerHits Then
			If map(Xpos, YPos, LayerCollision) > 1 Then
				If KeyDown(29) Then DecVal = 5 Else DecVal = 1
				map(xpos,ypos,LayerHits) = map(xpos,ypos,LayerHits) - DecVal
				If map(xpos,ypos,LayerHits) < 1 Then map(xpos,ypos,LayerHits) = 1
			EndIf		
		EndIf

OK, I don't hate the new hud... however... I'm not a fan.

Instead of a heart how about a heart moniter bing.. bing.. bing type screen?

The bullets flying up I think is disctracting, that's really not good.

yeah, but bullets... flying. you know you love it. It distracts in a really "this situation's out of control" type of way.

But if you don't like it you can take it out. In weapons.bb->FireWeapon, just comment the createFlyingBullet line. As for the heart, yeah, it was 4 in the morning. A heart monitor would be a lot better, I agree.

What's wrong with the energy bars?

We might want to consider an inventory screen / window to show detail of what keys, weapons, ammo, other objects that you have. We'll need this for carrying 'other objects' if we want to add some puzzle elements. e.g. find circuitboard and use it in broken down computer to access another area. The inventory screen can also provide the 'use' function to support this.

I think we just need to show the currently selected weapon on the HUD, with ammo count for it, and enable quick switching without entering the inventory. I don't think keys actually need to be shown on the HUD at all, but if we do that, we may need to tell the player they need a specific key when they try to open a door and don't have the key? I'm tempted to say not...as it's pretty damned obvious!

As for inventory, I say NEVER restrict 'other objects' to a fixed number / space. Let 'em carry everything. But we could consider only letting them carry one or two weapons at a time?

Mark, I agree, we could have a single button for the inventory for both players, the inventory screen would just overlay down each side of the screen, half the screen wide (or less) to allow both players to player to play with inventory at the same time if necessary.

The weapons are already accounted for with the player type.

Regarding the doors I'll get my girly Hannah to say things like "Red Pass required" and then stick loads of reverb on it to make it sound cool!! Actually speaking of speaking... We could do with a list of possible things doors / computers will say so I can get her to do it all in one sitting!

Red pass required
Blue Pass required
Green pass required
Yellow pass required [or (yellow security level required)?]
Shut down sequence initialised
Start sequence initialised
Self destruct sequence initialised
Please evacuate the building
30 seconds
20 seconds
10 seconds
9
8
7
6
5
4
3
2
1

Suggestions please!


I was thinking about ammo, and if we don't have traditonal weapons (ie machine gun) we could have them all as energy weapons and different guns use up more or less energy.?!?

This game is shaping up really nicely. Keep it up guys!

I noticed that there are two entries for addhealth in runscript().
There should only be one, right?

			Case "addhealth"				
;				pv.pickedup = New pickedup
;				pv\player = pl\id ; allowing for multiple players
;				pv\obj = 2
				Player_GiveHealth(pl,50)

			Case "addhealth"				
				;Give health to player
				Player_GiveHealth(pl, si\param)

Mark, thanks for spotting that. I think I just forgot to comment out one of them. Do we want to keep health packages as inventory items or simply use them when you move over them. In the heat of a firefight I think I'd prefer the later.

I like the energy weapon idea, it'd mean picking up ammo would be a lot less complicated. Also, the half a screen invenetory idea is spot on. Also, if both players had their inventory open you could use the mouse to drag things from each other's inventory. That'd be cool. "Here, you have the circuit board", etc.

Get hannah to say "you now have 2 minutes to reach minimum safe distance" I'm not sure why, but it'd be cool if we had a level with a time limit to escape within. You now have 30 seconds to reach minimum safe distance.

There's a slight problem with the frontend at the moment. If you go into a game then esc and go to load... then go back, it takes you back to the main menu rather than the "resume game" menu. I'll fix that though.

Oh, and yes, I like the player directory idea. We could package them up into one file later on.

Just knocked up a little thing to add to utils for the player info stuff... Copy this and call it testfile.bb!

; read test file

Print readitem("testfile.bb","speed")
Print readitem("testfile.bb","maxhealth")
Print readitem("testfile.bb","protection")
Print readitem("testfile.bb","toilet")

WaitKey


Function readitem$(filename$,item$)
	filein = ReadFile(filename)
	ret$ = "?Null?"
	lin$ = ""
	Repeat
		l$ = ReadLine(filein)
		lb = Instr(l$,"<"+item+">")
		rb = Instr(l$,"</"+item+">")
		If lb>0 And rb>0
			lb = lb + Len("<"+item+">")
			ret= Mid(l,lb,rb-lb)
		EndIf
	Until Eof(filein)
	CloseFile filein
	Return ret$
End Function

; test file
;<maxhealth>100</maxhealth>
;<speed>0.1</speed>
;<protection>2</protection>

Just created a mini website for the AB project. Link at the top ^^^ and don't you just love the way sites don't work properly on IE.

Zips updated.

Rob, the todo list link (and full history, etc.) have gone AWOL in your topmost post. Also you might want to mention Team17 on the site to make it clear they owned the original. Also, is *all* of the imagery on the web site *ours*? In particular, the alien gfx in the background?

As for health pickups, and whether they act instantly or not, I'd prefer not.

For one - consistency. If we're going to have objects to pick up like a circuit board, it will be inconsistent not to allow players to store health until it's actually needed.

For another, by using this mechanism, you'll likely end up needing to leave health pickups in non-sensical places. i.e. just after you kill a whole host of aliens, and you are on your last legs, it turns out they were hoarding health packs. WTF? Why?!? I'd rather we hide health packs away in med rooms. I also tend to think the same kind of logic should apply to (some) keys, although it'll be harder to apply. Keys don't just get left lying around in the corridor, but it's reasonable they might be in offices / side rooms / hidden behind the plant pot / whatever.

Having said all that, what I *do* propose is that if the player gets down to near-zero health, we automatically apply any health packs for them. Why make the player work on trivial tasks? They're gonna do it anyway, and if not, they'll just be annoyed that they didn't get to the 'use health pickup' key fast enough. (yup, another of my pet hates in modern videogames...uneccesary drudgery...)

Also, extra things to be recorded:
Welcome to Intex?

Intruder Alert -some alarm system stuff would be neat - maybe a (basic) sneak ability for some player classes? Laser trip wires to be gotten past either by tripping them and shooting, or using a skill / item?

'Some kind of under attack' alert. Might be quite cool to get halfway through exploring a level, and then get this alert and aliens flood in from where you've just come from...

Mark, I told Martyn Brown that we'd lifted a couple of box images and he didn't reply so I can only assume he's fine with it. I've updated the site a little, added links, made the team 17 connection clear etc. Let me know if you have any other ideas about content etc. NTL webspace doesn't support PHP which means we can't have the todo on there and it means everything is hand cranked which sucks :(

I have to agree if we're going for an inventory system with the ability to use items, health packs should be items that get used as and when they are needed.

Also the keys thing can be sorted with level design. You don't have 100s of keys lying around, you have a coloured door to get through to the next secure area then beyond that most of the doors are keyless. This way you'd only have a handful of red, green and yellow doors throughout the entire level. No reason why they shouldn't be added to your inventory and auto-used when you press a door though.

The 'Some kind of under attack' alert can be done nice an easily with an invisible object with an on-touch trigger.

I think sneak ability is taking the game a little over complicated, after all, it's basically a blast-a-thon with a bit of puzzle solving. Laser trip wires are cool, just have an object at the side that you need to blow up first, this on-destory will delete a bunch of laser objects stemming from it. If you touch a laser object it triggers x,y and z.

On the sneak thing, I'm not thinking it needs to be massively complicated. Just having the odd puzzle that can be gotten around either by a 'sneak' type of approach, OR all out assault. And not all sections of the game need to hold to that "two ways to do everything" approach, just some, as I think it adds to the feeling of being able to do things your way.

For example with the laser trip wire, you could provide objects to let the player either
1) just run it and set the alarm and blast loads of aliens
2) find the passcode and control device to turn it off
3) find access to the aliens hiding place (a grille in the wall) and gas them, then just run the laser trip wire with the aliens dead.
4) set up a mine in advance of the trip wire, then throw something at the tripwire, aliens come out and get slaughtered...

I'm not suggesting we have all those on a single tripwire, just putting forward ideas for alternative approaches that it'd be neat to allow (or even require?) on separate levels. All of this should be possible using objects / triggers as you say...

Those ideas are pretty sweet!

Just so you know... I'm about to go to bed!

However, been working on alien classes so we don't have to hard code them into the game. When the aliens are spawned a list is checked to see if it's gfx has been loaded yet, if it has it attaches itself to that image if not it loads the gfx and adds it to this list.
This means that if you have a level with only 2 types of alien in it only 2 alien gfx sets are loaded, ie It loads stuff as it needs it.

Anyway, the alien class thus far is:

; Alien Class outline

; gfx stuff
<gfxsize>64</gfxsize>
<gfxframes>128</gfxframes>

<health>10</health> ; start health of the alien
<fdelay>10</fdelay> ; speed of animation (higher is slower)
<frameTotal>8</frameTotal> ; The total number of frames in the animation
<speed>1</speed>   ; The speed the alien can move
<radius>20</radius>  ; The size of the alien
<offset>32</offset>  ; The pixel offset, ie a 64x64 sprite needs to offset 32 pixels to centre
<bloods>0</bloods> ; first particle to use as blood
<bloode>7</bloode> ; last particle to use as blood
<hurtsound></hurtsound> ; sound for when the alien is hurt
<deathsound></deathsound> ; sound for when the alien is killed
<canshoot>0</canshoot> ; if the alien can shoot
<bullettype>0</bullettype> ; bullet type if the alien is a shooter
<shootdelay>0</shootdelay> ; speed of shooting the higher the slower the shooting
<turnspeed></turnspeed> ; ** not yet implemented ** how fast the alien turns around

The turnspeed is a new one so the big aliens don't turn round as fast as the smaller ones... still got to code this lot in but it's getting there.

Zips updated:

Continued Here