CP - Alien Breed Remake - 4

http://www.perturbatio.com/files/AB/code.zip
http://www.perturbatio.com/files/AB/media.zip
http://www.perturbatio.com/files/AB/music.zip



Mark has recently added scripting support for the editor so we need graphics for the object tiles, some more scripting in the code aswell as our standard TODO:

This is looking great. Are there seperate graphics for each of the two players?
Because four player mode (like Gauntlet) would be fantastic.

Not at the moment, but we could put that on the todo list. I think we'll come up with the final player image/frames/animation before we copy it and make others. We could have different version you could play with.

An idea to save memory could be to have all the players looking the same but have different coloured shadows. Or a different coloured helmet drawn over the top of the image.

I agree with what someone else said in a seperate thread about doing the gfx in Blitz3D.
You would only have to need about 3 or 4 frames of animation. The rest is about rotating the sprite and entity colouring the image for seperate players. In 3D you could allow for clockwise/anticlockwise turning instead of 8 way movement. This would also allow split screen and for the camera to turn and zoomed out views.

The idea of separating out the graphics engine is a good one - it would be neat if the same engine could support a pure 2d and 2d in 3d mode. Personally, I prefer the straight 2d, but there's no reason why you couldn't abstract it out...

I'd actually quite like to see an isometric view too, although I'm thinking of holding onto my iso code for the next community project... ;-)

Rims, on the todo list, can you amend the notes as follows:

Extend Editor (nearly/partially done)
-Need an object & script editor

Extend Scripting (basics in place)
- Need trigger code for 'onevery(n)' and 'onrandom(n,m)' and script support for createalien(), playsound(), animate()
for placing bad guy spawn points , ambient sounds, animated decals etc. (Mark Tiffany to progress code, feel free to create some animations).

Doors
- Currently any key will open any door, need to extend addkey() and checkkey() script commands to open different doors with different keys. (Mark Tiffany to progress)

I'll try to knock up a crappy intex graphic and add an object / script for that tonight.

I just created this input box function, still not working properly, (wrapping text needs sorted, and it doesn't scroll).

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION InputBox									;
; Parameters:                                       ;
; msg$ : any message to display above the input box ;
; x,y : top left coords                             ;
; width, height: outer width and height of inputbox ;
; rtnSubmit : if the return key is pressed, then    ;
;             automatically submit the text			;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function InputBox$(Msg$,x,y,width,height,rtnSubmit=True, DefaultText$="")
	SetFont Font
;vars
	Local leave = False
	Local InnerWidth = Width - 6
	Local InnerHeight = Height - 20
	Local InnerX = 6
	Local InnerY = 20
	Local retString$ = ""
	Local fntWidth = FontWidth()/4
	Local fntHeight = FontHeight()

;main

	FlushKeys()
	Local EditWin = CreateImage(width, height)


Repeat
	;quit the function without returning any text if escape is pressed
	If KeyDown(1) Then 
		leave = True
		retString$ = ""
	EndIf
	
	;get character input
	get = GetKey()

	If Get = 13 Then
		If rtnSubmit Then 
			leave = True ;if return is pressed and rtnSubmit is True then leave
		Else
			retString$ = retString$ + Chr(get)
		EndIf
	ElseIf KeyDown(14); backspace
		If MilliSecs()-LastInput > 100 Then
			If Len(retString$) > 0 Then retString$ = Left$(retString$, Len(retString$) -1)		
			LastInput = MilliSecs()
		EndIf	
	ElseIf (get > 31) ;is a value letter, number or symbol
		retString$ = retString$ + Chr(get)
	End If
	
		oldbuffer = GraphicsBuffer()
		SetBuffer ImageBuffer(EditWin)
	
			;CopyRect 0,0,GraphicsWidth(), GraphicsHeight(),0,0,oldbuffer,ImageBuffer(EditWin)
	
			Color 160,160,160
			Rect 0,0,width,height

			Color 255,255,255
			Rect 2, 17, InnerWidth , InnerHeight

			Color 0,0,0
			
			Text width/2,8,msg,True,True
			

			;Draw Edit Content
			Local WCount = 0
			Local LineCount = 0
			Local CharCount = 0
			Local tempString$ = ""
			Local tempString2$ = ""
			Local StringLength = Len(retString$)
			
			While CharCount < StringLength

			
				Repeat 				
					CharCount = CharCount + 1
					Currentchar$ = Mid$(retString$, CharCount,1)	
					tempString$ = tempString$ + CurrentChar
					WCount = WCount + fntWidth
					
				Until WCount > InnerWidth - fntWidth Or (CharCount = StringLength) Or Asc(CurrentChar) = 13
				
				If Right$(tempString,1) = Chr(13) Then 
					tempString$ = Left(TempString$,Len(TempString$)-1)
				EndIf
				
				Text InnerX,InnerY + (LineCount * fntHeight),tempString$,False,False
				
				LineCount = LineCount + 1
				
				tempString$  = ""
				tempString2$ = ""
				
				WCount = 0

			Wend

		SetBuffer OldBuffer
	
	
	DrawImage EditWin,x,y
	Flip

Until leave = True

	Return retString$

	FlushKeys()
	FreeImage EditWin
	;SetBuffer oldbuffer

End Function

*EDIT*
belongs in editor.bb
*EDIT*
Updated slightly
add the following global to the top of editor.bb

Global LastInput = MilliSecs()

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Function saveBlitzVersion ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function saveBlitzVersion()

	FileName$ = InputBox("Enter filename to load (without .map extension)",200,300,400,40,True,"maps")
	If Len(FileName) <1 Then Return
	If FileType(FileName) = 2 Then Return
	FileName$ = FileName$

	save(filename)

	DebugLog "saved: " + FileName$

End Function

Ta pert'. That'll no doubt be useful for the object / script editor. Now for some more updates from moi!

Changes:
- added playsoundonce() to scripting, and moved health and key sounds into scripts
- added different door colours to match keys, and updated scripting to make them work
- updated objects.png with new doors and (very) basic intex graphic
- updated map with keys / doors / intex
- amended loadgraphics to determine number of tiles itself (rather than hardcoding)
- reuse loadgraphics in editor and engine
- minor bug in palettes fixed whereby last tile wasn't shown

(and yes, I know that the one intex on the map doesn't do anything...yet!)

Rims, you can get rid of the doors TODO completely now! ;)

You'll need *this* zip containing a new map and obj file, plus the updated objects.png.

In players.bb, replace keycheck() with the following:

Function keycheck(player,keyid%)
	For p.pickedup = Each pickedup
		If p\player = player And p\obj =keyid Then Delete p:Return True
	Next
	Return False
End Function

In script.bb, RunScript, update the "checkey" command to:

			Case "checkkey"
			   	If Not keycheck(pl\id,Int(si\param)+2) Then ClearScriptFrom(si):Return

and add this function:

Function ClearScriptFrom(si.scriptitem)
	Repeat
		nsi.scriptitem=After si
		Delete si
		si=nsi
	Until nsi=Null
End Function

In map.bb, update opendoor()

Function opendoor(x,y,vis=True)
	id%=map(x,y,LayerObject)
	map(x,y,LayerObject)=0
	map(x,y,0)=0
	
	If map(x,y-1,LayerObject)=id Then opendoor(x,y-1,False)
	If map(x,y+1,LayerObject)=id Then opendoor(x,y+1,False)
	If map(x+1,y,LayerObject)=id Then opendoor(x+1,y,False)
	If map(x-1,y,LayerObject)=id Then opendoor(x-1,y,False)

	; check the vis from this newly opened door!
	If vis Then CheckVis(x,y)
	
End Function

In the "editor include.bb", remove hardcoded numbers for maxobject and maxtile and move these to map.bb. Also move the global tiles, object, cursor and tiles_small.
Remove loadgraphics from "editor include.bb" and replace it in map.bb with this:

Function loadGraphics()
	; load tiles
	img=LoadImage("gfx/tiles.png")
	maxtile=(ImageWidth(img)/32)*ImageHeight(img)/32
	FreeImage img
	tiles = LoadAnimImage("gfx/tiles.png",32,32,0,maxtile)
	MaskImage tiles,255,0,255	
	
	; load objects
	img=LoadImage("gfx/objects.png")
	maxobject=(ImageWidth(img)/32)*ImageHeight(img)/32
	FreeImage img
	objects = LoadAnimImage("gfx/objects.png",32,32,0,maxobject)
	MaskImage objects,255,0,255
	
	; load small tiles
	tiles_small = LoadAnimImage("gfx/tiles_small.png",16,16,0,maxtile)
	MaskImage tiles_small,255,0,255
	
	cursor = LoadImage("gfx/cursor.png")
	MaskImage cursor,255,0,255	
	font=LoadFont("tahoma.ttf",10):SetFont(font)		
End Function

And in the palette drawing code, remove the -1's

	;palette
	For n=0 To 68
		tileno = n + tileoffset
		
		
		If activelayer <> 2
			If tileno<maxtile Then DrawBlock tiles,((n-(Floor(n/23)*23))*32)+32,490+(Floor(n/23)*32),n+tileoffset
			Else
			If tileno<maxobject Then DrawBlock objects,((n-(Floor(n/23)*23))*32)+32,490+(Floor(n/23)*32),n+tileoffset
		EndIf

		If tileno = activetile Then Color 0,255,0:Rect ((n-(Floor(n/23)*23))*32)+32,490+(Floor(n/23)*32),32,32,False

	Next

In engine.bb, replace the lines immediately following the "loading Gfx.." text with loadgraphics()

In script.bb, remove references to playoneshot(), and add this case statement:

			Case "playsoundonce"
				Select param
					Case "health_pickup":playoneshot(health_pickup,x,y)
					Case "key_pickup":playoneshot(key_pickup,x,y)
				End Select

If you ignore the fixes / tweaks above, hopefully this illustrated how easy it is to add new scripting stuff. Just add the code to support the command to RunScript and create/update an object to use it!

looks like a typo here:

			Case "playsoundonce"
				Select param
					Case "health_pickup":playoneshot(health_pickup,x,y)
					Case "key_pickup":playoneshot(key_pickup,x,y)
				End Select

Should be:

			Case "playsoundonce"
				Select si\param <-----
					Case "health_pickup":playoneshot(health_pickup,x,y)
					Case "key_pickup":playoneshot(key_pickup,x,y)
				End Select

*EDIT*
Also, on the new door colours (nice btw) you can shoot out a single section but the other sections do not open, if you shoot out the middle section, the two parts are now treated as separate doors.

Guys,

the player animation code was accidentally removed from Player_UpdateAll. Add this at the bottom to fix:

	;Animation
	If move Then
		pl\fpause = (pl\fpause+1) Mod 5
		If pl\fpause = 0 Then 
			pl\frame = (pl\frame+1) Mod 15
		End If	
		
	End If

Ok, it's 4am and I've going to bed, but I'm having some trouble in the InputBox function, if I set the fndWidth to a random value (using Rand(6,8)) I can display text in the edit windows, if I use the GetCharWidth Function (which does return a value) it does not display any text.

AAAAAaaaargh!

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION InputBox									;
; Parameters:                                       ;
; msg$ : any message to display above the input box ;
; x,y : top left coords                             ;
; width, height: outer width and height of inputbox ;
; rtnSubmit : if the return key is pressed, then    ;
;             automatically submit the text			;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function InputBox$(Msg$,x,y,width,height,rtnSubmit=True, DefaultText$="")
	SetFont Font

;vars
	Local leave = False
	Local InnerWidth = Width - 6
	Local InnerHeight = Height - 40
	Local InnerX = 6
	Local InnerY = 20
	Local retString$ = ""
	Local fntWidth = FontWidth()/4
	Local fntHeight = FontHeight()
	If rtnSubmit Then InnerHeight = Height - 6
;main
	FlushKeys()
	Local EditWin = CreateImage(width, height)

retString = retString+DefaultText

Repeat
	;quit the function without returning any text if escape is pressed
	If KeyHit(1) Then 
		leave = True
		retString$ = ""
	EndIf
	
	;get character input
	get = GetKey()

	If Get = 13 Then
		If rtnSubmit Then 
			leave = True ;if return is pressed and rtnSubmit is True then leave
		Else
			retString$ = retString$ + Chr(get)
		EndIf
	ElseIf KeyDown(14); backspace
		If MilliSecs()-LastInput > 100 Then
			If Len(retString$) > 0 Then retString$ = Left$(retString$, Len(retString$) -1)		
			LastInput = MilliSecs()
		EndIf
	ElseIf (get > 31) ;is a letter, number or symbol
		retString$ = retString$ + Chr(get)
	EndIf



		oldbuffer = GraphicsBuffer()
		SetBuffer ImageBuffer(EditWin)

			Color 160,160,160
			Rect 0,0,width,height

			Color 255,255,255
			Rect 2, 17, InnerWidth , InnerHeight

			Color 0,0,0
			
			Text width/2,8,msg,True,True
			

			;Draw Edit Content
			Local WCount% = 0
			Local LineCount% = 0
			Local CharCount% = 0
			Local tempString$ = ""
			Local tempString2$ = ""
			Local StringLength% = Len(retString$)
			Local CurrentChar$ = ""
			
			While CharCount < StringLength
			
				Repeat

					CharCount = CharCount + 1
					Currentchar$ = Mid$(retString$, CharCount,1)	
					tempString$ = tempString$ + CurrentChar$
					
					charWidth = GetCharWidth%(Currentchar$)+2 <!-----------
					
					WCount = WCount + charWidth

				Until (WCount > InnerWidth - 6) Or (CharCount = StringLength) Or (Asc(CurrentChar) = 13)
				

				If Right$(tempString,1) = Chr(13) Then 
					tempString$ = Left(TempString$,Len(TempString$)-1)
				EndIf


				Text InnerX,InnerY + (LineCount * fntHeight),tempString$,False,False


				LineCount = LineCount + 1

				tempString$  = ""
				tempString2$ = ""

				WCount = 0

			Wend
		
		SetBuffer OldBuffer
	
	
	DrawImage EditWin,x,y
	
	If Not rtnSubmit Then
		If Button(x+(Width/2)-30,y+Height-20,60,"OK") Then leave = True
	EndIf
	
	Flip

Until leave = True

	FlushKeys()
	FlushMouse()
	FreeImage EditWin
	
	Return retString$


End Function


;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION GetCharWidth ;
;;;;;;;;;;;;;;;;;;;;;;;;;

Function GetCharWidth%(char$)
;vars
	Local imgFontTest = CreateImage(32,32)
	Local oldBuffer = GraphicsBuffer()
	Local x = 0
	Local y = 0
	Local Found = False
	Local iLeft%=0
	Local iRight%=0
	
;main
SetBuffer ImageBuffer(imgFontTest)

	Color 0,0,0

	Rect 0,0,32,32
	Color 255,255,255
	Text 1,1,char$
	LockBuffer
	;Find left side
	For x = 0 To ImageWidth(imgFontTest)
		For y = 0 To ImageHeight(imgFontTest)			
			If (ReadPixelFast(x,y) And $FFFFFF) = $FFFFFF Then 
				iLeft = x
				Found = True
				Exit
			EndIf
		Next	
		If found Then Exit		
	Next
	Found = False
	
	;Find Right Side
	For x = ImageWidth(imgFontTest) To 0 Step -1
		For y = ImageHeight(imgFontTest) To 0 Step -1
			If (ReadPixelFast(x,y) And $FFFFFF) = $FFFFFF Then 
				iRight = x
				Found = True
				Exit
			EndIf

		Next	
		If found Then Exit		
	Next
	
	
;	DebugLog ReadPixelFast (0,0) And $FFFFFF
UnlockBuffer
SetBuffer oldBuffer

FreeImage imgFontTest
width = iRight - iLeft
If width <1 Then width = 6
Return width

End Function

I had a look at your code and... you're going to kick yourself... it's because you were drawing the text in the colour of the background. I added a colour 0,0,0 before you draw the text and it works.

For those who want to just download the differences to the media.zip instead of downloading 1.7 meg, the objects image is here: www.3030deathwar.com/downloads/ab/objects.png

@Pert' : Ta for fixing the sound, although I'm positive it was working for me!?! Going mad I guess...

And regarding the shooting doors thing, I suspect that's how it was working before my changes. The opendoor function looks for matching doors next to the current door section, and always has done - so I'm pretty sure that's an old 'bug'. Not sure how we deal with it: either we say that destroying one section of a door prevents all other sections from working as a door (you have to blow it all up), or we destroy the entire door on destroying one section. OR, (and I think I prefer this), don't have destroyable doors that can be opened by keys. I'm not convinced it makes sense to allow you to either use force or a key on any one door. By all means, we could have a new door object that looks like a door, but nothing opens it, forcing you to blast your way through. Requires a bit of thought...

@Matt : ta for picking up on that clumsy omission of the animation by yours truly. ;-)

Doh! *Puts on some hobnailed boots*.

It is however too damn slow, I think I'll try precalculating it.


It was playing both the key pickup sound and the health pickup sound for me.


No, the entire door opened when shot previously, I think it's because the different coloured doors need a const set in consts.bb and a check in the case statement of DamageTile. It was just going to the default case for non-yellow doors.

code.bb:

;OBJECT CONSTS (ot=ObjectType)
Const otVDoorYellow = 7
Const otHDoorYellow = 8

Const otVDoorRed    = 12
Const otHDoorRed    = 13

Const otVDoorBlue   = 14
Const otHDoorBlue   = 15

Const otVDoorGreen  = 16
Const otHDoorGreen  = 17

in map.bb - DamageTile

			;horizontal door
			Case otHDoorYellow,otHDoorRed,otHDoorBlue,otHDoorGreen
				OpenDoor(x,y)
			;vertical door
			Case otVDoorYellow,otVDoorRed,otVDoorBlue,otVDoorGreen
				OpenDoor(x,y)

I didn't realise it previously opened the entire door. To be honest, I'd prefer to see the logic that you've got there in a script, rather than hardcoding. i.e. an "ondestroy" trigger that the above map code runs, which runs a script along the lines of "opendoor(7):remove(nearby)".

However, that implies two triggers for the same object (ontouch and ondestroy), which we hadn't allowed for. I'll have to think about that...

I was looking at the script code and added the following for spawning aliens:

			Case "createalien"
				Select si\param
					Case "alien":SpawnAlien(x,y,-1,STANDARD_ALIEN)
					Case "hugger":SpawnAlien(x,y,-1,FACE_HUGGER_ALIEN)
				End Select

and add this to the test.obj:

18
1
Spawn (Alien)
createalien(alien)|remove(me)
19
1
Spawn (Hugger)
createalien(hugger)|remove(me)

I would imagine a couple of 'invisible' tiles would be added to the objects as triggers (just knocked up a couple of temp ones myself).


Couple of questions come from this?

* best way to determine x,y location to 'create' alien? specific spawn location, random ??
* alien ID - should we track this as part of the SpawnAlien process? ie. global counter
* spawning a number of aliens at once?

You have done a great job with this Mark!

We shouldn't need a blank tile image in objects.png, setting the image id to -1 ought to do it, although that's untested! (Feel free to amend the code to sort that out) With your additions to test.obj, you should also update the first line to specify the total number of objects (i.e. add 2) else the objects won't load!

As for your questions, in reverse order:
3)to create multiple aliens, use createalien() more than once. e.g. "createalien(hugger)|createalien(hugger)|createalien(alien)" would create a whole bunch.
2)do we need to track alien ids at all?
1)I was thinking that createalien should take the x,y as inputs...e.g. createalien(x,y,type).

On the last one, I was thinking that it'd be neat if the following script syntaxes were understood:

"createalien(x,y,hugger)" - creates a hugger at the objects x,y location
"createalien(px,py,hugger)" - creates a hugger at the players location (may be different to object)
"createalien(x-1,y+1)" - creates a hugger SW of the object (useful for creating a generic trap that creates 4 aliens around the trap)
"createalien(123,456,hugger) - creates a hugger at a very specific location on the map (useful for very specific scripted events)

Fancy implementing some of them? ;-)

Also, your code (and OBJ file) will only ever create aliens when the player touches the object square. At some point I was planning to extend the triggers to include "onevery(10)" and "onrandom(100,200)" to generate events at a specified number of game logic loops - i.e. spawning one alien every 100-200 loops. I haven't fully thought through yet whether this should only happen when the object is on screen or not though...

And I think I now see your point about counters of alien types - it might be nice if spawn points only create a new alien once an old one dies...maybe we need an optional ID in the createalien params too?

Another update! Changes:
-objects can now have multiple triggers (and a different script for each)
-ondestroy() trigger added
-Yellow doors now destroy properly (i.e. fully open when destroyed)

Updated the object type in consts.bb to allow for text based triggers and up to 5 trigger scripts per object.

Type objdef
	Field image%
	Field name$
	Field trigger$ ; see constants below
	Field script$[5]
End Type

and the constants for script items

Const ScriptTrigger_OnOver$="|onover("
Const ScriptTrigger_OnTouch$="|ontouch("
Const ScriptTrigger_OnDestroy$="|ondestroy("
Const ScriptTrigger_OnAction$="|onaction("

Updated the object load part of map.bb load() to deal with multiple trigger scripts

			For i=1 To NumObjects
				objectdef(i)=New objdef
				objectdef(i)\image=ReadLine(filein)
				objectdef(i)\trigger=ReadLine(filein) 
				;add a separator to the start to make searching simpler
				If Left(objectdef(i)\trigger,1)<>"|" Then objectdef(i)\trigger="|"+objectdef(i)\trigger
				objectdef(i)\name=ReadLine(filein)		
				For n=1 To CountString(objectdef(i)\trigger,"|")
					objectdef(i)\script[n]=ReadLine(filein)
				Next
			Next

And the equivalent in save()

	For i=1 To NumObjects
		WriteLine fileout, objectdef(i)\image
		WriteLine fileout, Mid(objectdef(i)\trigger,2) ; chop off the first | for saving
		WriteLine fileout, objectdef(i)\name		
		For n=1 To CountString(objectdef(i)\trigger,"|")
			WriteLine fileout,objectdef(i)\script[n] 
		Next
	Next

Add this to util.bb:

Function CountString(s$,search$)
	n=0
	While Instr(s$,search$)
		n=n+1
		s$=Mid(s$,Instr(s$,search$)+1)
	Wend
	Return n
End Function

and add util.bb as an include to editor.bb
Okay, so that sorts out defining multiple triggers on an object. Now to make them do something!

In players.bb, player_updateall, amend the four 'touch' lines that look like this

If objectdef(tile)\trigger=ScriptTrigger_OnTouch Then RunScript(pl,objectdef(tile),pl\x,pl\y+playerradius)

to this

If Instr(objectdef(tile)\trigger,ScriptTrigger_OnTouch) Then RunScript(pl,objectdef(tile),ScriptTrigger_OnTouch,pl\x,pl\y+playerradius)

and update the collect lines to:

	; collect objects
	If map(pl\x/32,pl\y/32,LayerObject)>0 Then 
		If Instr(objectdef(map(pl\x/32,pl\y/32,LayerObject))\trigger,ScriptTrigger_OnOver) Then RunScript(pl,objectdef(map(pl\x/32,pl\y/32,LayerObject)),ScriptTrigger_OnOver,pl\x,pl\y)
	End If

and update the top of the RunScript function to look like this:

Function RunScript(pl.player,obj.objdef,trigger$,x,y)
	p=Instr(obj\trigger,trigger)
	n=CountString(Left(obj\trigger,p),"|")
	si.scriptitem=ParseScript(obj\script[n])
	While si<>Null

That allows the scripting to process the two existing triggers on the saem object, but to fix the doors, we need to implement the ondestroy() trigger.
So, back to map.bb, and this time update DamageTile code for <1 hit to:

	;if run out of hits
	If map(x,y,LayerHits) <1 Then 
		
		If map(x,y,LayerObject)>0 Then 
			If Instr(objectdef(map(x,y,LayerObject))\trigger,ScriptTrigger_OnDestroy) Then 
				;TODO: we probably need to keep track of which player owns which bullet, and pass that player in here
				RunScript(Player(1),objectdef(map(x,y,LayerObject)),ScriptTrigger_OnDestroy,x*32,y*32)
			Else
				;default action for any other destructible object
				Map(x,y,LayerObject) = 0 
				Map(x,y,LayerCollision) = 0
			End If			
		End If
		
	EndIf

And to actually fix the door problem, and support the new OBJ file model for triggers, an updated test.obj - note that only yellow doors will destruct 'properly' on the basis we probably want the other key types to never be destructible.

18
0
onover()
Ammo
addammo(50)|remove(me)
1
onover()
Health
addhealth(10)|playsoundonce(health_pickup)|remove(me)
2
onover()
Key (yellow)
addkey(1)|playsoundonce(key_pickup)|remove(me)
3
onover()
Key (red)
addkey(2)|playsoundonce(key_pickup)|remove(me)
4
onover()
Key (green)
addkey(3)|playsoundonce(key_pickup)|remove(me)
5
onover()
Key (blue)
addkey(4)|playsoundonce(key_pickup)|remove(me)
6
ontouch()|ondestroy()
Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)
7
ontouch()|ondestroy()
Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)
8
onover()
100 Credit
addcredit(100)|remove(me)
9
onover()
50 Credit
addcredit(50)|remove(me)
10
onover()
10 Credit
addcredit(10)|remove(me)
11
ontouch()
Door (red)
checkkey(2)|opendoor()|remove(nearby)
12
ontouch()
Door (red)
checkkey(2)|opendoor()|remove(nearby)
13
ontouch()
Door (blue)
checkkey(4)|opendoor()|remove(nearby)
14
ontouch()
Door (blue)
checkkey(4)|opendoor()|remove(nearby)
15
ontouch()
Door (green)
checkkey(3)|opendoor()|remove(nearby)
16
ontouch()
Door (green)
checkkey(3)|opendoor()|remove(nearby)
17
onaction()
Intex System
intex()

Finally, for reference, I've updated the script.bb comments:

;Scripting Design Notes
;======================

;Each map has a <mapname>.obj file that is simply a series of strings.
;This can be tidied up later on, but allows us To edit objects / scripts
;without actually having a script editor.

;An Object is defined once, And has a unique id (defined by it's position 
;in the OBJ file.  This ID is Then held in the Object layer of the map.
;Many locations on the map may reuse the same ID For common objects such
;as keys, cash, ammo, doors, etc.  These share the same Object definition, 
;but the script can be run from many places on the map.

;Special objects (such as conversations) are defined in the same way, 
;but are generally used only once (although you might have a conversation
;that you wish To be triggered by coming near a character, which might 
;require several surrounding map tiles To point To the same Object, but
;the Object Then does a remove(all) To ensure it's Not used again).

;The idea is that If you want To add a New scripted Object / event, you
;simply update the OBJ file (by hand For now) with a New Entry (don't
;forget To up the count!), Write the script in that Entry, Then load the 
;editor, place the Object somewhere (it should just appear in the palette),
;save And run.  Once the scripting language is complete, that really is all
;you'll need To do - well, other than draw an image For it.  Note that an 
;image of 0 _should_ in principle be invisible, but I haven't tested it yet...
;(may be useful For conversations / traps / scripted events occurring on 
;entering a room).

;FORMAT
;======
;Number of Objects, followed by the following fields repeated For Each Object:
;Image       - the image in object_tiles that will be used For display
;Trigger     - what will trigger the script To run (see below); multiple triggers separated by |
;description - a simple description of the Object!
;script x N  - The script To run (1 to 5 of them, based on how many triggers there are

;TRIGGERS
;========
;trigger is one of:
;onover()    - on passing over (collectable items, traps)
;ontouch()   - on touching (doors, buttons on walls, intex systems)
;ondestroy() - if a block is destructible, run on destruction
;onaction()  - on pressing the action key near the object

;SCRIPTS
;=======
;script is formed of a series of commands, all taking the format:
;commandname(params)|commandname(params)

;For example:
;addammo(100)|remove(me)


; ----------------------------------------------------------
;Script commands implemented:
;addammo(N) - adds N To the players ammo count
;checkkey() - checks that they have a key, If Not, the script stops
;opendoor() - runs the old opendoor code as is
;addkey(N)  - adds key Type N
;addhealth(N) - adds N health
;remove(me) - removes the Object that caused this script To run
;addcredit(ID,N) - adds N amount to player
;playsoundonce(sound) - plays the specified sound once
;createalien(type) - creates an alien of the specified type at the object location
; ----------------------------------------------------------

;TODO
;====
;remove(nearby) - removes all nearby objects of the same Type (e.g. doors) And change opendoor?
;remove(all) - removes all objects of the same Type
;playsoundcont(sfx) - play a continuous sound effect.  No idea how we Stop these though...
;showdoc(Text) - show a document on screen
;showconv(x,y,Text) - show a speech bubble at specified x,y.
;createalien(x,y,Type,anim) - create an alien - need creation animations
;setcollision(x,y,value) - set the collision layer of the map directly
;setobject(x,y,value) - set the Object layer of the map directly
;settile(x,y,value) - set the base tile layer of the map directly
;
;onaction() triger - on pressing a new action key near the object (for intex, etc)
;onload() tigger - on first loading the map, e.g. for creating aliens (and players?)
;onevery(N) - on every Nth pass of the logic loop
;onrandom(n,m) - randomly, between every n and m logic loops

Mark, do you ever sleep? (great work by the way!)

He's a robot, you know. I've had no time to update this tonight and my eyes kill. I'll update and actually get some code done tomorrow. Honestly!

Mark,

Just back on the 'invisible' tiles thing, if we set the objectID to -1 how would you add this 'trigger' tile to the editor?

Do we need some sort of flag (true/false) to determine if an object is a visible object or collectable or trigger? This way it would be shown on the editor but not in the game itself.

I'll have a look at processing multiple parameters if you like.

Again, you have done a great job with the scripting stuff!!

Nah, just an humble ace coder. ;-)

(The trick is that I think about exactly how I want something to work in my head before I even consider coding anything. Luckily, 99% of the time it works first time...)

Matt, go ahead with multiple params stuff - assume that you'll need to deal with any number of params separated by commas, but also make sure you consider quotes (e.g. for showconv(px,py"I'm gonna get you, you scum eating alien!")

As for invisible tiles, the object ID is defined by it's position in the OBJ file, *not* the number in the file. That number is the image to be used by that object, and it should be possible to set it to -1 to force it to be invisible.

However, as you've spotted, there is a flaw in this. Although you'll be able to set the object in the editor, and it will work in the engine, you won't see it on the map (or palette) in either. I realised this last night, and am thinking along these lines (feel free to do this yourself, probably won't have time myself tonight):

- Ensure image numbers in OBJ file start from 1 not 0.
- Change drawmap and palette drawing to deal with this.
- Use negative numbers in the OBJ file for images to be used in editor, but not in the engine.
- Amend drawmap to know if it's in the editor or engine, and draw negative OBJ image in the editor only (using the positive image id)
- Amend the editor palette to do the same

I'd also quite like to see a 'tile info' area in the editor that specifies what each layer is currently set to on the tile you're currently hovering over. In this way, you can also display the object name in the editor, making it easier to understand what objects are!

Just played a game of Alien Breed in DosBox and captured some images of the intexsystems. Don't know if we want to use these or use them as an example for the version this community is making. I also captured and slighly altered some tiles like the ones in Alien Breed for the Intex Terminals.
Also included the 'INTEX SYSTEMS' female voice.

http://home.wanadoo.nl/~snader/intexsystems.zip

BTW, these are the weapons used in Alien Breed 1:

Broadhurst DJ Twinfire 3LG (Rapid fire) - 10000 Credits
Dalton Arc Flame (Rapid fire) - 24000 Credits
Robinson Plasma Gun (Pump action) - 35000 Credits
Ryxx Firebolt MK22 (Flamethrower) - 48000 Credits
Styrling Multimatic (Triple barrel) - 60000 Credits
High Impact Astro Laser (Lazer) - 75000 Credits

I get a stack overflow with this updated scripting. It occurs in the opendoor function which seems to get called an infinite amount of times. I added some checking for coords in the function so it now reads:

Function opendoor(x,y,vis=True)
	id%=gettile(x,y,LayerObject)
	putTile(x,y,LayerObject,0) ; set to 0
	putTile(x,y,LayerCollision,0)
	
	If gettile(x,y-1,LayerObject)=id Then opendoor(x,y-1,False)
	If gettile(x,y+1,LayerObject)=id Then opendoor(x,y+1,False)
	If gettile(x+1,y,LayerObject)=id Then opendoor(x+1,y,False)
	If gettile(x-1,y,LayerObject)=id Then opendoor(x-1,y,False)

	; check the vis from this newly opened door!
	If vis Then CheckVis(x,y)	
End Function

But on my computer with debug on it simply quits and with debug off it displays a "stack overflow" which is likely caused by and infinite loop. I suspect it has something to do with on touch AND on destroy but I'm not sure where it's from. Here's the broken code at the moment with all these updates: www.3030deathwar.co.uk/downloads/ab/temp_code.zip

-----
Thanks for those Snader. They seem a bit pricy especially if you're just picking up 10,50 and 100 credit chips. We'll probably have to play test those!

Does it break when destroying the door, or when opening it with a key (or both?)?

Is it definitely clearing the door objects that relate to the door being destroyed / opened? That would cause a loop, as it would move on to the nearby object, then back to the original ad infinitum...

Is the id being picked up correctly? If it's getting a zero instead of the id of the object, then that would also cause a horrendous loop as above, but across (almost) the entire map. Yuck! I did wonder if I should pass in the id, but thought it neater to determine it in the function - maybe there's a scenario where the x,y doesn't match the object location?

(I'm not likely to get a chance to do anything tonight, so thought I'd throw in as many thoughts as possible in the hope someone else spots my mistake...it was working okay for me, so I must've slipped up and missed a change somewhere)

No, it was me I think. When I first ran it there was some boundry error when checking the map array. So I added a call to getTile instead of directly to the array. Thing is, these use different coords; the map 32x32 and the getTile the screencoords. It works now though.

I've added some new weapons. I did some crap graphics so if someone can spruce them up I won't be so embarressed. I've also made a change to the obj file. Whilst I was adding objects I found it quite hard, so I've modified to read:

image = 0
trigger = onover()
description = Ammo
addammo(50)|remove(me)

for simplicity, seeing as it's a pre-compiled handwritten version. The map->load/save functions update this as well. The onl problem I've discovered is that the editor won't let me add any weapons after the 3rd, I think. I'm not sure what the problem is. I've got to polish the gun picking up section, but at the moment you can pick up guns and shoot them. Still to do: changing weapons, noises, power, notifying you you picked one up, etc.

The code and media have been updated, but, as always if you don't want to update the entire media.zip you can download the new objects.png from here: www.3030deathwar.co.uk/downloads/ab/objects.png
Also, for those who don't want to dl media.zip, here's the updated map.obj:

total objects = 25

image = 0
trigger = onover()
description = Ammo
addammo(50)|remove(me)

image = 1
trigger = onover()
description = Health
addhealth(10)|playsoundonce(health_pickup)|remove(me)

image = 2
trigger = onover()
description = Key (yellow)
addkey(1)|playsoundonce(key_pickup)|remove(me)

image = 3
trigger = onover()
description = Key (red)
addkey(2)|playsoundonce(key_pickup)|remove(me)

image = 4
trigger = onover()
description = Key (green)
addkey(3)|playsoundonce(key_pickup)|remove(me)

image = 5
trigger = onover()
description = Key (blue)
addkey(4)|playsoundonce(key_pickup)|remove(me)

image = 6
trigger = ontouch()|ondestroy()
description = Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)

image = 7
trigger = ontouch()|ondestroy()
description = Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)

image = 8
trigger = onover()
description = 100 Credit
addcredit(100)|remove(me)

image = 9
trigger = onover()
description = 50 Credit
addcredit(50)|remove(me)

image = 10
trigger = onover()
description = 10 Credit
addcredit(10)|remove(me)

image = 11
trigger = ontouch()
description = Door (red)
checkkey(2)|opendoor()|remove(nearby)

image = 12
trigger = ontouch()
description = Door (red)
checkkey(2)|opendoor()|remove(nearby)

image = 13
trigger = ontouch()
description = Door (blue)
checkkey(4)|opendoor()|remove(nearby)

image = 14
trigger = ontouch()
description = Door (blue)
checkkey(4)|opendoor()|remove(nearby)

image = 15
trigger = ontouch()
description = Door (green)
checkkey(3)|opendoor()|remove(nearby)

image = 16
trigger = ontouch()
description = Door (green)
checkkey(3)|opendoor()|remove(nearby)

image = 17
trigger = onaction()
description = Intex System
intex()

image = 18
trigger = onover()
description = weapon (Broadhurst DJ Twinfire 3LG) [image=19]
pickupweapon(1)|remove(me)

image = 19
trigger = onover()
description = weapon (Dalton Arc Flame) [image=20]
pickupweapon(2)|remove(me)

image = 20
trigger = onover()
description = weapon (Ryxx Firebolt MK22) [image=21]
pickupweapon(3)|remove(me)

image = 21
trigger = onover()
description = weapon (Styrling Multimatic) [image=22]
pickupweapon(4)|remove(me)

image = 22
trigger = onover()
description = weapon (High Impact Astro Laser) [image=23]
pickupweapon(5)|remove(me)

Guys,

If we want to use more of the intex system gfx, I have been able to grab clean images from the amiga version.

These include the backgrounds, weapon images and text. It was something I wanted to look at - just been too busy with work.

What do you rekon?

vis seems to be slightly broken, when I shoot the row of credits, it doesn't update, you then walk into a void.

suggested updated objects.png:

<See further down.>

*EDIT*

I need to adjust the lighting on the terminal graphics actually, but we do need four directions for them.

I'm not sure why that is, perty. I've made some updates including adding your image. Have a look at the history.txt for more info.

I'm now going to flay myself for not reading the docs, stringwidth has solved my character width issue in about 5 seconds flat.

Oh the shame.

Ha! I've just used your getInput function quite a lot. The new version (newer than 10 minutes ago) has some new editor code:

- Added a simple commandline to editor. maps\test will load that map.
- Right clicking on the object in the object palette will allow you to edit the script.

Don't flay yourself too much. I'm pretty sure it's illegal in 18 states.

Matt, as for the intex screenies, I'm not sure. Should we use graphics from the actual game? I know we're not selling it, but since we've done our own version so far I think we should probably steer clear of copying. I don't know, though. They're cool, aren't they. What do you think?

I've updated the InputBox to have proper character wrap, no word wrap yet.
It has key repeat for backspace (and the cursor keys) and now has a CaratPos so that you can go back and forward and insert text.

The GetCharWidth function can probably be removed now as it is obsolete (doh!).

in editor.bb:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION InputBox									;
; Parameters:                                       ;
; msg$ : any message to display above the input box ;
; x,y : top left coords                             ;
; width, height: outer width and height of inputbox ;
; rtnSubmit : if the return key is pressed, then    ;
;             automatically submit the text			;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function InputBox$(Msg$,x,y,width,height,rtnSubmit=True, DefaultText$="")

	SetFont Font
	
;;;;;;
;vars;
;;;;;;

	Local leave = False
	Local InnerWidth = Width - 6
	Local InnerHeight = Height - 40
	Local InnerX = 6
	Local InnerY = 20
	Local retString$ = ""
	Local fntWidth = FontWidth()/4
	Local fntHeight = FontHeight()
	Local EditWin = CreateImage(width, height)
	
;;;;;;
;main;
;;;;;;

If rtnSubmit Then InnerHeight = Height - 6
FlushKeys()
CaratPos = Len(DefaultText)
retString = retString+DefaultText

Repeat
	;quit the function without returning any text if escape is pressed
	If KeyHit(1) Then 
		leave = True
		retString$ = ""
	EndIf
	
	;;;;;;;;;;;;;;;;;;;;;
	;get character input;
	;;;;;;;;;;;;;;;;;;;;;
	get = GetKey()

	If Get = 13 Then
		If rtnSubmit Then 
			leave = True ;if return is pressed and rtnSubmit is True then leave
		Else
			retString$ = retString$ + Chr(get)
			CaratPos = CaratPos + 1
		EndIf
	ElseIf KeyDown(14); backspace
		If MilliSecs()-LastInput > KeyRepeat Then
			If Len(retString$) > 0 Then retString$ = Left$(retString$, Len(retString$) -1)		
			LastInput = MilliSecs()
			CaratPos = CaratPos - 1
			If CaratPos < 0 Then CaratPos = 0
		EndIf
	ElseIf KeyDown(203) ; Left Cursor
		If MilliSecs()-LastInput > KeyRepeat Then
			CaratPos = CaratPos - 1
			If CaratPos < 0 Then CaratPos = 0
			LastInput = MilliSecs()
			;DebugLog CaratPos
		EndIf
	ElseIf KeyDown(205) ; Right Cursor
		If MilliSecs()-LastInput > KeyRepeat Then
			CaratPos = CaratPos + 1
			If CaratPos > Len(retString$) Then CaratPos = Len(retString$)
			LastInput = MilliSecs()
			;DebugLog CaratPos
		EndIf
	ElseIf (get > 31) ;is a letter, number or symbol
		LeftSide$ = Left$(retString$,CaratPos)
		RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
		retString$ = LeftSide$ + Chr(get) + RightSide$;retString$ + Chr(get)
		CaratPos = CaratPos + 1
		;DebugLog CaratPos
	EndIf

		

		oldbuffer = GraphicsBuffer()
		SetBuffer ImageBuffer(EditWin)

			Color 160,160,160
			Rect 0,0,width,height

			Color 255,255,255
			Rect 2, 17, InnerWidth , InnerHeight

			Color 0,0,0
			
			Text width/2,8,msg,True,True
			

			;Draw Edit Content
			Local WCount% = 0
			Local LineCount% = 0
			Local CharCount% = 0
			Local tempString$ = ""
			Local tempString2$ = ""
			Local StringLength% = Len(retString$)
			Local CurrentChar$ = ""
			Local LineLength% = 0

			While CharCount < StringLength
				Repeat
					CharCount = CharCount + 1
					Currentchar$ = Mid$(retString$, CharCount,1)	
					If Charcount = CaratPos+1 Then tempString$ = tempString$ + CaratSymbol$
					tempString$ = tempString$ + CurrentChar$
					
					;DebugLog "CharCount: " + CharCount
					;DebugLog "CaratPos: " + CaraPos + "  " + CaratSymbol
					
					charWidth = CharWidths(Asc(CurrentChar))
					WCount = WCount + charWidth
				Until (WCount > InnerWidth - 8) Or (CharCount = StringLength) Or (Asc(CurrentChar) = 13)
				

				If Right$(tempString,1) = Chr(13) Then 
					tempString$ = Left(TempString$,Len(TempString$)-1)
				EndIf
				
				LineLength = LineLength + Len(tempString$)
				
				Color 0,0,0
				If (CaratPos = StringLength) And (CaratPos = CharCount) Then tempString = tempString + CaratSymbol
				Text InnerX,InnerY + (LineCount * fntHeight),tempString$,False,False
				

				LineCount = LineCount + 1

				tempString$  = ""
				tempString2$ = ""

				WCount = 0

			Wend
		
		SetBuffer OldBuffer
	
	DrawImage EditWin,x,y	
	
	If Not rtnSubmit Then
		If Button(x+(Width/2)-30,y+Height-20,60,"OK") Then leave = True
	EndIf
	
	Flip

Until leave = True

	FlushKeys()
	FlushMouse()
	FreeImage EditWin
	
	Return retString$


End Function

add the following after SetFont font:

;INPUT BOX SETUP
;Get the character widths
Dim charwidths(512)
	charwidths(32) = 4
	For c = 33 To 512
		charwidths(c) = StringWidth(Chr$(c))
	Next

Const KeyRepeat% = 100
Const CaratSymbol$ = "¦"

Global SelStart% = 0 
Global SelEnd% = 0
Global CaratPos% = 0

there's a slight bug in your script editing code that wipes the code if escape is pressed.

In the main loop change the RMB action to:

					For n=1 To CountString(objectdef(activetile2+1)\trigger,"|")
						trigger$=parse(objectdef(activetile2+1)\trigger,"|",n)
						newdef$ = InputBox("New Script for trigger: '"+trigger+"'. ESC or RETURN to end",20,20,500,300,True,objectdef(activetile2+1)\script[n])
						If Len(newDef) > 0 Then objectdef(activetile2+1)\script[n] = newdef$
					Next

the media.zip file is coming down as a 32kb corrupt zip.

As for the intex screens, maybe I can make something similar. I think the green used in the original is very cool as it symbolizes the old terminal screens.

might want to change the CaratSymbol actually because it clashes with the pipe character in the scripts.

Maybe change it to 0x166 ( ¦ )

Rims - the latest media pack is not working here :/ is the zip corrupted?

Sorry guys. I've uploaded it again. I may be coming to end of my bandwidth allowance. I've emailed Chad about borrowing some. I've uploaded the media.zip again, so it *should* work this time.

Done the carat symbol as well.

Added CTRL+ARROW Key to jump to next delimiter (delimiters are currently set as the pipe character, and the left and right brackets).

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION InputBox									;
; Parameters:                                       ;
; msg$ : any message to display above the input box ;
; x,y : top left coords                             ;
; width, height: outer width and height of inputbox ;
; rtnSubmit : if the return key is pressed, then    ;
;             automatically submit the text			;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function InputBox$(Msg$,x,y,width,height,rtnSubmit=True, DefaultText$="")

	SetFont Font
	
;;;;;;
;vars;
;;;;;;

	Local leave = False
	Local InnerWidth = Width - 6
	Local InnerHeight = Height - 40
	Local InnerX = 6
	Local InnerY = 20
	Local retString$ = ""
	Local fntWidth = FontWidth()/4
	Local fntHeight = FontHeight()
	Local EditWin = CreateImage(width, height)
	Local Delimiters$ = "|() "+Chr$(13)
	Local FoundDelim = False
	
;;;;;;
;main;
;;;;;;

If rtnSubmit Then InnerHeight = Height - 6
FlushKeys()
CaratPos = Len(DefaultText)
retString = retString+DefaultText

Repeat
	;quit the function without returning any text if escape is pressed
	If KeyHit(1) Then 
		leave = True
		retString$ = ""
	EndIf
	
	;;;;;;;;;;;;;;;;;;;;;
	;get character input;
	;;;;;;;;;;;;;;;;;;;;;
	get = GetKey()

	If Get = 13 Then
		If rtnSubmit Then 
			leave = True ;if return is pressed and rtnSubmit is True then leave
		Else
			LeftSide$ = Left$(retString$,CaratPos)
			RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
			retString$ = LeftSide$ + Chr(get) + RightSide$
			CaratPos = CaratPos + 1
		EndIf
	ElseIf KeyDown(14); backspace
		If MilliSecs()-LastInput > KeyRepeat Then
			If Len(retString$) > 0 Then 
				LeftSide$ = Left$(retString$,CaratPos)
				RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
				retString$ = Left$(LeftSide$, Len(LeftSide$) -1) + RightSide$
			EndIf
			LastInput = MilliSecs()
			CaratPos = CaratPos - 1
			If CaratPos < 0 Then CaratPos = 0
		EndIf
	ElseIf KeyDown(203) ;Left Cursor
		If MilliSecs()-LastInput > KeyRepeat Then
		
			If KeyDown(157) ; CTRL ; Allow CTRL+Left to jump the carat pos to the next delimiter to the left of the cursor
				For i = CaratPos To 1 Step -1
					
					d = 1
					While (d < Len(Delimiters$)+1) And (Not FoundDelim )	
						
						If Mid(retString$, i,1) = Mid(Delimiters$, d,1) Then 
							CaratPos = i-1
							FoundDelim = True
						EndIf
						d = d + 1
					
					Wend
				
					If FoundDelim Then Exit
				Next
				
				If Not FoundDelim Then CaratPos = CaratPos - 1
				If CaratPos < 0 Then CaratPos = 0
				
				FoundDelim = False
			
			Else
				CaratPos = CaratPos - 1
				If CaratPos < 0 Then CaratPos = 0
			EndIf
			LastInput = MilliSecs()
		EndIf
	ElseIf KeyDown(205) ; RIGHT CURSOR
		If MilliSecs()-LastInput > KeyRepeat Then
			If KeyDown(157) ;CTRL ; Allow CTRL+RIGHT to jump the carat pos to the next delimiter to the right of the cursor

				For i = CaratPos+1 To Len(retString$)
					d = 1					
					While (d < Len(Delimiters$)+1) And (Not FoundDelim )

						If Mid(retString$, i,1) = Mid(Delimiters$, d,1) Then 
							CaratPos = i
							FoundDelim = True
						EndIf
						d = d + 1
					Wend				

					If FoundDelim Then Exit
				Next
				
				If Not FoundDelim Then CaratPos = CaratPos + 1
				If CaratPos > Len(retString$) Then CaratPos = Len(retString$)
				
				FoundDelim = False
		
			Else
				CaratPos = CaratPos + 1
				If CaratPos > Len(retString$) Then CaratPos = Len(retString$)
			EndIf
			LastInput = MilliSecs()
		EndIf

	ElseIf KeyDown(207) ; end
		CaratPos = Len(retString$)
	ElseIf KeyDown(199) ; home
		CaratPos = 0
	ElseIf (get > 31) ;is a letter, number or symbol
		LeftSide$ = Left$(retString$,CaratPos)
		RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
		retString$ = LeftSide$ + Chr(get) + RightSide$;retString$ + Chr(get)
		CaratPos = CaratPos + 1
		
	EndIf

		

		oldbuffer = GraphicsBuffer()
		SetBuffer ImageBuffer(EditWin)

			Color 160,160,160
			Rect 0,0,width,height

			Color 255,255,255
			Rect 2, 17, InnerWidth , InnerHeight

			Color 0,0,0
			
			Text width/2,8,msg,True,True
			

			;Draw Edit Content
			Local WCount% = 0
			Local LineCount% = 0
			Local CharCount% = 0
			Local tempString$ = ""
			Local tempString2$ = ""
			Local StringLength% = Len(retString$)
			Local CurrentChar$ = ""
			Local LineLength% = 0

			While CharCount < StringLength

				Repeat
					CharCount = CharCount + 1
					Currentchar$ = Mid$(retString$, CharCount,1)	
					If Charcount = CaratPos+1 Then tempString$ = tempString$ + CaratSymbol$
					tempString$ = tempString$ + CurrentChar$
					charWidth = CharWidths(Asc(CurrentChar))
					WCount = WCount + charWidth
				Until (WCount > InnerWidth - 8) Or (CharCount = StringLength) Or (Asc(CurrentChar) = 13)

				If Right$(tempString,1) = Chr(13) Then 
					tempString$ = Left(TempString$,Len(TempString$)-1)
				EndIf

				LineLength = LineLength + Len(tempString$)

				Color 0,0,0
				If (CaratPos = StringLength) And (CaratPos = CharCount) Then tempString = tempString + CaratSymbol
				Text InnerX,InnerY + (LineCount * fntHeight),tempString$,False,False

				LineCount = LineCount + 1

				tempString$  = ""
				tempString2$ = ""

				WCount = 0

			Wend
		
		SetBuffer OldBuffer
	
	DrawImage EditWin,x,y	
	
	If Not rtnSubmit Then
		If Button(x+(Width/2)-30,y+Height-20,60,"OK",False,False,KEY_INSERT) Then leave = True
	EndIf
	
	Flip

Until leave = True

	FlushKeys()
	FlushMouse()
	FreeImage EditWin
	
	Return retString$


End Function

modified Function Button:

Function Button(x,y,width,name$,active=False, symbol=False, ShortCutKey=KEY_NONE)
;VARS
	Local result = False
	
;MAIN
	
	If RectsOverlap(MouseX(),MouseY(),1,1,x,y,width,16) Then Color 200,200,200 Else Color 160,160,160
	Rect x,y,width,16
	Color 0,0,0

	If Symbol Then SetFont symbFont
	If ShortCutKey > KEY_NONE Then name = name + " ("+ KeyNames(ShortCutKey) +")"
	Text x+width/2,y+7,name,True,True

	If Symbol Then SetFont Font

	If active Then Color 255,0,0:Rect x,y,width,16,False
	If RectsOverlap(MouseX(),MouseY(),1,1,x,y,width,16) And MouseDown(1) Then result = True

	If ShortCutKey > KEY_NONE Then
		If KeyDown(ShortCutKey) Then Result = True
	EndIf
	
	Return Result
	
End Function 

Added scancodes.bb to includes ( Include "inc\scancodes.bb" ):

Const KEY_NONE				= 0
Const KEY_ESCAPE			= 1
Const KEY_1					= 2
Const KEY_2					= 3
Const KEY_3					= 4
Const KEY_4					= 5
Const KEY_5					= 6
Const KEY_6					= 7
Const KEY_7					= 8
Const KEY_8					= 9
Const KEY_9					= 10
Const KEY_0					= 11
Const KEY_HYPHEN			= 12
Const KEY_EQUAL				= 13
Const KEY_BACKSPACE			= 14
Const KEY_TAB				= 15
Const KEY_Q					= 16
Const KEY_W					= 17
Const KEY_E					= 18
Const KEY_R					= 19
Const KEY_T					= 20
Const KEY_Y					= 21
Const KEY_U					= 22
Const KEY_I					= 23
Const KEY_O					= 24
Const KEY_P					= 25
Const KEY_BRACKET_LEFT		= 26
Const KEY_BRACKET_RIGHT		= 27
Const KEY_ENTER				= 28
Const KEY_CTRL_LEFT			= 29
Const KEY_A					= 30
Const KEY_S					= 31
Const KEY_D					= 32
Const KEY_F					= 33
Const KEY_G					= 34
Const KEY_H					= 35
Const KEY_J					= 36
Const KEY_K					= 37
Const KEY_L					= 38
Const KEY_SEMICOLON			= 39
Const KEY_APOSTROPHE		= 40
Const KEY_GRAVE				= 41
Const KEY_SHIFT_LEFT		= 42
Const KEY_BACKSLASH			= 43
Const KEY_Z					= 44
Const KEY_X					= 45
Const KEY_C					= 46
Const KEY_V					= 47
Const KEY_B					= 48
Const KEY_N					= 49
Const KEY_M					= 50
Const KEY_COMMA				= 51
Const KEY_PERIOD			= 52
Const KEY_SLASH				= 53
Const KEY_SHIFT_RIGHT		= 54
Const KEY_NUMPAD_MULTIPLY	= 55
Const KEY_ALT_LEFT			= 56
Const KEY_SPACE				= 57
Const KEY_CAPS_LOCK			= 58
Const KEY_F1				= 59
Const KEY_F2				= 60
Const KEY_F3				= 61
Const KEY_F4				= 62
Const KEY_F5				= 63
Const KEY_F6				= 64
Const KEY_F7				= 65
Const KEY_F8				= 66
Const KEY_F9				= 67
Const KEY_F10				= 68
Const KEY_NUM_LOCK			= 69
Const KEY_SCROLL_LOCK		= 70
Const KEY_NUMPAD_7			= 71
Const KEY_NUMPAD_8			= 72
Const KEY_NUMPAD_9			= 73
Const KEY_NUMPAD_HYPHEN		= 74
Const KEY_NUMPAD_4			= 75
Const KEY_NUMPAD_5			= 76
Const KEY_NUMPAD_6			= 77
Const KEY_PLUS				= 78
Const KEY_NUMPAD_1			= 79
Const KEY_NUMPAD_2			= 80
Const KEY_NUMPAD_3			= 81
Const KEY_NUMPAD_0			= 82
Const KEY_NUMPAD_PERIOD		= 83
Const KEY_F11				= 87
Const KEY_F12				= 88
Const KEY_F13				= 100
Const KEY_F14				= 101
Const KEY_F15				= 102
Const KEY_NUMPAD_EQUAL		= 141
Const KEY_NUMPAD_ENTER		= 156
Const KEY_CTRL_RIGHT		= 157
Const KEY_NUMPAD_SLASH		= 181
Const KEY_SYS_RQ			= 183
Const KEY_ALT_RIGHT			= 184
Const KEY_PAUSE				= 197
Const KEY_HOME				= 199
Const KEY_ARROW_UP			= 200
Const KEY_PAGE_UP			= 201
Const KEY_ARROW_LEFT		= 203
Const KEY_ARROW_RIGHT		= 205
Const KEY_END				= 207
Const KEY_ARROW_DOWN		= 208
Const KEY_PAGE_DOWN			= 209
Const KEY_INSERT			= 210
Const KEY_DELETE			= 211
Const KEY_WINDOWS_LEFT		= 219
Const KEY_WINDOWS_RIGHT		= 220

Dim Keynames$(220)
For n = 0 To 220
	Keynames(n)= "Unknown"
Next
	Keynames(1)= "Escape"
	Keynames(2)= "1"
	Keynames(3)= "2"
	Keynames(4)= "3"
	Keynames(5)= "4"
	Keynames(6)= "5"
	Keynames(7)= "6"
	Keynames(8)= "7"
	Keynames(9)= "8"
	Keynames(10)= "9"
	Keynames(11)= "0"
	Keynames(12)= "-"
	Keynames(13)= "="
	Keynames(14)= "Backspace"
	Keynames(15)= "Tab"
	Keynames(16)= "Q"
	Keynames(17)= "W"
	Keynames(18)= "E"
	Keynames(19)= "R"
	Keynames(20)= "T"
	Keynames(21)= "Y"
	Keynames(22)= "U"
	Keynames(23)= "I"
	Keynames(24)= "O"
	Keynames(25)= "P"
	Keynames(26)= "["
	Keynames(27)= "]"
	Keynames(28)= "Return"
	Keynames(29)= "Left Ctrl"
	Keynames(30)= "A"
	Keynames(31)= "S"
	Keynames(32)= "D"
	Keynames(33)= "F"
	Keynames(34)= "G"
	Keynames(35)= "H"
	Keynames(36)= "J"
	Keynames(37)= "K"
	Keynames(38)= "L"
	Keynames(39)= ";"
	Keynames(40)= "'"
	Keynames(41)= "#";UK Keyboard
	Keynames(42)= "Left Shift"
	Keynames(43)= ""
	Keynames(44)= "Z"
	Keynames(45)= "X"
	Keynames(46)= "C"
	Keynames(47)= "V"
	Keynames(48)= "B"
	Keynames(49)= "N"
	Keynames(50)= "M"
	Keynames(51)= ","
	Keynames(52)= "."
	Keynames(53)= "/"
	Keynames(54)= "Right Shift"
	Keynames(55)= "Numpad *"
	Keynames(56)= "Left Alt"
	Keynames(57)= "Space"
	Keynames(58)= "Caps Lock"
	Keynames(59)= "F1"
	Keynames(60)= "F2"
	Keynames(61)= "F3"
	Keynames(62)= "F4"
	Keynames(63)= "F5"
	Keynames(64)= "F6"
	Keynames(65)= "F7"
	Keynames(66)= "F8"
	Keynames(67)= "F9"
	Keynames(68)= "F10"
	Keynames(69)= "Num Lock"
	Keynames(70)= "Scroll Lock"
	Keynames(71)= "Numpad 7"
	Keynames(72)= "Numpad 8"
	Keynames(73)= "Numpad 9"
	Keynames(74)= "Numpad -"
	Keynames(75)= "Numpad 4"
	Keynames(76)= "Numpad 5"
	Keynames(77)= "Numpad 6"
	Keynames(78)= "Numpad +"
	Keynames(79)= "Numpad 1"
	Keynames(80)= "Numpad 2"
	Keynames(81)= "Numpad 3"
	Keynames(82)= "Numpad 0"
	Keynames(83)= "Numpad ."

	Keynames(87)= "F11"
	Keynames(88)= "F12"

	Keynames(100)= "F13"
	Keynames(101)= "F14"
	Keynames(102)= "F15"
	
	Keynames(141)= "Numpad ="
	
	Keynames(156)= "Numpad Enter"
	Keynames(157)= "Right Ctrl"
	
	Keynames(181)= "Numpad /"
	
	Keynames(183)= "Sys RQ"
	Keynames(184)= "Right Alt"
	
	Keynames(197)= "Pause"
	
	Keynames(199)= "Home"
	Keynames(200)= "Up Arrow"
	Keynames(201)= "Page Up"
	
	Keynames(203)= "Left Arrow"
	
	Keynames(205)= "Right Arrow"
	
	Keynames(207)= "End"
	Keynames(208)= "Down Arrow"
	Keynames(209)= "Page Down"
	Keynames(210)= "Insert"
	Keynames(211)= "Delete"
	
	Keynames(219)= "Left Windows"
	Keynames(220)= "Right Windows"

modified code in main loop to test new button:

	If Button(650,300,140,"Save",False,False,KEY_F1) Then saveBlitzVersion()
	If Button(650,320,140,"Load",False,False,KEY_F2) Then loadBlitzVersion()

And it works!

*EDIT*

changed layer buttons in main loop to have number keys for shortcuts:

	For n=0 To NumLayers
		If activelayer=n Then act=True Else act=False
		If Button(650,n*20,100,layername(n),act,False,n+2) Then
			activelayer=n
			If activeLayer = LayerObject Then tileoffset = 0
		EndIf
		
		
		If Button(760,n*20,30,"Vis",visible(n))
			visible(n)=(visible(n)+1) Mod 2
			Repeat:Until MouseDown(1)=False
		EndIf
	Next

I can host the files on my server if you like, I have an enormously large amount of bandwidth (i.e. unlimited).

When I try to open the red door that leads into the central room, I get:



All the other doors I've tried open fine.
If I create a new red door in front of or behind that door, I get the same error.
If I create one further up the map, it opens fine.

I'm a tad confused with this one.

Added LoadLast function and changed Load Old to Load Last:

Function LoadLast()
	FileIn = ReadFile("prefs.txt")
		FileName$ = ReadString(FileIn)
	CloseFile(FileIn)
	If Len(FileName$) > 0 Then Load(FileName$)
End Function

in SaveBlitzVersion after the save command, add:

	
	;Save last file name
	fileout = WriteFile("prefs.txt")
		WriteString fileout,FileName$
	CloseFile(fileout)

Change the buttons at the end of the main loop to:

	If Button(650,280,140,"New",False,False,KEY_F8) Then createRandomMap()
	If Button(650,300,140,"Save",False,False,KEY_F1) Then saveBlitzVersion()
	If Button(650,320,140,"Load",False,False,KEY_F4) Then loadBlitzVersion()
	If Button(650,340,140,"Load Last",False,False,KEY_F5) Then LoadLast()

Updated lighting on intex consoles in objects.png:

<object image in media.zip>

new map.obj:

total objects = 28

image = 0
trigger = onover()
description = Ammo
addammo(50)|remove(me)

image = 1
trigger = onover()
description = Health
addhealth(10)|playsoundonce(health_pickup)|remove(me)

image = 2
trigger = onover()
description = Key (yellow)
addkey(1)|playsoundonce(key_pickup)|remove(me)

image = 3
trigger = onover()
description = Key (red)
addkey(2)|playsoundonce(key_pickup)|remove(me)

image = 4
trigger = onover()
description = Key (green)
addkey(3)|playsoundonce(key_pickup)|remove(me)

image = 5
trigger = onover()
description = Key (blue)
addkey(4)|playsoundonce(key_pickup)|remove(me)

image = 6
trigger = ontouch()|ondestroy()
description = Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)

image = 7
trigger = ontouch()|ondestroy()
description = Door (yellow)
checkkey(1)|opendoor()|remove(nearby)
opendoor()|remove(nearby)

image = 8
trigger = onover()
description = 100 Credit
addcredit(100)|remove(me)

image = 9
trigger = onover()
description = 50 Credit
addcredit(50)|remove(me)

image = 10
trigger = onover()
description = 10 Credit
addcredit(10)|remove(me)

image = 11
trigger = ontouch()
description = Door (red)
checkkey(2)|opendoor()|remove(nearby)

image = 12
trigger = ontouch()
description = Door (red)
checkkey(2)|opendoor()|remove(nearby)

image = 13
trigger = ontouch()
description = Door (blue)
checkkey(4)|opendoor()|remove(nearby)

image = 14
trigger = ontouch()
description = Door (blue)
checkkey(4)|opendoor()|remove(nearby)

image = 15
trigger = ontouch()
description = Door (green)
checkkey(3)|opendoor()|remove(nearby)

image = 16
trigger = ontouch()
description = Door (green)
checkkey(3)|opendoor()|remove(nearby)

image = 17
trigger = onaction()
description = Intex System
intex()

image = 18
trigger = onaction()
description = Intex System
intex()

image = 19
trigger = onaction()
description = Intex System
intex()

image = 20
trigger = onaction()
description = Intex System
intex()

image = 21
trigger = onover()
description = weapon (Broadhurst DJ Twinfire 3LG) [image
pickupweapon(1)|remove(me)

image = 22
trigger = onover()
description = weapon (Dalton Arc Flame) [image
pickupweapon(2)|remove(me)

image = 23
trigger = onover()
description = weapon (Ryxx Firebolt MK22) [image
pickupweapon(3)|remove(me)

image = 24
trigger = onover()
description = weapon (Styrling Multimatic) [image
pickupweapon(4)|remove(me)

image = 25
trigger = onover()
description = weapon (High Impact Astro Laser) [image
pickupweapon(5)|remove(me)

image = 0
trigger = 
description = 


image = 0
trigger = 
description = 

Regarding the door issue, if you approach a door from the right or above, it will open fine, if you try to open it from the left or below, it causes the runtime error.
It would appear to be offset by one tile when approached from these sides.

ok, solved it, in players.bb - Player_UpdateAll modify the collision code to:

	; Object Collision (walls, doors etc)
	If mr Then
		If gettile(pl\x+playerradius,pl\y,0)=0 Then
			If control(pstrafe,Player_Count+1)=0 Then pl\x=pl\x+1
			move=True
		EndIf
		tile=map((pl\x+playerradius)/32,pl\y/32,LayerObject)
		If tile>0 Then
			If Instr(objectdef(tile)\trigger,ScriptTrigger_OnTouch) 
				RunScript(pl,objectdef(tile),ScriptTrigger_OnTouch,pl\x+playerradius,pl\y)
			EndIf
		End If
		direct=direct+"R"
	End If
	If ml Then 
		If gettile(pl\x-playerradius,pl\y,0)=0 Then 
			If control(pstrafe,Player_Count+1)=0 Then pl\x=pl\x-1
			move=True	
		End If
		tile=map((pl\x-playerradius)/32,pl\y/32,LayerObject)
		If tile>0 Then
			If Instr(objectdef(tile)\trigger,ScriptTrigger_OnTouch) Then RunScript(pl,objectdef(tile),ScriptTrigger_OnTouch,pl\x-playerradius,pl\y)
		End If
		direct=direct+"L"
	End If
	If mu Then
		If gettile(pl\x,pl\y-playerradius,0)=0 Then 
			If control(pstrafe,Player_Count+1)=0 Then pl\y=pl\y-1
			move=True
		End If
		tile=map(pl\x/32,(pl\y-playerradius)/32,LayerObject)
		If tile>0 Then
			If Instr(objectdef(tile)\trigger,ScriptTrigger_OnTouch) Then RunScript(pl,objectdef(tile),ScriptTrigger_OnTouch,pl\x,pl\y-playerradius)
		End If
		direct=direct+"U"
	End If
	If md Then 
		If gettile(pl\x,pl\y+playerradius,0)=0 Then 
			If control(pstrafe,Player_Count+1)=0 Then pl\y=pl\y+1
			move=True
		End If	
		tile=map(pl\x/32,(pl\y+playerradius)/32,LayerObject)
		If tile>0 Then
			If Instr(objectdef(tile)\trigger,ScriptTrigger_OnTouch) Then RunScript(pl,objectdef(tile),ScriptTrigger_OnTouch,pl\x,pl\y+playerradius)
		End If
		direct=direct+"D"
	End If

It was adding the playerradius to p1\y in all directions except Right.

*EDIT*
Also in script.bb - RunScript

the opendoor case should really floor() the x and y values:

			Case "opendoor"
				opendoor(Floor(x/32),Floor(y/32))

Looks like some good progress has been made - and some good fixes for my stupid mistakes! ;-)

As for the line of credits and vis - I think I stuffed up DamageTile. Currently, if a map tile is marked as destructible, and there is no OBJECT present, then the tile will not be detroyed. Equally, if there IS an object present, but it doesn't have an ondestroy() trigger, or actions within the object script that will auto 'CheckVis()' like the opendoor() script command, then it won't sort things out. I don't have time now, but will try to fix this later unless someone else beats me to it...I think it's just restructuring the If block and adding CheckVis() to code rather than rely on the script.

I'll also look at adding an action key too, such that we can get the intex systems working properly...

Guys,

I'm currently working on an Intex systems console - will have something to update hopefully around this time tomorrow night.

Is there a way currently to attach the same script to multiple objects?
i.e. have a generic explode me on destroy script and attach it to barrels, vents, computers.

I don't necessarily mean in the editor, but has provision been made for this in the script section?

I *think*, according to the way mark's done it, a new script will have to be made for each. So you'll have a script and image for an exploding barrel; a script and image for an exploding red barrel, etc.

But you only have to do this once and it can be reused, so it's sort of a long way of doing it for a shorter production time kind of thing. I prefer it this way.

Looking forward to seeing what you've got for the intex, Matt. As for the hosting, yeah Perty, if I could pass the torch to you for now... how should we go about this? You take my position as keeper of the code? I'll make a final update...

I'm thinking we should sign up for a SourceForge account, that way it makes it easier to update the project and they will host it.
And if I understand how it works correctly, then there's a CVS service as well, which would make an individual code keeper unnecessary.
I can't guarantee that I will be able to regularly update the code you see.
I have however hosted the media and music on my site (see my sig)

ahhh, good idea. I'm not sure how sourceforge works. I've seen it before but not really had a look. I'll read up on it tonight. Go ahead and sign up, I'm all for it. What about you other guys?

SourceForge sounds good, although I've never used it. I guess we need to check out the T&C...

As for reuse of scripting, and your example of exploding barrels, I'd see this as:

Implement a 'bigexplosion()' command in runscript to do the whole graphical explosion thing, and add 'big_explosion' as a sound to 'playsoundonce()'. Then for each object definition that needs to use it (barrel, vent, computer) they each have the ondestroy() trigger pointing at a script that says 'bigexplosion()|playsoundonce(big_explosion)'. So yes, each object definition needs to have it's own copy of the script, but the script commands should be at a high enough level that reuse isn't a problem.

Oh, and another scripting command that would be nice to add to the end of that: destroy(nearby). i.e. ondestroying one barrel, we trigger the destroy script for any nearby barrels! woohoo! I think I might implement that command soon... ;-)

As I understand the T&C, you need to actually be developing an open source project that complies with these restrictions:
http://opensource.org/docs/definition.php

how about destroy(nearby|<Radius>) i.e. only destroy items within the specified radius (in tiles).

on another note, it might be a good idea to move the GUI functions of the editor into an include, so that they and any future ones can be used in the main game if necessary.

i.e. We can have GUI functions for the intex system in the same file and usuable anywhere.

Pert, good idea (both the radius and GUI stuff). In fact, if we go with SourceForge (and having read the details, I don't see any reason not too ; this is effectively an open source project), it's probably better in some ways if we have as many separate files as possible (within reason!).

yes, that was another reason for my suggestion, it means someone can add GUI stuff without blocking access to the main editor code.

*EDIT*

We do need to decide which license to use though. I don't know enough about the specifics of the license to make a suggestion at the moment.
Presumably we want one that prevents someone else from selling the source or a compiled product without the explicit permission from the copyright holders?

Ok, I've separated the gui as much as I can just now, I'm going to have to go out soon. I had trouble with the fonts for some reason, although they may not need to be separated anyway.

In editor, change the top section to:

; blitz3d version

; keys

; arrow keys move around map
; pgup/pgdown scroll through tiles
; return - pick up tile
; numpad4 - place a ground of 4 squares starting with the selected tile ie 12
;                                                                          34
; Space - Promote background tile to a over block tile

Global LastInput = MilliSecs()

Include "inc\scancodes.bb"
Include "inc\sounds.bb"
Include "inc\consts.bb"
Include "inc\gui.bb"
Include "inc\map.bb"
Include "inc\editor include.bb"
Include "inc\util.bb"


Graphics 800,600,32,0
SetBuffer BackBuffer()



loadGraphics() ; both version use this.

;had trouble when moving these to gui (symbFont did not exist for some reason)
Global font = LoadFont("Arial.ttf",15)
Global symbFont = LoadFont("Symbol.ttf",15)

InitGUI()


createRandomMap()

gui.bb:

;Global font = LoadFont("Arial.ttf",15)
;Global symbFont = LoadFont("Symbol.ttf",15)

Dim CharWidths(1)

Global SelStart% = 0 
Global SelEnd% = 0
Global CaratPos% = 0

Const KeyRepeat% = 100
Const CaratSymbol$ = "¦"


;;;;;;;;;;;;;;;;;;;;
; FUNCTION InitGUI ;
;;;;;;;;;;;;;;;;;;;;
Function InitGUI()

	SetFont font


;INPUT BOX SETUP
;Get the character widths
Dim charwidths(512)
	charwidths(32) = 4
	For c = 33 To 512
		charwidths(c) = StringWidth(Chr$(c))
	Next
End Function


;;;;;;;;;;;;;;;;;;;
; FUNCTION Button ;
;;;;;;;;;;;;;;;;;;;

Function Button(x,y,width,name$,active=False, symbol=False, ShortCutKey=KEY_NONE, ShowShortCut = True)
;VARS
	Local result = False
	
;MAIN
	
	If RectsOverlap(MouseX(),MouseY(),1,1,x,y,width,16) Then Color 200,200,200 Else Color 160,160,160
	Rect x,y,width,16
	Color 0,0,0

	If Symbol Then SetFont symbFont

	If (ShortCutKey > KEY_NONE) And (ShowShortCut) Then name = name + " ("+ KeyNames(ShortCutKey) +")"

	Text x+width/2,y+7,name,True,True

	If Symbol Then SetFont Font

	If active Then Color 255,0,0:Rect x,y,width,16,False
	If RectsOverlap(MouseX(),MouseY(),1,1,x,y,width,16) And MouseDown(1) Then result = True

	If ShortCutKey > KEY_NONE Then
		If KeyDown(ShortCutKey) Then Result = True
	EndIf
	
	Return Result
	
End Function 



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FUNCTION InputBox									;
; Parameters:                                       ;
; msg$ : any message to display above the input box ;
; x,y : top left coords                             ;
; width, height: outer width and height of inputbox ;
; rtnSubmit : if the return key is pressed, then    ;
;             automatically submit the text			;
;             If this is false, then an OK button is;
;             displayed at the bottom of the box    ;
; DefaultText : automatically inserts this into the ;
; input box, the carat will be positioned at the end;
; of this text.                                     ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Function InputBox$(Msg$,x,y,width,height,rtnSubmit=True, DefaultText$="")

	SetFont Font

;;;;;;
;vars;
;;;;;;

	Local leave = False
	Local InnerWidth = Width - 6
	Local InnerHeight = Height - 40
	Local InnerX = 6
	Local InnerY = 20
	Local retString$ = ""
	Local fntWidth = FontWidth()/4
	Local fntHeight = FontHeight()
	Local EditWin = CreateImage(width, height)
	Local Delimiters$ = "|() "+Chr$(13)
	Local FoundDelim = False
	Local TopLine = 0
;;;;;;
;main;
;;;;;;

If rtnSubmit Then InnerHeight = Height - 6
FlushKeys()
CaratPos = Len(DefaultText)
retString = retString+DefaultText

Repeat
	;quit the function without returning any text if escape is pressed
	If KeyHit(1) Then 
		leave = True
		retString$ = ""
	EndIf
	
	;;;;;;;;;;;;;;;;;;;;;
	;get character input;
	;;;;;;;;;;;;;;;;;;;;;
	get = GetKey()

	If Get = 13 Then
		If rtnSubmit Then 
			leave = True ;if return is pressed and rtnSubmit is True then leave
		Else
			LeftSide$ = Left$(retString$,CaratPos)
			RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
			retString$ = LeftSide$ + Chr(get) + RightSide$
			CaratPos = CaratPos + 1
		EndIf
	ElseIf KeyDown(14); backspace
		If MilliSecs()-LastInput > KeyRepeat Then
			If Len(retString$) > 0 Then 
				LeftSide$ = Left$(retString$,CaratPos)
				RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
				retString$ = Left$(LeftSide$, Len(LeftSide$) -1) + RightSide$
			EndIf
			LastInput = MilliSecs()
			CaratPos = CaratPos - 1
			If CaratPos < 0 Then CaratPos = 0
		EndIf
	ElseIf KeyDown(203) ;Left Cursor
		If MilliSecs()-LastInput > KeyRepeat Then
		
			If KeyDown(157) ; CTRL ; Allow CTRL+Left to jump the carat pos to the next delimiter to the left of the cursor
				For i = CaratPos To 1 Step -1
					
					d = 1
					While (d < Len(Delimiters$)+1) And (Not FoundDelim )	
						
						If Mid(retString$, i,1) = Mid(Delimiters$, d,1) Then 
							CaratPos = i-1
							FoundDelim = True
						EndIf
						d = d + 1
					
					Wend
				
					If FoundDelim Then Exit
				Next
				
				If Not FoundDelim Then CaratPos = CaratPos - 1
				If CaratPos < 0 Then CaratPos = 0
				
				FoundDelim = False
			
			Else
				CaratPos = CaratPos - 1
				If CaratPos < 0 Then CaratPos = 0
			EndIf
			LastInput = MilliSecs()
		EndIf
	ElseIf KeyDown(205) ; RIGHT CURSOR
		If MilliSecs()-LastInput > KeyRepeat Then
			If KeyDown(157) ;CTRL ; Allow CTRL+RIGHT to jump the carat pos to the next delimiter to the right of the cursor

				For i = CaratPos+1 To Len(retString$)
					d = 1					
					While (d < Len(Delimiters$)+1) And (Not FoundDelim )

						If Mid(retString$, i,1) = Mid(Delimiters$, d,1) Then 
							CaratPos = i
							FoundDelim = True
						EndIf
						d = d + 1
					Wend				

					If FoundDelim Then Exit
				Next
				
				If Not FoundDelim Then CaratPos = CaratPos + 1
				If CaratPos > Len(retString$) Then CaratPos = Len(retString$)
				
				FoundDelim = False
		
			Else
				CaratPos = CaratPos + 1
				If CaratPos > Len(retString$) Then CaratPos = Len(retString$)
			EndIf
			LastInput = MilliSecs()
		EndIf

	ElseIf KeyDown(207) ; end
		CaratPos = Len(retString$)
	ElseIf KeyDown(199) ; home
		CaratPos = 0
	ElseIf (get > 31) ;is a letter, number or symbol
		LeftSide$ = Left$(retString$,CaratPos)
		RightSide$ = Right$(retString$, Len(RetString)-CaratPos)
		retString$ = LeftSide$ + Chr(get) + RightSide$;retString$ + Chr(get)
		CaratPos = CaratPos + 1
		
	EndIf

		
		;Draw the edit window
		oldbuffer = GraphicsBuffer()
		SetBuffer ImageBuffer(EditWin)

			Color 160,160,160
			Rect 0,0,width,height

			Color 255,255,255
			Rect 2, 17, InnerWidth , InnerHeight

			Color 0,0,0
			
			Text width/2,8,msg,True,True
			

			;Draw Edit Content
			Local WCount% = 0
			Local LineCount% = 0
			Local CharCount% = 0
			Local tempString$ = ""
			Local tempString2$ = ""
			Local StringLength% = Len(retString$)
			Local CurrentChar$ = ""
			Local LineLength% = 0

			While CharCount < StringLength

				Repeat
					CharCount = CharCount + 1
					Currentchar$ = Mid$(retString$, CharCount,1)	
					If Charcount = CaratPos+1 Then tempString$ = tempString$ + CaratSymbol$
					tempString$ = tempString$ + CurrentChar$
					charWidth = CharWidths(Asc(CurrentChar))
					WCount = WCount + charWidth
				Until (WCount > InnerWidth - 8) Or (CharCount = StringLength) Or (Asc(CurrentChar) = 13)

				If Right$(tempString,1) = Chr(13) Then 
					tempString$ = Left(TempString$,Len(TempString$)-1)
				EndIf

				LineLength = LineLength + Len(tempString$)

				Color 0,0,0
				If (CaratPos = StringLength) And (CaratPos = CharCount) Then tempString = tempString + CaratSymbol
				Text InnerX,InnerY + (LineCount * fntHeight),tempString$,False,False

				LineCount = LineCount + 1

				tempString$  = ""
				tempString2$ = ""

				WCount = 0

			Wend
		
		SetBuffer OldBuffer
	
	DrawImage EditWin,x,y	
	
	If Not rtnSubmit Then
		If Button(x+(Width/2)-30,y+Height-20,60,"OK",False,False,KEY_INSERT) Then leave = True
	EndIf
	
	Flip

Until leave = True

	FlushKeys()
	FlushMouse()
	FreeImage EditWin
	
	Return retString$


End Function

Reading sourceforge docs now. In the end I haven't made any changes since my last update, anyone else who wants to take a stab at them feel free, I may not get much time to code (but will pop in to discuss) over the next couple of days...

Oh, and as for licenses, I'm perfectly happy that whatever we do is open source, but I agree that I would only want it to be used in non-commercial works without permission. Isn't that the essence of the GPL? The sourceforge don't *include* the GPL, but do their terms *preclude* us applying the GPL? Still reading...

Okay, so as I understand SourceForge, their T&C essentially just force you to make it open source, and to distribute code with everything (or make available). They then allow you to use a number of different licenses for your software, including the GNU General Public License.

I've read the SourceForge T&C, Open Source definition (required by the T&C) and the GNU GPL and am happy with them. They embody the sentiments above of myself, and, I think Perturbatio. I suggest all others take a look at these documents and post whether they're happy with them.

GNU General Public License
GPL FAQ
SourceForge T&C
Open Source Definition (part of SF's T&C)

Provided there's no problems, then I'll submit the new project (I've registered today) Tuesday / Wednesday about 2000 GMT. And if we (Rob?) decides otherwise later on, we can always take the project off SourceForge, and only the version as it stands at that point remains 'open-sourced' or 'GPL'ed' - at least that's how I read it!

I'm confused by all the licence speak, but does this mean anyone can download, compile and sell this project? I'd be a bit miffed if that happened.

Wow. What you guys are doing here is really amazing. Who knew a 2D game could be so cool?

I would suggest that anyone that has not already added something to this, delay in doing so until we have decided upon the license we are going to use.
(so that they can be sure they want to adhere to that license).

I'm a little confused by the whole GPL thing actually, if we offer the source and binaries for free, as far as I can tell, under the GPL any person who receives these can then charge for them. This isn't what I thought the GPL did.

I would like it to be that we offer the source and binaries for free, and no one can charge for the source or modified source or binaries.

*EDIT*
Basically and Open-Source Free of Charge and free to modify software license.

The way I read it:
I think anyone can charge a reasonable fee for redistribution, but not sell it as such. i.e. a CD packed full of free games can be sold in shops for £5 on the basis of redistribution costs, but just hosting the software as a standalone download wouldn't allow a charge to be levied.

If someone wanted to include the software within another piece of software, then provided that software is not a derivative work (i.e. not just changing the gfx and code a bit to create a slightly different game, but say as a demo in the BlitzMax distro), a fee can be charged for the package as a whole.

Derivative works must retain the same license.

I think the GPL FAQ covers a lot of these, and I intend to read that over the next few days (I've only read the license itself).

The GPL FAQ doesn't seem to cover what happens if someone sells software that was originally released without charge.

It covers the inverse (i.e. people can distribute it without charge, even if we were to charge for the initial download).

Okay, I've read the GPL FAQ, and I'm happy. Specifically:

*Modified versions*

Any modified version is bound by the GPL. This means it can be distributed *under the GPL*, i.e. for free and must make source code available.

*Charging*

Even if someone chooses to charge a fee for it, or a derivative work, anyone who purchases that copy may a) distribute that same version FREE b) request, and distribute the source of that version. Effectively, the GPL renders the sale of versions worthless, as any purchasers can then redistribute the same thing for free! So while charging for copies is not ruled out, they won't make much money out of it!

*Creating a non-GPL version*

Essentially, only the copyright holders can choose to distribute a non-free version of the software. I suggest we all claim joint copyright to each module of code. We can, or someone else can, *by mutual consent from all copyright holders*, choose to create a non-free version. i.e. if we collectively decide to take the code and make a commercial game from it, provided we *all* agree, we can. However, anyone could still gain access to the original GPL version if they so wish, so it'd have to be sufficiently different to justify someone buying that new version. (I'm not suggesting we want to do this, but it's not precluded in the agreement...)

Hope that answers everyone's key questions - it does mine!

Heh, cross post Pert'!

I reckon that section that you posted renders the sale worthless. If someone is selling a version (modified or unmodified), then anyone else can buy it and distribute it under the GPL, i.e. FOR FREE. The sold version must include the GPL, which states that it can be distributed FOR FREE. The seller, unless it's a really hot game, and no-one catches on for some time, is therefore unlikely to make much money out of our work. They might make a little, but nothing worth worrying about.

While I personally would prefer an explicitly statement of 'no charge', I think the reasons for doing it the way they have done, while complex, are reasonable.

yeah alright, sounds fair enough to me.

Yeah I suppose that's reasonably safe, but what we could do is have a statement like 'This software is provided "As Is" free of charge by the copyright holders under the GNU GPL' on the loading screen so that our intent is plainly obvious.

http://www.cvsdude.org/ does free CVS and SubVersion hosting if you don't want to use SourceForge. I haven't used it, but heard it's very good.

Part of the GNU GPL actually includes a formal statement regrding 'fitness for purpose' etc, so even that's covered! Also, it requires that anyone publishing a modified version must clearly attribute their name to their changes, so as not to damage the reputation of the original authors.

Ty, thanks for the link; however I think we do need to get a copyright & license statement in there even if we go with somewhere that doesn't require it. i.e. some protection is better than none. (and before someone points it out, yes I know copyright always holds unless it's stated as public domain, I think we need a statement of some form, and GPL does it for me)

I think we should wait until Rob gets back though before doing this - it was his code base, and so mainly his copyright: I don't believe we have any right to issue this under any license without his say-so.

In the meantime, if you're happy with the GNU GPL, code away! Let's not let this hold up the good work we've done!

Great stuff, looking cooler each time :)

Suggest we post some screenies in the gallery, and link to those from the top of the thread if we're having bandwidth problems...

Mark, could you please do it? I keep getting weird file not found, jpeg not detected errors when it's clearly a jpg and I've clearly selected the file. Perhaps it's a firewall issue. I doubt it though.

Will try tonight when I get home from work...

I can't submit one either, I even tried saving a JPG from a program other than photoshop and it still can't read the image.

feel free to link to this image at the top of this thread:

<image link removed since it's been added>

Yeah, weird innit? Could you email me your email address perty so I can send you the latest code to host temporarily until we get this sourceforge up and running?

email sent.

I'm currently attempting to rewrite the InputBox so that it's more organised, it's a bit of a kludge at the moment.

I've noticed a problem with the editor.

You can't create a new map without an obj file for it, since it won't allow you to add an object without a script for it.

latest code in my sig.

Mmmm, yeah. Maybe we can have an obj import button as well. Or a default obj file to import and edit.

A default OBJ file is probably the best idea, including all the basics (doors, keys, exploding barrels, etc.).

What you could do, is have the load function assume that if there is no OBJ file, then use "default.obj" and rename our current OBJ file to that. It's likely we'll be building up the basic OBJ file for now anyway until we start creating maps for the story with scripted events...

Yes, a default OBJ would be a good way to do it, but it also needs to be done on new.

simple graphic for Alien Queen:

I think Rims should post a link to the zip right at the top of this page so people can easily find which is the latest version to download.

when do you suppose this will be done? looks GREAT!

Hi guys,

Sorry, been really busy and work and cricket this week. Have most of the weekend off so am trying to finish the intex menu - have got quite a bit done and it seems to work quite well.

Really nice game. It is normal when i shot then i have no shoot sfx ? And the walk is not really good, i can`t see the feeds from the player and he walk so strong with your body left and right. But it is a cool game.

Regards Blitzblaster

another weapon has been added that has no sfx and the bullets fire way too slowly, the default weapon should have sound and be fast firing.

3 days without anyone posting... not good guys... time to get some momentum going again.

Rims, is the latest update the downloads at the top, you've not posted recently so just curious if I need to hack in any code or if the zips bring me 100% up to date.

Is the todo list at the top up to date?

I've got a bit of reading to do to see what's been going on so I'll take a look at where we are this evening.

As far as I know, no code updates have been made since the latest upload to my server. (links at top and in my sig).

I have started work on more GUI stuff, but it's going a little slower than I would've liked since I have other things in my life to sort out as well.

What's the date of those uploads? Just need to know if those zips are up to date or if code from this thread needs adding in.

Yeah, they're about as up to date as possible. We've been considering moving this to sourceforge (read up a bit) so I've made no modifications to the code on my end. What are your thoughts rob? We've got no bandwidth problems at the moment since perty's taken the load but with regards to updating and such perhaps we should move to sourceforge.

Hey Rob, good holiday?

Been a bit busy myself recently, but hope to have some time in the next couple of days, although I'm away again over the weekend. To be honest, I was kind of waiting for your return to kick off the whole license / source control discussion again. What are your thoughts?

Rims, No ideas about sourceforge as I have no experience of it... I'll look into it.

Mark, yep thanks. I'll look into some of the discussions in more detail later. From what I've seen from them it looks like there are some perfect legal doobies there that we just need to add to the zips.

Guys,

Note: I have also e-mailed each of you the images as I don't have anywhere to host as yet.


Here's the start of the Intex Systems I've been working on:

Create 'Intex-new.bb'

;Images 
Global intexBackground = LoadImage("gfx\intex-background-sm.png")
Global intexFrame = LoadImage("gfx\intex-frame.png")
Global intexText = LoadAnimImage("gfx\intex-text-sm.png",8,11,0,40)
MaskImage intexText,255,0,255
;Global intexWeapon = LoadAnimImage("gfx\intex-weapons.png",320,88,0,6)
;MaskImage intexWeapon,255,0,255

Global intexChars$ = "*ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789.:?"
Const pauseMax = 75
Const maxLines = 20

Const charWidth = 8
Const xOffset = 146
Const yOffset = 100

Type MenuSystem
	Field id
	Field build
	Field bChar
	Field bLine
	Field menuText$[maxLines]
	Field x[maxLines]
	Field y[maxLines]
	Field subMenu[maxLines]
	Field highlight[maxLines]
	Field total
	Field pauseCounter
	Field cursorRow
	Field cursorX
	Field cursorY
	Field bCharCounter
	
End Type

Global intexMenu.MenuSystem

Function IntexMenu(pl.player)
	Local currentMenu = 0
	Local exitMenu = False
	Local preBootCounter = 0
	Local menuUpdateCounter
	
	;Create a menu store
	intexMenu.MenuSystem = New MenuSystem
	
	;Get the boot text
	GetMenuText(currentMenu,pl)
	
	While Not KeyHit(1) Or exitMenu = True
		;Set buffer
		SetBuffer BackBuffer()
		
		;Draw
		DrawBlock intexFrame,xOffset-15,yOffset-12
		DrawImage intexBackground,xOffset,yOffset 
			
		;Drawtext
		ProcessMenuText()
		
		;Individual menu functions
		If intexMenu\build = False Or currentMenu = 11 Then
			Select currentMenu
				Case 0	;Intex Boot
					;Set menu to Main Menu 
					currentMenu = 1
					GetMenuText(currentMenu,pl)

				Case 1,2,3	;Main Menu
					DrawImage intexText,32+xOffset,intexMenu\y[intexMenu\highlight[intexMenu\cursorRow]], 0
					
					;Menu Up/Down
					If menuUpdateCounter = 0 Then
						If control(pUp,pl\id) And intexMenu\cursorRow > 1 Then
							intexMenu\cursorRow = intexMenu\cursorRow - 1
							menuUpdateCounter = 10
							
						ElseIf control(pDown,pl\id) And intexMenu\highlight[intexMenu\cursorRow + 1] <> 0 Then
							intexMenu\cursorRow = intexMenu\cursorRow + 1
							menuUpdateCounter = 10
							
						End If
						
					Else
						;Control the speed of the menu movement
						If menuUpdateCounter > 0 Then
							menuUpdateCounter = menuUpdateCounter - 1
						
						End If
						
					End If
					
					;Menu select
					If control(pfire1,pl\id) And intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]] > 0 Then
						currentMenu = intexMenu\subMenu[intexMenu\highlight[intexMenu\cursorRow]]
						GetMenuText(currentMenu,pl)
						
					End If
						
				Case 7
					If control(pfire1,pl\id) Then
						;Return to main menu
						currentMenu = 1
						GetMenuText(currentMenu,pl)
						
					End If
										
				Case 10	;Disconnect
					exitMenu = True
							
			End Select
			
		End If
		
		;Draw
		Flip True
		
	Wend
	
	;Clear keys
	FlushKeys()
	
	;Tidyup
	Delete Each menuSystem
	
End Function

Function GetMenuText(menu, pl.player)
	Local totalLines, lines
	Local lineText$, x, y, subMenu, max
	Local highlight

	Select menu
		Case 0	;Intex Boot
			Restore menuIntexBoot
			
		Case 1	;Menu
			Restore menuIntexMain

		Case 2	;Weapon Supplies
			Restore menuIntexWeaponsSupply
			
		Case 3	;Tool Supplies
			Restore menuIntexToolSupply
			
		Case 7	;Statistics
			Restore menuIntexStatistics
			
		Case 10	;Disconnect
			Restore menuIntexDisconnect
			
	End Select
	
	;Read the data
	Read totalLines
	
	;Clear
	For lines = 1 To maxLines
		intexMenu\highlight[lines] = 0
	Next
	
	;Process the lines
	For lines = 1 To totalLines
		Read lineText, x, y, subMenu, highlight
		intexMenu\menuText$[lines] = UpdateTags(Upper(lineText), pl)
		intexMenu\x[lines] = x/2 + xOffset
		intexMenu\y[lines] = y/2 + yOffset
		intexMenu\subMenu[lines] = subMenu
		
		;Set line selection
		If highlight <> -1 Then
			intexMenu\highlight[highlight] = Lines
			
		End If
		
	Next
	
	;Set remaining fields
	intexMenu\build = True
	intexMenu\bChar = 0
	intexMenu\bLine = 1
	intexMenu\id = menu
	intexMenu\pauseCounter = 0
	intexMenu\total = totalLines + 1
	intexMenu\cursorRow = 1
	intexMenu\bCharCounter = 0
	
End Function

Function UpdateTags$(lineText$, pl.player)
	;Update tags
	lineText = Replace(lineText,"%PLSCORE%",LSet(pl\score,6))
	lineText = Replace(lineText,"%PLCREDITS%",LSet(pl\credits,6))
	lineText = Replace(lineText,"%PLKILLS%",pl\kills)
	lineText = Replace(lineText,"%PLSHOTS%",LSet(pl\shots,6))
	lineText = Replace(lineText,"%PLDOORS%",LSet(pl\doors,6))
	lineText = Replace(lineText,"%PLAMMO%",LSet(pl\clip,6))
	lineText = Replace(lineText,"%PLENERGY%","GOOD")
	lineText = Replace(lineText,"%PLCURRENTWEAPON%",Upper(pl\weapon\name))	;Current
	lineText = Replace(lineText,"%WBROADHURST%",WeaponStatus(pl\ownedWeapons[1]))
	lineText = Replace(lineText,"%WDALTON%",WeaponStatus(pl\ownedWeapons[2]))
	lineText = Replace(lineText,"%WROBINSON%",WeaponStatus(pl\ownedWeapons[3]))
	lineText = Replace(lineText,"%WRYXX%",WeaponStatus(pl\ownedWeapons[4]))
	lineText = Replace(lineText,"%WSTYRLING%",WeaponStatus(pl\ownedWeapons[5]))
	lineText = Replace(lineText,"%WIMPACT%",WeaponStatus(pl\ownedWeapons[6]))

	;Return
	Return lineText
	
End Function

function WeaponStatus$(wp.weapon)
	If wp<>Null Then
		Return "YES"
		
	End If
	Return " NO"
End Function

Function ProcessMenuText()
	Local currentChar$,x,y,maxChar,char
	Local charCounter = 0
	Local drawCursor = False
	
	If intexMenu\build Then
		If intexMenu\bChar > 0 Then
			;Get the current char
			Repeat
				currentChar = Mid(intexMenu\menuText[intexMenu\bLine],intexMenu\bChar,1)
				If currentChar = " " And intexMenu\bChar < Len(intexMenu\menuText[intexMenu\bLine]) - 1 Then
					;Skip over any spaces
					intexMenu\bCharCounter = intexMenu\bCharCounter + 1
					intexMenu\bChar = intexMenu\bChar + 1
					
				ElseIf currentChar = "+" Then
					;We need to pause
					intexMenu\pauseCounter = (intexMenu\pauseCounter +1) Mod pauseMax
				    Exit
				    
				Else
					;Exit out
					Exit
					
			    End If
			    			    
		    Forever
			
		End If
		
		;Continue to process text
		If intexMenu\pauseCounter = 0 Then
			;Increment number of shown characters
			intexMenu\bCharCounter = intexMenu\bCharCounter + 1
			
			;Increment char
			intexMenu\bChar = (intexMenu\bChar + 1) Mod Len(intexMenu\menuText[intexMenu\bLine])
			If intexMenu\bChar = 0 Then
				;Increment line
				intexMenu\bLine = (intexMenu\bLine + 1) Mod intexMenu\total
				If intexMenu\bLine = 0 Then
					;Set each item to it's max
					intexMenu\bLine = intexMenu\total - 1
					intexMenu\bChar = Len(intexMenu\menuText[intexMenu\bLine])
					
					;Finish
					intexMenu\build = False
					FlushKeys()
					
				End If
				
			End If
			
		End If
		
	End If
	
	;Draw text
	For drawLine = 1 To intexMenu\bLine
		;Set co-ords for current line
		x = intexMenu\x[drawLine]
		y = intexMenu\y[drawLine]
			
		;Draw current line
		For drawChar = 1 To Len(intexMenu\menuText[drawLine])
			;Increment letter count
			charCounter = charCounter + 1
			
			;Get current char
			char = Instr(intexChars, Mid(intexMenu\menuText[drawLine],drawChar,1)) - 1
			If char > -1 Then
				DrawImage intexText,x,y,char
			
			End If
			
			;Building the menu, if so pause on last char and display cursor
			If intexMenu\build Then
				;Slight pause when first displaying character?
				If (charCounter = intexMenu\bCharCounter) Then 
					Delay 15
					intexMenu\cursorX = x
					intexMenu\cursory = y
					drawCursor = True
					Exit
				
				End If
					
			End If
			
			x = x + charWidth
			
		Next
			
		If drawCursor Then
			DrawImage intexText,intexMenu\cursorX,intexMenu\cursorY,0
			Exit
			
		End If
		
	Next
	
End Function

;Data Structure
;No of lines
;Text$,X,Y,SubMenu

.menuIntexBoot
Data 10
Data "INTEX NETWORK CONNECT: CODE ABF01DCC60 ",8,96,-1,-1
Data "CONNECTING..................... ",8,120,-1,-1
Data "INTEX NETWORK SYSTEM V10.0 ",8,168,-1,-1
Data "2G RAM:           OK ",8,192,-1,-1
Data "EXTERNAL DEVICE:  OK ",8,216,-1,-1
Data "SYSTEM V1.10 CS:  OK ",8,240,-1,-1
Data "VIDEODISPLAY:     DAMAGED+ ",8,264,-1,-1
Data "EXECUTING DOS 5.0 ",8,312,-1,-1
Data "SYSTEM DOWNLOADING NETWORKDATA..... OK ",8,336,-1,-1
Data "INTEX EXECUTED!+ ",8,360,-1,-1

.menuIntexMain
Data 8
Data "INTEX MAIN MENU ",192,64,-1,-1
Data "INTEX WEAPON SUPPLIES ",144,136,-1,1
Data "INTEX TOOL SUPPLIES ",160,160,3,2
Data "INTEX RADAR SERVICE ",160,184,-1,3
Data "LEVEL INFORMATION UPDATE ",128,208,-1,4
Data "INTEX ENTERTAINMENT ",160,232,-1,5
Data "STATISTICS ",240,256,7,6
Data "EXIT INTEX NETWORK ",176,280,10,7

.menuIntexWeaponsSupply
Data 2
Data "INTEX WEAPON SUPPLIES ",144,48,-1,-1
Data "WEAPON SUPPLIES REQUEST: ",48,96,-1,-1

.menuIntexToolSupply
Data 8
Data "INTEX TOOL SUPPLIES ",160,72,-1,-1
Data "ELECTRONIC HAND MAP        500 CR ",64,144,-1,1 
Data "AMMO NYBBLE               1000 CR ",64,192,-1,2
Data "FIRST AID KIT             2000 CR ",64,240,-1,3
Data "6 KEYS                    4000 CR ",64,288,-1,4
Data "EXTRA LIFE               10000 CR ",64,336,-1,5
Data "EXIT ",288,384,1,6
Data "YOUR CREDIT LIMIT IS: %PLCREDITS% CR ",80,432,-1,-1

.menuIntexStatistics
Data 16
Data "INTEX STATISTICS ",176,32,-1,-1
Data "PLAYER SCORES:  %PLSCORE% PTS ",80,80,-1,-1
Data "ALIENS KILLED:  %PLKILLS% ",80,104,-1,-1
Data "SHOTS FIRED:  %PLSHOTS% BULLETS ",112,128,-1,-1
Data "CREDITS OWNED:  %PLCREDITS% CR ",80,152,-1,-1
Data "DOORS OPENED:  %PLDOORS% ",96,176,-1,-1
Data "AMMO OWNED:  %PLAMMO% CLIP",128,200,-1,-1
Data "ENERGY STATE:  %PLENERGY% ",96,224,-1,-1
Data "CURRENT WEAPON:  %PLCURRENTWEAPON%",64,248,-1,-1
Data "WEAPONS AVAILABLE: ",16,272,-1,-1
Data weaponBroadhurst + "... %WBROADHURST% ",48,320,-1,-1		;112
Data weaponDalton + "...           %WDALTON% ",48,344,-1,-1
Data weaponRobinson + "...        %WROBINSON% ",48,368,-1,-1
Data weaponRyxx + "...         %WRYXX% ",48,392,-1,-1
Data weaponStyrling + "...        %WSTYRLING% ",48,416,-1,-1
Data weaponImpact + "...    %WIMPACT% ",48,440,-1,-1

.menuIntexDisconnect
Data 1
Data "DISCONNECTING..............+ ",32,128,-1,-1

Other Changes:

;Player.bb ----------------------------------------------------------------------------------
type player
	Field score, kills, shots, doors
End Type

;Function Player_updateall
	; weapons (player specific)
	If control(p_weapon1,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponBroadhurst))
	If control(p_weapon2,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponDalton))
	If control(p_weapon3,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponRobinson))
	If control(p_weapon4,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponRyxx))
	If control(p_weapon5,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponStyrling))
	If control(p_weapon6,pl\id) Then EquipWeapon(pl\id,getWeaponFromName(weaponImpact))

;Engine.bb -----------------------------------------------------------------------------------

createWeapon(1,weaponBroadhurst,    1.5, 	5, 	25, 	100, 3.0, 	2,			21, "sfx\mgun.mp3", "", "sfx\pistolreload1.mp3")
createWeapon(2,weaponDalton,    	10.0,	1, 	25,  	500, 6.3, 	1,			22, "", "", "")
createWeapon(3,weaponRobinson,  	8.0, 	5, 	25, 	300, 2.6, 	0,			23, "", "", "")
createWeapon(4,weaponRyxx,      	0.4, 	5, 	25, 	100, 3.0, 	-1,			24, "", "", "")
createWeapon(5,weaponStyrling,  	1.5, 	5, 	25, 	100, 3.0, 	3,			25, "", "", "")
createWeapon(6,weaponImpact,    	1.5, 	5, 	25, 	100, 3.0, 	3,			26, "", "", "")

;Script.bb ------------------------------------------------------------------------------------

;Function RunScript
			Case "pickupweapon"
				Select Int(si\param)
					Case 1:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponBroadhurst))
					Case 2:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponDalton))
					Case 3:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponRobinson))
					Case 4:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponRyxx))
					Case 5:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponStyrling))
					Case 6:giveWeaponToPlayer(pl.player,getWeaponFromName(weaponImpact))
				End Select

			Case "opendoor"
				opendoor(Floor(x/32),Floor(y/32))
				;Update counter for player status
				pl\doors = pl\doors + 1

;Weapons.bb ---------------------------------------------------------------------------------

Const weaponBroadhurst$ = "Broadhurst DJ Twinfire 3LG"
Const weaponDalton$ = "Dalton Arc Flame"
Const weaponRobinson$ = "Robinson Plasma Gun"
Const weaponRyxx$ = "Ryxx Firebolt MK22"
Const weaponStyrling$ = "Styrling Multimatic"
Const weaponImpact$ = "High Impact Astro Laser"

;Function Shoot

		;Update counter for player status
		p\shots = p\shots + 1
		; create muzzle flash
		p\weapon\fireSoundChannel=PlaySound(p\weapon\fireSound)		
		
;Function HandleBullets
			For al.alien = Each alien
				If ImagesCollide(bulletgfx,b\x,b\y,1,		al\image,al\x-al\offset,al\y-al\offset,al\dir)
				;circlesoverlap(al\x,al\y,al\radius,bx+16,by+16,3)
					; knock alien back
					If Rand(1,10)=1
						al\x = al\x + (Sin((al\dir*45)+180))*3
						al\y = al\y - (Cos((al\dir*45)+180))*3
					EndIf
					
					killed = alien_hit(al,b\damage)
					If killed = True Then
						;Update counter for player status
						b\owner\kills = b\owner\ammo + 1

					End If
					ok=False ;bullet hit alien
					
					
				EndIf
			Next


;Aliens.bb ------------------------------------------------------------------------------------------

Function alien_hit(al.alien,damage#=1.0)
	
	al\health = al\health - damage
	al\mode="underattack"
	
	If Rand(0,2)=0 Then playoneshot(snd_alienhit(Rand(0,3)),al\x,al\y)
	
	
	
	;random alien blood splats
	d=Rand(0,359)
	f=Rand(0,3)
	createparticle(al\x,al\y,Sin(d)*2,Cos(d)*2,Rand(10,100),f,f,particles,16)
		
	If al\health<=0 Then 
		alien_die(al)
		;Return true so we know the alien died
		Return True
		
	End If
	
	Return False
	
End Function

Also add this stuff into engine.bb

Include "inc\intex-new.bb"

If KeyHit(23) Then IntexMenu(player(1)):time=MilliSecs()-period  ;Need to determine player activates

Hopefully that's everything - if not, get it in there and I will check to see if anything is missing.